[gentoo-commits] repo/gentoo:master commit in: dev-util/bear/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     13a71f63abb9767cc5434f0c00d4e5df2bb8267f
Author:     Alexey Sokolov <alexey+gentoo <AT> asokolov <DOT> org>
AuthorDate: Mon Feb 10 23:55:38 2025 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Tue Feb 11 20:54:22 2025 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=13a71f63

dev-util/bear: drop 3.1.4-r2

Signed-off-by: Alexey Sokolov <alexey+gentoo <AT> asokolov.org>
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 dev-util/bear/Manifest             |   1 -
 dev-util/bear/bear-3.1.4-r2.ebuild | 115 -------------------------------------
 2 files changed, 116 deletions(-)

diff --git a/dev-util/bear/Manifest b/dev-util/bear/Manifest
index 4b6cbb75bce1..7d3abd94609a 100644
--- a/dev-util/bear/Manifest
+++ b/dev-util/bear/Manifest
@@ -1,2 +1 @@
-DIST bear-3.1.4.tar.gz 127672 BLAKE2B 18deb1172fcd8afdf4721a04b5d72b182190afd92d645841023033d187c812a0a30805af2bfb67b794ab8a8f0ca42965bebab6d035e95e2a25c5fccfe48a1afd SHA512 c63da7586d25a64dd8b3ff82f37505b36071dd064deb973c012840bc52ff6aec861fca21422b86b11629e86dc43d156b233d21b01e689369f0726799083afa98
 DIST bear-3.1.5.tar.gz 152228 BLAKE2B 64d03d1ca5b1473e4d0b2106969285a2391471a0027cf387c72fe70769293fa361196cb1d37ebb528d27b5741b792472fad09688761ab7f73dc0ea7db96d8be1 SHA512 acf233f7bb8215694734b6c947c965323c0a5ea0c2a6bbb210a37e38fdf545326ca8de3a7b31ce81469756afd1c02233775ddc5936fd04132f216def6e3ce1de

diff --git a/dev-util/bear/bear-3.1.4-r2.ebuild b/dev-util/bear/bear-3.1.4-r2.ebuild
deleted file mode 100644
index 10a1423f03cb..000000000000
--- a/dev-util/bear/bear-3.1.4-r2.ebuild
+++ /dev/null
@@ -1,115 +0,0 @@
-# Copyright 2020-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-PYTHON_COMPAT=( python3_{10..13} )
-
-inherit cuda cmake multiprocessing python-any-r1
-
-DESCRIPTION="Build EAR generates a compilation database for clang tooling"
-HOMEPAGE="https://github.com/rizsotto/Bear"
-SRC_URI="https://github.com/rizsotto/Bear/archive/${PV}.tar.gz -> ${P}.tar.gz"
-S="${WORKDIR}/${P^}"
-
-LICENSE="GPL-3+"
-SLOT="0"
-KEYWORDS="amd64 ~arm64 ~loong ~ppc64 ~riscv x86"
-IUSE="cuda test"
-RESTRICT="!test? ( test )"
-
-# <libfmt-11 https://github.com/rizsotto/Bear/issues/592
-RDEPEND="
-	>=dev-libs/libfmt-9.1.0:=
-	<dev-libs/libfmt-11
-	dev-libs/protobuf:=
-	>=dev-libs/spdlog-1.11.0:=
-	>=net-libs/grpc-1.49.2:=
-	cuda? ( dev-util/nvidia-cuda-toolkit )
-"
-
-DEPEND="
-	${RDEPEND}
-	>=dev-cpp/nlohmann_json-3.11.2:=
-	test? (
-		>=dev-cpp/gtest-1.13
-	)
-"
-
-BDEPEND="
-	virtual/pkgconfig
-	test? (
-		dev-build/libtool
-		$(python_gen_any_dep '
-			dev-python/lit[${PYTHON_USEDEP}]
-		')
-	)
-"
-
-PATCHES=(
-	"${FILESDIR}/${PN}-3.1.4-tests.patch"
-	"${FILESDIR}/${PN}-3.1.4-reduce-grpc-verbosity.patch"
-)
-
-pkg_setup() {
-	use test && python-any-r1_pkg_setup
-}
-
-src_prepare() {
-	cmake_src_prepare
-	# Turn off testing before installation
-	sed -i 's/TEST_BEFORE_INSTALL/TEST_EXCLUDE_FROM_MAIN/g' CMakeLists.txt || die
-}
-
-src_configure() {
-	# TODO: remove this when https://bugs.gentoo.org/928346 is fixed
-	export CMAKE_BUILD_PARALLEL_LEVEL=$(makeopts_jobs)
-
-	local mycmakeargs=(
-		-DENABLE_UNIT_TESTS="$(usex test)"
-		-DENABLE_FUNC_TESTS="$(usex test)"
-	)
-	cmake_src_configure
-}
-
-src_test() {
-	if has sandbox "${FEATURES}"; then
-		ewarn "FEATURES=sandbox detected"
-		ewarn "Bear overrides LD_PRELOAD and conflicts with gentoo sandbox"
-		ewarn "tests will fail"
-	fi
-	if has usersandbox "${FEATURES}"; then
-		ewarn "FEATURES=usersandbox detected"
-		ewarn "tests will fail"
-	fi
-	if
-		has network-sandbox "${FEATURES}"; then
-		ewarn "FEATURES=network-sandbox detected"
-		ewarn "tests will fail"
-	fi
-	if
-		has_version -b 'sys-devel/gcc-config[-native-symlinks]'; then
-		ewarn "\'sys-devel/gcc-config[-native-symlinks]\' detected, tests call /usr/bin/cc directly (hardcoded)"
-		ewarn "and will fail without generic cc symlink"
-	fi
-
-	einfo "test may use optional tools if found: gfortran libtool nvcc valgrind"
-
-	# unit tests
-	BUILD_DIR="${BUILD_DIR}/subprojects/Build/BearSource" cmake_src_test
-
-	# functional tests
-	if use cuda; then
-		NVCC_CCBIN="$(cuda_gccdir)"
-		export NVCC_CCBIN
-	else
-		LIT_SKIP_TESTS+=( "cases/compilation/output/compile_cuda.sh" )
-	fi
-
-	mylitopts+=(-j "$(makeopts_jobs)" )
-	[[ -n "${LIT_SKIP_TESTS[*]}" ]] && mylitopts+=( --filter-out "($( IFS='|'; echo "${LIT_SKIP_TESTS[*]}"))" )
-
-	export LIT_OPTS="${mylitopts[*]}"
-
-	BUILD_DIR="${BUILD_DIR}/subprojects/Build/BearTest" cmake_src_test
-}