[gentoo-commits] repo/proj/guru:dev commit in: net-voip/baresip/

["Dale Showers" <gentoo@fictx.com>]

commit:     34359c53beb15ca7c134e9ae2a21b39c94e0206e
Author:     Dale Showers <gentoo <AT> fictx <DOT> com>
AuthorDate: Wed Jan 15 13:31:50 2025 +0000
Commit:     Dale Showers <gentoo <AT> fictx <DOT> com>
CommitDate: Wed Jan 15 13:33:13 2025 +0000
URL:        https://gitweb.gentoo.org/repo/proj/guru.git/commit/?id=34359c53

net-voip/baresip: add 3.19.0

Signed-off-by: Dale Showers <gentoo <AT> fictx.com>

 net-voip/baresip/Manifest              |   1 +
 net-voip/baresip/baresip-3.19.0.ebuild | 109 +++++++++++++++++++++++++++++++++
 2 files changed, 110 insertions(+)

diff --git a/net-voip/baresip/Manifest b/net-voip/baresip/Manifest
index 45df4dd82..a7eda500f 100644
--- a/net-voip/baresip/Manifest
+++ b/net-voip/baresip/Manifest
@@ -1,2 +1,3 @@
 DIST baresip-3.17.0.tar.gz 1173530 BLAKE2B 34bebfa51f29da13017309af03dcdaa3adb5c7e8a4726f1700b3d7ab116c23edd6c01e452c2a50404d480532a74fd4d6a0515d1f1ea1444cbb01de8ef03e162b SHA512 3cd35f0ea34b21a1d9b7a7b140b0390becc14947c1fdd1fa0f6aa188efcc5e9f50d680ef334712dc294699b049d3014b4bd0a91c3380aabe5a6366a7400d48c9
 DIST baresip-3.18.0.tar.gz 1179585 BLAKE2B 658fbc810c2d4b80c285f1788ab520af9a02cfbb10145b18b756c5774acbea2d33b8dda9c60415e833320f3338aa658d0e5d9f41f3baff0422e180dc894f9e24 SHA512 98d7c73a23ae64964b82504dd3ddc1386d197a0da04af726b572364549b1c874829e7b4db4ec5fdf8eafd2ea4fb4a653dff4aec517036d7989a1cf6a6f38f8ac
+DIST baresip-3.19.0.tar.gz 1177190 BLAKE2B f14f580ebd4a9a4cf7ecaf172db317eefd3be5736c269ca78d2a7e3613583c4662717d1ec65d0828d6982cf5969b0ad96a61ca1573b7e0efb3d89014666a39d1 SHA512 b8a34b0103fbbe280a6ce1da11739d703904665e27b559effa8f22cfb1127ae6fe2adff7d3e1eb5836996845c898ac28081d301371393fe18c682da03ae5e622

