From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1715000-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from smtp.gentoo.org (woodpecker.gentoo.org [140.211.166.183])
(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
key-exchange X25519 server-signature RSA-PSS (4096 bits))
(No client certificate requested)
by finch.gentoo.org (Postfix) with ESMTPS id E2CF2158B20
for <garchives@archives.gentoo.org>; Wed, 05 Feb 2025 11:13:45 +0000 (UTC)
Received: from lists.gentoo.org (bobolink.gentoo.org [140.211.166.189])
(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
key-exchange X25519 server-signature RSA-PSS (4096 bits))
(No client certificate requested)
(Authenticated sender: relay-lists.gentoo.org@gentoo.org)
by smtp.gentoo.org (Postfix) with ESMTPSA id BF2EC34302F
for <garchives@archives.gentoo.org>; Wed, 05 Feb 2025 11:13:45 +0000 (UTC)
Received: from bobolink.gentoo.org (localhost [127.0.0.1])
by bobolink.gentoo.org (Postfix) with ESMTP id 230EE110473;
Wed, 05 Feb 2025 11:13:39 +0000 (UTC)
Received: from smtp.gentoo.org (woodpecker.gentoo.org [IPv6:2001:470:ea4a:1:5054:ff:fec7:86e4])
(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
key-exchange X25519 server-signature RSA-PSS (4096 bits))
(No client certificate requested)
by bobolink.gentoo.org (Postfix) with ESMTPS id 1DF5D110473
for <gentoo-commits@lists.gentoo.org>; Wed, 05 Feb 2025 11:13:39 +0000 (UTC)
Received: from oystercatcher.gentoo.org (oystercatcher.gentoo.org [148.251.78.52])
(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
key-exchange X25519 server-signature RSA-PSS (4096 bits) server-digest SHA256)
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id C1160342F99
for <gentoo-commits@lists.gentoo.org>; Wed, 05 Feb 2025 11:13:38 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id 2E8682644
for <gentoo-commits@lists.gentoo.org>; Wed, 05 Feb 2025 11:13:37 +0000 (UTC)
From: "Florian Schmaus" <flow@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Florian Schmaus" <flow@gentoo.org>
Message-ID: <1738753990.4a74f0f02ddf05549d7122da1c12cbc391dcae07.flow@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: net-misc/frr/
X-VCS-Repository: repo/gentoo
X-VCS-Files: net-misc/frr/Manifest net-misc/frr/frr-9.1.3.ebuild
X-VCS-Directories: net-misc/frr/
X-VCS-Committer: flow
X-VCS-Committer-Name: Florian Schmaus
X-VCS-Revision: 4a74f0f02ddf05549d7122da1c12cbc391dcae07
X-VCS-Branch: master
Date: Wed, 05 Feb 2025 11:13:37 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: 7734e70e-ea28-44de-9c7e-64a71133f576
X-Archives-Hash: cdeb603d955f67bfdd8e3e808daaae30
commit: 4a74f0f02ddf05549d7122da1c12cbc391dcae07
Author: Jaco Kroon <jaco <AT> uls <DOT> co <DOT> za>
AuthorDate: Mon Jan 6 19:45:23 2025 +0000
Commit: Florian Schmaus <flow <AT> gentoo <DOT> org>
CommitDate: Wed Feb 5 11:13:10 2025 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=4a74f0f0
net-misc/frr: add 9.1.3
Signed-off-by: Jaco Kroon <jaco <AT> uls.co.za>
Closes: https://github.com/gentoo/gentoo/pull/39575
Signed-off-by: Florian Schmaus <flow <AT> gentoo.org>
net-misc/frr/Manifest | 1 +
net-misc/frr/frr-9.1.3.ebuild | 146 ++++++++++++++++++++++++++++++++++++++++++
2 files changed, 147 insertions(+)
diff --git a/net-misc/frr/Manifest b/net-misc/frr/Manifest
index ca12b25e2691..d1c46796993b 100644
--- a/net-misc/frr/Manifest
+++ b/net-misc/frr/Manifest
@@ -2,3 +2,4 @@ DIST frr-10.0.3.tar.gz 10968934 BLAKE2B 18ef81af21b9ca2861dd66c7c3d4ec7faa2ba322
DIST frr-10.1.2.tar.gz 11046539 BLAKE2B db983becc4c00256cfc87032252f85f763d9acfdc5eb8488206b32fe8caddfb8e9371808d929cb708b4df1a32d2a2df148d036f3eef98ff432812ae6a865d539 SHA512 257844687c0132819bedf559a527217d4c01abfa6b98c787f18f24e5006a53d9d3e561b22ab36631d691ba53d3f206c1d52d8020cb1b962d7ad117b159f674c6
DIST frr-10.2.1.tar.gz 11178677 BLAKE2B 8bcc8ccf8febee1012d94a9f3de40cc177bec1af464cd935303df8859a72607d03e5f9030f05bed5d56a7a413a0029479f538b3c0b35acc4a66295b4229f6be1 SHA512 8544280a0c536e8688cbf2811d96cdc2fa3413f662013bb1b58cb02d4d56a08d98e870b39e477f6b0294e6aceb5dcc99c5facdeee165ce7597c2150ebb79101e
DIST frr-9.1.2.tar.gz 10790677 BLAKE2B dfa4967ee0e0bbecea016b9deeb70b1c1b9e409469de145050602608dddd41857be946e8df5c8a594dfaf6a124729af55d7ce4483e6fe6edc41125f09d9dabd2 SHA512 e0ed613090140ece181bff077a7067a00a5fca648ec6627c02d815060087497c68712c1ba244fa1534cdbcef49db92bd9432545d05027dc4b04db4f423726882
+DIST frr-9.1.3.tar.gz 10790704 BLAKE2B e8e68aa7bd4c4c9e01d82c2ef2788fb66fad0332000fc61bcc094af22628a09ce4dc28d41891a4a48e8493a6377f9fa02c5b782cf8a989fd7f54484ecb24e0eb SHA512 5f07ae1dcea2bca8de30dba97011de999a08cebdd1b2dd05f1eb24c4dbde2746a51de54867d77a6b5a205c8d13636589e0513c360d453143fd64802d5956a682
diff --git a/net-misc/frr/frr-9.1.3.ebuild b/net-misc/frr/frr-9.1.3.ebuild
new file mode 100644
index 000000000000..271bab6bccbd
--- /dev/null
+++ b/net-misc/frr/frr-9.1.3.ebuild
@@ -0,0 +1,146 @@
+# Copyright 2020-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..13} )
+inherit autotools pam python-single-r1 systemd
+
+DESCRIPTION="The FRRouting Protocol Suite"
+HOMEPAGE="https://frrouting.org/"
+SRC_URI="https://github.com/FRRouting/frr/archive/${P}.tar.gz"
+# FRR tarballs have weird format.
+S="${WORKDIR}/frr-${P}"
+
+LICENSE="GPL-2+"
+SLOT="0/$(ver_cut 1-2)"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="doc fpm grpc nhrp ospfapi pam rpki snmp test"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+RESTRICT="!test? ( test )"
+
+COMMON_DEPEND="
+ ${PYTHON_DEPS}
+ acct-user/frr
+ dev-libs/json-c:0=
+ dev-libs/protobuf-c:0=
+ >=net-libs/libyang-2.0.0
+ <net-libs/libyang-2.1.111
+ sys-libs/libcap
+ sys-libs/readline:0=
+ virtual/libcrypt:=
+ grpc? ( net-libs/grpc:= )
+ nhrp? ( net-dns/c-ares:0= )
+ pam? ( sys-libs/pam )
+ rpki? ( >=net-libs/rtrlib-0.8.0[ssh] )
+ snmp? ( net-analyzer/net-snmp:= )
+"
+BDEPEND="
+ sys-devel/flex
+ app-alternatives/yacc
+ doc? ( dev-python/sphinx )
+"
+DEPEND="
+ ${COMMON_DEPEND}
+ elibc_musl? ( sys-libs/queue-standalone )
+ test? (
+ $(python_gen_cond_dep 'dev-python/pytest[${PYTHON_USEDEP}]')
+ dev-util/cunit
+ )
+"
+RDEPEND="
+ ${COMMON_DEPEND}
+"
+
+PATCHES=(
+ "${FILESDIR}"/${PN}-7.5-ipctl-forwarding.patch
+ "${FILESDIR}"/${PN}-8.4.1-logrotate.patch
+ "${FILESDIR}"/${PN}-9.1-mimic-gnu-basename-api-for-non-glibc.patch
+)
+
+QA_CONFIG_IMPL_DECL_SKIP=(
+ mallinfo # No functional impact.
+ mallinfo2
+)
+
+src_prepare() {
+ default
+
+ python_fix_shebang tools
+ eautoreconf
+}
+
+src_configure() {
+ local myconf=(
+ LEX=flex
+ --with-pkg-extra-version="-gentoo"
+ --enable-configfile-mask=0640
+ --enable-logfile-mask=0640
+ --libdir="${EPREFIX}"/usr/lib/frr
+ --sbindir="${EPREFIX}"/usr/lib/frr
+ --libexecdir="${EPREFIX}"/usr/lib/frr
+ --sysconfdir="${EPREFIX}"/etc/frr
+ --localstatedir="${EPREFIX}"/run/frr
+ --with-moduledir="${EPREFIX}"/usr/lib/frr/modules
+ --enable-user=frr
+ --enable-group=frr
+ --enable-vty-group=frr
+ --enable-multipath=64
+ $(use_enable doc)
+ $(use_enable fpm)
+ $(use_enable grpc)
+ $(use_enable kernel_linux realms)
+ $(use_enable nhrp nhrpd)
+ $(usex ospfapi '--enable-ospfclient' '' '' '')
+ $(use_enable rpki)
+ $(use_enable snmp)
+ )
+
+ econf "${myconf[@]}"
+}
+
+src_compile() {
+ default
+
+ use doc && emake -C doc html
+}
+
+src_test() {
+ local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+ default
+}
+
+src_install() {
+ default
+ find "${ED}" -name '*.la' -delete || die
+
+ # Install user documentation if asked
+ use doc && dodoc -r doc/user/_build/html
+
+ # Create configuration directory with correct permissions
+ # Create logs directory with the correct permissions
+ diropts -ofrr -gfrr -m0775
+ keepdir /var/log/frr /etc/frr
+
+ # Install the default configuration files
+ insinto /etc/frr
+ doins tools/etc/frr/{vtysh.conf,frr.conf,daemons}
+
+ # Fix permissions/owners.
+ fowners frr:frr /etc/frr/{vtysh.conf,frr.conf,daemons}
+ fperms 640 /etc/frr/{vtysh.conf,frr.conf,daemons}
+
+ # Install logrotate configuration
+ insinto /etc/logrotate.d
+ newins redhat/frr.logrotate frr
+
+ # Install PAM configuration file
+ use pam && newpamd "${FILESDIR}"/frr.pam frr
+
+ # Install init scripts
+ systemd_dounit tools/frr.service
+ newinitd "${FILESDIR}"/frr-openrc-v2 frr
+
+ # Conflict files, installed by net-libs/libsmi, bug #758383
+ rm "${ED}"/usr/share/yang/ietf-interfaces.yang || die
+}