[gentoo-commits] repo/gentoo:master commit in: net-misc/tuba/

["Michał Górny" <mgorny@gentoo.org>]

commit:     1c770d4af14cf70293ab19dbae6461cbb3d1c13b
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Mon Jan  6 17:34:56 2025 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Mon Jan  6 17:37:04 2025 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1c770d4a

net-misc/tuba: Bump to 0.9.1

Closes: https://bugs.gentoo.org/946558
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 net-misc/tuba/Manifest          |  1 +
 net-misc/tuba/tuba-0.9.1.ebuild | 76 +++++++++++++++++++++++++++++++++++++++++
 2 files changed, 77 insertions(+)

diff --git a/net-misc/tuba/Manifest b/net-misc/tuba/Manifest
index f4c3c98ab68d..e035134408d1 100644
--- a/net-misc/tuba/Manifest
+++ b/net-misc/tuba/Manifest
@@ -1 +1,2 @@
 DIST Tuba-0.8.4.gh.tar.gz 1803987 BLAKE2B 9ec1647bc255a3cef37293fc86f81eed534f4a313e3ec0ab81318766972ed01100b30afcc05448f5344637da08962bb72dc2eb5d44fc0561ce1a61c48b9b8b5d SHA512 8484cdb898174958c1e79ddfd6fab9e74693bca19d1eddde504679d1074cac986580dcf2e2c98fa13ab54fec2a4ffc25b1977bc6e62f1b3a524a6810b2ac268f
+DIST Tuba-0.9.1.gh.tar.gz 2137594 BLAKE2B 1df526b4340896d367243eeee534b923554cf039368e851d82faa178b2d2bb43dc84612f0af209f4ded6e7902c47026dd2305b82159d8d92323810075c7daa43 SHA512 4c80fb98902359f9f8b59665ea580e477885d5de66e1d5640b67766fde49805702eababed4600b13afd6e8a16b5dbdc9b2391b0c8271eebdef70152c1b60f7a4

diff --git a/net-misc/tuba/tuba-0.9.1.ebuild b/net-misc/tuba/tuba-0.9.1.ebuild
new file mode 100644
index 000000000000..c1a37aee8975
--- /dev/null
+++ b/net-misc/tuba/tuba-0.9.1.ebuild
@@ -0,0 +1,76 @@
+# Copyright 2023-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome2-utils meson optfeature vala
+
+MY_P=${P^}
+DESCRIPTION="Browse the Fediverse (GTK client)"
+HOMEPAGE="
+	https://tuba.geopjr.dev/
+	https://github.com/GeopJr/Tuba/
+"
+SRC_URI="
+	https://github.com/GeopJr/Tuba/archive/v${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="GPL-3 CC-BY-SA-4.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+
+# TODO: optional dep on libspelling-1
+DEPEND="
+	app-crypt/libsecret[introspection,vala]
+	>=dev-libs/glib-2.76.0:2
+	dev-libs/icu:=
+	>=dev-libs/json-glib-1.4.4[introspection]
+	>=dev-libs/libgee-0.8.5:0.8[introspection]
+	dev-libs/libxml2
+	>=gui-libs/gtk-4.13.4:4[gstreamer,introspection]
+	>=gui-libs/libadwaita-1.5:1[introspection,vala]
+	>=gui-libs/gtksourceview-5.6.0:5[introspection,vala]
+	media-libs/gstreamer[introspection]
+	net-libs/libsoup:3.0[introspection,vala]
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	$(vala_depend)
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local emesonargs=(
+		# disable calling updaters (see pkg_post*)
+		-Ddistro=true
+		# not packaged
+		-Dclapper=false
+	)
+
+	vala_setup
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	dosym dev.geopjr.Tuba /usr/bin/tuba
+}
+
+pkg_postinst() {
+	optfeature "WebP image support" gui-libs/gdk-pixbuf-loader-webp
+
+	gnome2_schemas_update
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	gnome2_schemas_update
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}