[gentoo-commits] repo/gentoo:master commit in: dev-util/lttng-tools/

["Florian Schmaus" <flow@gentoo.org>]

commit:     2d668327a99d351d58abbd96b931cedfb22ec41f
Author:     Stefan Cristian B. <stefan.cristian+git <AT> rogentos <DOT> ro>
AuthorDate: Mon Feb  3 10:40:49 2025 +0000
Commit:     Florian Schmaus <flow <AT> gentoo <DOT> org>
CommitDate: Mon Feb  3 16:30:11 2025 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=2d668327

dev-util/lttng-tools: add 2.12.17 (LTS version)

Bug: https://bugs.gentoo.org/948954
Closes: https://bugs.gentoo.org/949256
Closes: https://github.com/gentoo/gentoo/pull/40407
Signed-off-by: Stefan Cristian B. <stefan.cristian+git <AT> rogentos.ro>
Signed-off-by: Florian Schmaus <flow <AT> gentoo.org>

 dev-util/lttng-tools/Manifest                   |  1 +
 dev-util/lttng-tools/lttng-tools-2.12.17.ebuild | 54 +++++++++++++++++++++++++
 2 files changed, 55 insertions(+)

diff --git a/dev-util/lttng-tools/Manifest b/dev-util/lttng-tools/Manifest
index f1d95490141e..bc1ba823ec59 100644
--- a/dev-util/lttng-tools/Manifest
+++ b/dev-util/lttng-tools/Manifest
@@ -1 +1,2 @@
+DIST lttng-tools-2.12.17.tar.bz2 1627001 BLAKE2B db080e433320e1b9129a40e3e12bbf7c7071d80486953a6c2b2da3cdf8568d6ab8ed69fd61a477c56b940a3e144327ec4f813821f5e2bd2097a91c13a7276b35 SHA512 25480505e7f12b0a9abdfbbdc96cf12223a143bf13f436f2a1fbf616940323bcf088d51e0abcc72dad24cae237fca07620ff187ab437088e4ec808e6b47d4bb3
 DIST lttng-tools-2.13.14.tar.bz2 1932238 BLAKE2B f079051502d01ffc67c4f8f0bbcdf3a4428546c652dcc352918c4908a37aeb510dd66309306cec835297c8d2f276e5cbd22ea4efef6866d3c0c0cf8651d68ef8 SHA512 61bdebb539cfb4eb61c9806e98742f39dc032d849b03d90cdb98d1891bd5bfbd0cb1f54bbc7bf79a11505ce7fee558497312d650bb41f11f739884e7cb8a750f

diff --git a/dev-util/lttng-tools/lttng-tools-2.12.17.ebuild b/dev-util/lttng-tools/lttng-tools-2.12.17.ebuild
new file mode 100644
index 000000000000..8e98406e44ee
--- /dev/null
+++ b/dev-util/lttng-tools/lttng-tools-2.12.17.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit flag-o-matic
+
+# Please bump the following packages together:
+# dev-util/lttng-modules
+# dev-util/lttng-tools
+# dev-util/lttng-ust
+
+MY_P="${P/_rc/-rc}"
+MY_SLOT="$(ver_cut 1-2)"
+
+DESCRIPTION="Linux Trace Toolkit - next generation"
+HOMEPAGE="https://lttng.org"
+SRC_URI="https://lttng.org/files/${PN}/${MY_P}.tar.bz2"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="GPL-2"
+SLOT="0/${MY_SLOT}"
+KEYWORDS="~amd64 ~x86"
+IUSE="+ust"
+
+DEPEND="
+	>=dev-libs/userspace-rcu-0.11.0:=
+	dev-libs/popt
+	>=dev-libs/libxml2-2.7.6
+	ust? ( >=dev-util/lttng-ust-${MY_SLOT}.0:= )
+"
+RDEPEND="${DEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+QA_CONFIG_IMPL_DECL_SKIP=(
+	pthread_get_name_np # different from pthread_getname_*, not on linux
+	pthread_set_name_np # different from pthread_setname_*, not on linux
+)
+
+src_configure() {
+	# bug 906928
+	use elibc_musl && append-cppflags -D_LARGEFILE64_SOURCE
+
+	econf \
+		$(usex ust "" --without-lttng-ust) \
+		--disable-Werror \
+		--disable-test-sdt-uprobe \
+		--disable-test-python3-agent
+}
+
+src_install() {
+	default
+	find "${ED}" -type f -name '*.la' -delete || die
+}