[gentoo-commits] repo/gentoo:master commit in: dev-libs/rocm-comgr/

["Sam James" <sam@gentoo.org>]

commit:     0f5bc2048670c751eed4f7f5877e676f8bb19537
Author:     Sv. Lockal <lockalsash <AT> gmail <DOT> com>
AuthorDate: Sun Jan 26 14:56:48 2025 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Thu Feb 13 12:05:16 2025 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=0f5bc204

dev-libs/rocm-comgr: drop 6.3.0, fix out-of-process compiler in 6.3.2

This version drops the `rocm-comgr-6.1.0-enforce-oop-compiler.patch`, which was an attempt to fix the `compile_source_to_executable` test.
This test has already been removed from future releases (in `amd-staging` branch), and the code section that failed was not even supposed to be executed
(it was only executed because CMake was able to find `hip-config.cmake` on Gentoo).
Removing the `rocm-comgr-6.1.0-enforce-oop-compiler.patch` resolves the compilation failure in the comfyui -> miopen -> comgr chain via hiprtc.

Signed-off-by: Sv. Lockal <lockalsash <AT> gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/40317
Signed-off-by: Sam James <sam <AT> gentoo.org>

 dev-libs/rocm-comgr/Manifest                       |  1 -
 dev-libs/rocm-comgr/rocm-comgr-6.3.0.ebuild        | 88 ----------------------
 ...mgr-6.3.2.ebuild => rocm-comgr-6.3.2-r1.ebuild} |  6 +-
 3 files changed, 4 insertions(+), 91 deletions(-)

diff --git a/dev-libs/rocm-comgr/Manifest b/dev-libs/rocm-comgr/Manifest
index eecd5abc159c..683e08c150ad 100644
--- a/dev-libs/rocm-comgr/Manifest
+++ b/dev-libs/rocm-comgr/Manifest
@@ -1,5 +1,4 @@
 DIST llvm-project-rocm-6.1.1.tar.gz 196027084 BLAKE2B 3ef0b6e3c47c66fd80289373e6ff8aaff44751f9b380addfae73a18dc388093c0535f230b0cc7528724bc43f6992e2ae6decd3d0d3c700893ca95a6166b7b8dc SHA512 e320d4eeaa6f61ed1cdbf653d67fe887d3ce9dc0d6743b4713502e1cb5318ab8afbe1ee71f8cba07635c54ce532df6683de40ade0e5be4a52e50ce25a9b70818
 DIST llvm-project-rocm-6.1.2.tar.gz 195992927 BLAKE2B d821f29f2f1f7c1ff414c63a710281f16d2a394b21f3365d01b86710cc09ed27e514b49fb744bf6a36b38815afa56cc26d44f0238f38479a0c2db9bf9989f389 SHA512 5f7e5dbe5976141de35e96e603624bd9d5a2c08b0690ba9fcd81d1b32f540f94bb9f4b74539e2838fd60ae1312dbe5e0b429ba80a03871782cdf3bd834940ce0
-DIST llvm-project-rocm-6.3.0.tar.gz 206677330 BLAKE2B f3e68a8c94599e3a938d3e761af163b9f010a06421680ee70aaaaf8073fb18da9151729c311fc4bd12b281b3afdd15e61cea31c970f0e4d36bb97838fa17ca5f SHA512 674fc3242c6dbb6962f1002dc34ccbd618da6adeb640bac15265d22fdcedf9de16ea3d79899891734ccc1099cb5b5ed9110b1162f4515c4cbc0d847810682b59
 DIST llvm-project-rocm-6.3.2.tar.gz 206671202 BLAKE2B a280e2be22b8eb9fd51814074447baed3637231d4bfbe391047a1fb2409197c8d8ba58cebb3aeaec15aa4daee9371311274b30ede48e0039d7c84e432b15de1a SHA512 314e27577af76268635f3c96ee3516829e4622913c3d0c4c68eccbaee0c9f7f5fc031cbd35827deb4bc29712592c424e296c15ce8c500c897bfb3eb19455899c
 DIST rocm-comgr-5.7.1.tar.gz 137923 BLAKE2B e215f51137fd0c4b67e85496bf289dc0afde6ebc9efb9416f5fc4cf312b2be9be26da35cb70965bf4857a0f1434d750bcc03ce83095173098487ef7805948735 SHA512 cdd2609b858d9503c30122a2d328d36baa8a930a05bcb6c38e30723909c492b4d47eaaf4884dbb7aa82053e7cda6c22ee1aa16fc5ba266e272d98ff772c5079d