diff --git a/net-voip/baresip/baresip-3.19.0.ebuild b/net-voip/baresip/baresip-3.19.0.ebuild
new file mode 100644
index 000000000..1e6ad4330
--- /dev/null
+++ b/net-voip/baresip/baresip-3.19.0.ebuild
@@ -0,0 +1,109 @@
+# Copyright 2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="Baresip is a portable and modular SIP User-Agent"
+HOMEPAGE="https://github.com/baresip/baresip"
+SRC_URI="https://github.com/baresip/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+
+IUSE="aac acip alsa amr aptx aom codec2 console dbus echo evdev ffmpeg gstreamer
+	  gtk3 jack httpd httpreq mpa mqtt opus pipewire portaudio pulseaudio sdl
+	  serreg snapshot sndfile spandsp static-libs syslog tcpcontrol v4l video vpx webrtc X"
+
+RE_PVF="$(ver_cut 1-2)*"
+
+DEPEND="
+	dev-libs/openssl:0=
+	=net-voip/re-${RE_PVF}
+	sys-libs/zlib
+	aac? ( media-libs/fdk-aac )
+	alsa? ( media-libs/alsa-lib )
+	amr? ( media-libs/opencore-amr )
+	aom? ( media-libs/libaom )
+	aptx? ( media-libs/libopenaptx )
+	codec2? ( media-libs/codec2 )
+	dbus? (
+		dev-util/gdbus-codegen
+		sys-apps/dbus
+	)
+	ffmpeg? ( media-video/ffmpeg )
+	gstreamer? (
+		media-libs/gstreamer:1.0
+		media-libs/gst-plugins-base:1.0
+		media-libs/gst-plugins-good:1.0
+	)
+	gtk3? ( x11-libs/gtk+:3 )
+	jack? ( virtual/jack )
+	mpa? (
+		media-sound/twolame
+		media-sound/mpg123
+		media-libs/speexdsp
+	)
+	mqtt? ( app-misc/mosquitto )
+	opus? ( media-libs/opus )
+	pipewire? ( media-video/pipewire )
+	snapshot? ( media-libs/libpng )
+	portaudio? ( media-libs/portaudio )
+	pulseaudio? ( media-libs/libpulse )
+	sdl? ( media-libs/libsdl2 )
+	sndfile? ( media-libs/libsndfile )
+	spandsp? ( media-libs/spandsp )
+	v4l? ( media-libs/libv4l )
+	vpx? ( media-libs/libvpx )
+	webrtc? ( media-plugins/gst-plugins-webrtc )
+	X? ( x11-libs/libX11 )
+	"
+
+RDEPEND="${DEPEND}"
+
+src_configure() {
+	use aac && MODULES+="aac;"
+	use acip && MODULES+="ebuacip;"
+	use alsa && MODULES+="alsa;"
+	use amr && MODULES+="amr;"
+	use aom && MODULES+="av1;"
+	use aptx && MODULES+="aptx;"
+	use codec2 && MODULES+="codec2;"
+	use console && MODULES+="cons;"
+	use dbus && MODULES+="ctrl_dbus;"
+	use evdev && MODULES+="evdev;"
+	use echo && MODULES+="echo;"
+	use gtk3 && MODULES+="gtk;"
+	use gstreamer && MODULES+="gst;"
+	use httpd && MODULES+="httpd;"
+	use httpreq && MODULES+="httpreq;"
+	use ffmpeg && MODULES+="avcodec;avfilter;avformat;selfview;swscale;"
+	use jack && MODULES+="jack;"
+	use mpa && MODULES+="mpa;"
+	use mqtt && MODULES+="mqtt;"
+	use opus && MODULES+="opus;opus_multistream;"
+	use pipewire && MODULES+="pipewire;"
+	use pulseaudio && MODULES+="pulse;"
+	use portaudio && MODULES+="portaudio;"
+	use serreg && MODULES+="serreg;"
+	use snapshot && MODULES+="snapshot;"
+	use sdl && MODULES+="sdl;"
+	use sndfile && MODULES+="sndfile;"
+	use spandsp && MODULES+="g722;g726;plc;"
+	use syslog && MODULES+="syslog;"
+	use tcpcontrol && MODULES+="ctrl_tcp;"
+	use v4l && MODULES+="v4l2;"
+	use video && MODULES+="vidbridge;vidinfo;"
+	use vpx && MODULES+="vp8;vp9;"
+	use webrtc && MODULES+="webrtc_aec;"
+	use X && MODULES+="x11;"
+	MODULES+="account;aubridge;auconv;aufile;auresamp;ausine;contact;debug_cmd;dtls_srtp;g711;ice;menu;mixausrc;mixminus;mwi;natpmp;netroam;pcp;presence;turn;rtcpsummary;srtp;stdio;stun;uuid;vumeter"
+
+	local mycmakeargs=(
+		-DMODULES="$MODULES"
+		-DSTATIC=$(usex static-libs ON OFF)
+	)
+	cmake_src_configure
+}