[gentoo-commits] repo/gentoo:master commit in: net-irc/atheme-services/files/, net-irc/atheme-services/

[gentoo-commits] repo/gentoo:master commit in: net-irc/atheme-services/files/, net-irc/atheme-services/

[Joonas Niilola]

commit:     38170f3850411e75ec88aa94ce2210f63ed3b6d0
Author:     Wade Cline <wadecline <AT> hotmail <DOT> com>
AuthorDate: Mon Feb 27 02:37:41 2023 +0000
Commit:     Joonas Niilola <juippis <AT> gentoo <DOT> org>
CommitDate: Wed Mar  8 13:43:45 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=38170f38

net-irc/atheme-services: Add 7.2.12-r4

Bug: https://bugs.gentoo.org/895470
Signed-off-by: Wade Cline <wadecline <AT> hotmail.com>
Closes: https://github.com/gentoo/gentoo/pull/29821
Signed-off-by: Joonas Niilola <juippis <AT> gentoo.org>

 .../atheme-services-7.2.12-r4.ebuild               | 92 ++++++++++++++++++++++
 .../atheme-services/files/atheme-services.service  | 15 ++++
 2 files changed, 107 insertions(+)

diff --git a/net-irc/atheme-services/atheme-services-7.2.12-r4.ebuild b/net-irc/atheme-services/atheme-services-7.2.12-r4.ebuild
new file mode 100644
index 000000000000..1868e2015273
--- /dev/null
+++ b/net-irc/atheme-services/atheme-services-7.2.12-r4.ebuild
@@ -0,0 +1,92 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit perl-functions systemd
+
+DESCRIPTION="A portable and secure set of open-source and modular IRC services"
+HOMEPAGE="https://github.com/atheme/atheme"
+SRC_URI="https://github.com/atheme/atheme/releases/download/v${PV}/${PN}-v${PV}.tar.xz -> ${P}.tar.xz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64"
+IUSE="cracklib largenet ldap nls +pcre perl profile ssl"
+S="${WORKDIR}/${PN}-v${PV}"
+
+RDEPEND="
+	acct-group/atheme-services
+	acct-user/atheme-services
+	>=dev-libs/libmowgli-2.1.0:2
+	virtual/libcrypt:=
+	cracklib? ( sys-libs/cracklib )
+	ldap? ( net-nds/openldap:= )
+	perl? ( dev-lang/perl:= )
+	pcre? ( dev-libs/libpcre )
+	ssl? ( dev-libs/openssl:0= )"
+DEPEND="${RDEPEND}"
+# 'dev-vcs/git' required as per bug #665802
+BDEPEND="
+	dev-vcs/git
+	virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-7.2.10_p2-configure-logdir.patch)
+
+src_configure() {
+	# perl scriping module support is also broken in 7.0.0. Yay for QA failures.
+	econf \
+		--sysconfdir="${EPREFIX}"/etc/${PN} \
+		--localstatedir="${EPREFIX}"/var \
+		--enable-fhs-paths \
+		--disable-warnings \
+		--enable-contrib \
+		$(use_enable largenet large-net) \
+		$(use_with cracklib) \
+		$(use_with ldap) \
+		$(use_enable nls) \
+		$(use_enable profile) \
+		$(use_with pcre) \
+		$(use_with perl) \
+		$(use_enable ssl)
+}
+
+src_compile() {
+	emake V=1
+}
+
+src_install() {
+	default
+
+	insinto /etc/${PN}
+	for conf in dist/*.example; do
+		# The .cron file isn't meant to live in /etc/${PN}, so only
+		# install a .example version.
+		[[ ${conf} == *cron* ]] && continue
+
+		local confdest=${conf##*/}
+		newins ${conf} ${confdest%.example}
+	done
+
+	fowners -R 0:${PN} /etc/${PN}
+	keepdir /var/{lib,log}/atheme
+	fowners ${PN}:${PN} /var/{lib,log}/atheme
+	fperms -R go-w,o-rx /etc/${PN}
+	fperms 750 /etc/${PN} /var/{lib,log}/atheme
+
+	newinitd "${FILESDIR}"/${PN}.initd ${PN}
+	mv "${ED}"/usr/bin/{,atheme-}dbverify || die
+	systemd_dounit "${FILESDIR}"/${PN}.service
+
+	# contributed scripts and such:
+	docinto contrib
+	dodoc contrib/*.{c,pl,php,py,rb}
+
+	use perl && perl_domodule -r contrib/Atheme{,.pm}
+
+	rm "${ED}/usr/share/doc/${PF}/WINDOWS" || die
+
+	# Bug #454840 #520490
+	rm -rf "${ED}/var/run" || die
+}

diff --git a/net-irc/atheme-services/files/atheme-services.service b/net-irc/atheme-services/files/atheme-services.service
new file mode 100644
index 000000000000..a552ead5b413
--- /dev/null
+++ b/net-irc/atheme-services/files/atheme-services.service
@@ -0,0 +1,15 @@
+[Unit]
+Description=Atheme IRC services
+After=network-online.target
+Wants=network-online.target
+
+[Service]
+RuntimeDirectory=atheme
+ExecStart=/usr/bin/atheme-services
+ExecReload=kill -HUP $MAINPID
+Type=forking
+PIDFile=/run/atheme/atheme.pid
+User=atheme-services
+
+[Install]
+WantedBy=multi-user.target

[gentoo-commits] repo/gentoo:master commit in: net-irc/atheme-services/files/, net-irc/atheme-services/

[Sam James]

commit:     181986ebe563128879b90bef85c435e4544c75e2
Author:     Wade Cline <wadecline <AT> hotmail <DOT> com>
AuthorDate: Sat Nov 30 02:52:19 2024 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sun Dec 29 14:43:18 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=181986eb

net-irc/atheme-services: Bump to 7.2.12-r5

Backports a0410c3 from upstream which fixes a compilation failure.

Closes: https://bugs.gentoo.org/944125
Signed-off-by: Wade Cline <wadecline <AT> hotmail.com>
Closes: https://github.com/gentoo/gentoo/pull/39529
Signed-off-by: Sam James <sam <AT> gentoo.org>

 ...-r4.ebuild => atheme-services-7.2.12-r5.ebuild} |  7 ++--
 ...e-account-fix-assertion-macro-return-type.patch | 37 ++++++++++++++++++++++
 2 files changed, 41 insertions(+), 3 deletions(-)

diff --git a/net-irc/atheme-services/atheme-services-7.2.12-r4.ebuild b/net-irc/atheme-services/atheme-services-7.2.12-r5.ebuild
similarity index 92%
rename from net-irc/atheme-services/atheme-services-7.2.12-r4.ebuild
rename to net-irc/atheme-services/atheme-services-7.2.12-r5.ebuild
index 335443e95737..fdcf9d3dbdbc 100644
--- a/net-irc/atheme-services/atheme-services-7.2.12-r4.ebuild
+++ b/net-irc/atheme-services/atheme-services-7.2.12-r5.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2023 Gentoo Authors
+# Copyright 1999-2024 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
@@ -9,11 +9,11 @@ DESCRIPTION="A portable and secure set of open-source and modular IRC services"
 HOMEPAGE="https://github.com/atheme/atheme"
 SRC_URI="https://github.com/atheme/atheme/releases/download/v${PV}/${PN}-v${PV}.tar.xz -> ${P}.tar.xz"
 
+S="${WORKDIR}/${PN}-v${PV}"
 LICENSE="BSD"
 SLOT="0"
 KEYWORDS="amd64 ~arm ~arm64"
 IUSE="cracklib largenet ldap nls +pcre perl profile ssl"
-S="${WORKDIR}/${PN}-v${PV}"
 
 RDEPEND="
 	acct-group/atheme-services
@@ -32,7 +32,8 @@ BDEPEND="
 	virtual/pkgconfig"
 
 PATCHES=(
-	"${FILESDIR}"/${PN}-7.2.10_p2-configure-logdir.patch)
+	"${FILESDIR}"/${PN}-7.2.10_p2-configure-logdir.patch
+	"${FILESDIR}"/${PN}-7.2.12-libathemecore-account-fix-assertion-macro-return-type.patch)
 
 src_configure() {
 	# perl scriping module support is also broken in 7.0.0. Yay for QA failures.

diff --git a/net-irc/atheme-services/files/atheme-services-7.2.12-libathemecore-account-fix-assertion-macro-return-type.patch b/net-irc/atheme-services/files/atheme-services-7.2.12-libathemecore-account-fix-assertion-macro-return-type.patch
new file mode 100644
index 000000000000..26cc3829346c
--- /dev/null
+++ b/net-irc/atheme-services/files/atheme-services-7.2.12-libathemecore-account-fix-assertion-macro-return-type.patch
@@ -0,0 +1,37 @@
+From a0410c301293736a09b52763d25893019ede3e3a Mon Sep 17 00:00:00 2001
+From: Aaron Jones <me@aaronmdjones.net>
+Date: Mon, 25 Nov 2024 05:31:26 +0000
+Subject: [PATCH] libathemecore/account: fix assertion macro return
+ types/values
+
+---
+ libathemecore/account.c | 6 +++---
+ 1 file changed, 3 insertions(+), 3 deletions(-)
+
+diff --git a/libathemecore/account.c b/libathemecore/account.c
+index 80233ade2..985cf9ff6 100644
+--- a/libathemecore/account.c
++++ b/libathemecore/account.c
+@@ -1631,7 +1631,7 @@ chanacs_t *chanacs_find_host_by_user(mychan_t *mychan, user_t *u, unsigned int l
+ 	mowgli_node_t *n;
+ 	chanacs_t *ca;
+ 
+-	return_val_if_fail(mychan != NULL && u != NULL, 0);
++	return_val_if_fail(mychan != NULL && u != NULL, NULL);
+ 
+ 	for (n = next_matching_host_chanacs(mychan, u, mychan->chanacs.head); n != NULL; n = next_matching_host_chanacs(mychan, u, n->next))
+ 	{
+@@ -1779,8 +1779,8 @@ chanacs_t *chanacs_open(mychan_t *mychan, myentity_t *mt, const char *hostmask,
+ 	chanacs_t *ca;
+ 
+ 	/* wrt the second assert: only one of mu or hostmask can be not-NULL --nenolod */
+-	return_val_if_fail(mychan != NULL, false);
+-	return_val_if_fail((mt != NULL && hostmask == NULL) || (mt == NULL && hostmask != NULL), false);
++	return_val_if_fail(mychan != NULL, NULL);
++	return_val_if_fail((mt != NULL && hostmask == NULL) || (mt == NULL && hostmask != NULL), NULL);
+ 
+ 	if (mt != NULL)
+ 	{
+-- 
+2.45.2
+