diff --git a/dev-libs/rocm-comgr/rocm-comgr-6.3.0.ebuild b/dev-libs/rocm-comgr/rocm-comgr-6.3.0.ebuild
deleted file mode 100644
index 66239d28f79c..000000000000
--- a/dev-libs/rocm-comgr/rocm-comgr-6.3.0.ebuild
+++ /dev/null
@@ -1,88 +0,0 @@
-# Copyright 1999-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-LLVM_COMPAT=( 19 )
-
-inherit cmake llvm-r1 prefix
-
-MY_P=llvm-project-rocm-${PV}
-components=( "amd/comgr" )
-
-DESCRIPTION="Radeon Open Compute Code Object Manager"
-HOMEPAGE="https://github.com/ROCm/llvm-project/tree/amd-staging/amd/comgr"
-SRC_URI="https://github.com/ROCm/llvm-project/archive/rocm-${PV}.tar.gz -> ${MY_P}.tar.gz"
-S="${WORKDIR}/${MY_P}/${components[0]}"
-
-LICENSE="MIT"
-SLOT="0/$(ver_cut 1-2)"
-KEYWORDS="~amd64"
-
-IUSE="test"
-RESTRICT="!test? ( test )"
-
-PATCHES=(
-	"${FILESDIR}/${PN}-5.1.3-rocm-path.patch"
-	"${FILESDIR}/0001-Find-CLANG_RESOURCE_DIR-using-clang-print-resource-d.patch"
-	"${FILESDIR}/${PN}-6.0.0-extend-isa-compatibility-check.patch"
-	"${FILESDIR}/${PN}-6.1.0-enforce-oop-compiler.patch"
-	"${FILESDIR}/${PN}-6.3.0-fix-comgr-default-flags.patch"
-	"${FILESDIR}/${PN}-6.1.0-dont-add-nogpulib.patch"
-	"${FILESDIR}/${PN}-6.3.0-llvm-19-compat.patch"
-	"${FILESDIR}/${PN}-6.3.0-bypass-device-libs-copy.patch"
-)
-
-RDEPEND=">=dev-libs/rocm-device-libs-${PV}
-	llvm-core/clang-runtime:=
-	$(llvm_gen_dep '
-		llvm-core/clang:${LLVM_SLOT}=
-		llvm-core/lld:${LLVM_SLOT}=
-	')
-	dev-util/hipcc:${SLOT}
-"
-DEPEND="${RDEPEND}"
-
-CMAKE_BUILD_TYPE=Release
-
-src_unpack() {
-	if [[ ${PV} == *9999 ]] ; then
-		git-r3_fetch
-		git-r3_checkout '' . '' "${components[@]}"
-	else
-		archive="${MY_P}.tar.gz"
-		ebegin "Unpacking from ${archive}"
-		tar -x -z -o \
-			-f "${DISTDIR}/${archive}" \
-			"${components[@]/#/${MY_P}/}" || die
-		eend ${?}
-	fi
-}
-
-src_prepare() {
-	sed '/sys::path::append(HIPPath/s,"hip","",' -i src/comgr-env.cpp || die
-	sed "/return LLVMPath;/s,LLVMPath,llvm::SmallString<128>(\"$(get_llvm_prefix)\")," -i src/comgr-env.cpp || die
-	eapply $(prefixify_ro "${FILESDIR}"/${PN}-5.0-rocm_path.patch)
-
-	cmake_src_prepare
-
-	# Replace @CLANG_RESOURCE_DIR@ in patches
-	local CLANG_RESOURCE_DIR="$("$(get_llvm_prefix)"/bin/clang -print-resource-dir)"
-	sed "s,@CLANG_RESOURCE_DIR@,\"${CLANG_RESOURCE_DIR}\"," -i src/comgr-compiler.cpp || die
-}
-
-src_configure() {
-	local mycmakeargs=(
-		-DLLVM_DIR="$(get_llvm_prefix)"
-		-DCMAKE_STRIP=""  # disable stripping defined at lib/comgr/CMakeLists.txt:58
-		-DBUILD_TESTING=$(usex test ON OFF)
-	)
-	cmake_src_configure
-}
-
-src_test() {
-	local CMAKE_SKIP_TESTS=(
-		comgr_nested_kernel_test # See https://github.com/ROCm/llvm-project/issues/35
-	)
-	cmake_src_test
-}

diff --git a/dev-libs/rocm-comgr/rocm-comgr-6.3.2.ebuild b/dev-libs/rocm-comgr/rocm-comgr-6.3.2-r1.ebuild
similarity index 92%
rename from dev-libs/rocm-comgr/rocm-comgr-6.3.2.ebuild
rename to dev-libs/rocm-comgr/rocm-comgr-6.3.2-r1.ebuild
index bf8986261a9f..cea4ebe78e73 100644
--- a/dev-libs/rocm-comgr/rocm-comgr-6.3.2.ebuild
+++ b/dev-libs/rocm-comgr/rocm-comgr-6.3.2-r1.ebuild
@@ -26,14 +26,14 @@ PATCHES=(
 	"${FILESDIR}/${PN}-5.1.3-rocm-path.patch"
 	"${FILESDIR}/0001-Find-CLANG_RESOURCE_DIR-using-clang-print-resource-d.patch"
 	"${FILESDIR}/${PN}-6.0.0-extend-isa-compatibility-check.patch"
-	"${FILESDIR}/${PN}-6.1.0-enforce-oop-compiler.patch"
 	"${FILESDIR}/${PN}-6.3.0-fix-comgr-default-flags.patch"
 	"${FILESDIR}/${PN}-6.1.0-dont-add-nogpulib.patch"
 	"${FILESDIR}/${PN}-6.3.0-llvm-19-compat.patch"
 	"${FILESDIR}/${PN}-6.3.0-bypass-device-libs-copy.patch"
 )
 
-RDEPEND=">=dev-libs/rocm-device-libs-${PV}
+RDEPEND="
+	dev-libs/rocm-device-libs:${SLOT}
 	llvm-core/clang-runtime:=
 	$(llvm_gen_dep '
 		llvm-core/clang:${LLVM_SLOT}=
@@ -77,6 +77,8 @@ src_configure() {
 		-DCMAKE_STRIP=""  # disable stripping defined at lib/comgr/CMakeLists.txt:58
 		-DBUILD_TESTING=$(usex test ON OFF)
 	)
+	# Prevent CMake from finding systemwide hip, which breaks tests
+	use test && mycmakeargs+=( -DCMAKE_DISABLE_FIND_PACKAGE_hip=ON )
 	cmake_src_configure
 }