[gentoo-commits] repo/gentoo:master commit in: media-libs/libvpl-tools/

["Nowa Ammerlaan" <nowa@gentoo.org>]

commit:     4076df7cc7f5236fad8c314de11a80f82928fc21
Author:     Nowa Ammerlaan <nowa <AT> gentoo <DOT> org>
AuthorDate: Thu Dec 26 12:05:56 2024 +0000
Commit:     Nowa Ammerlaan <nowa <AT> gentoo <DOT> org>
CommitDate: Thu Dec 26 12:06:08 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=4076df7c

media-libs/libvpl-tools: add 1.3.0

Signed-off-by: Nowa Ammerlaan <nowa <AT> gentoo.org>

 media-libs/libvpl-tools/Manifest                  |  1 +
 media-libs/libvpl-tools/libvpl-tools-1.3.0.ebuild | 73 +++++++++++++++++++++++
 2 files changed, 74 insertions(+)

diff --git a/media-libs/libvpl-tools/Manifest b/media-libs/libvpl-tools/Manifest
index d30f5c473cbd..8226751ddb7e 100644
--- a/media-libs/libvpl-tools/Manifest
+++ b/media-libs/libvpl-tools/Manifest
@@ -1 +1,2 @@
 DIST libvpl-tools-1.2.0.tar.gz 1294249 BLAKE2B 8a9e8db303d7b0632c7a0e8b03fa1ebff79dedbe581e185824f731415fb3bb9bc58712551ccea9354d0f8b04755efc222c27d1b1e9f6a34d7fd1982d89bb4dd5 SHA512 e44e752aec48673ff93c7d6eaa9363150607e299008b5df6bed2a6373355c37483d68d703b2e45586ff6062a83ef87fabbd70c034926389873bb3470b1712bc4
+DIST libvpl-tools-1.3.0.tar.gz 1303138 BLAKE2B 7b219049e837b71cd2ce4f9d5b152873d5a6d9fea642b2908e7132d5d38c72cc251be4d9113f658452d2064486f2d4ebe9036b40ee1680792afd2b893b6cd9fe SHA512 8aa91258a78bdbb1ab3814f3f7a3647e95b01a0f580bee8e5b66fdb850eec3e63250ea31897c462c747ed9ceff03593e800d22f899bd453617b4be20cf50596b

diff --git a/media-libs/libvpl-tools/libvpl-tools-1.3.0.ebuild b/media-libs/libvpl-tools/libvpl-tools-1.3.0.ebuild
new file mode 100644
index 000000000000..bb09032dafcc
--- /dev/null
+++ b/media-libs/libvpl-tools/libvpl-tools-1.3.0.ebuild
@@ -0,0 +1,73 @@
+# Copyright 2022-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="Intel Video Processing Library tools"
+HOMEPAGE="https://github.com/intel/libvpl-tools/"
+SRC_URI="https://github.com/intel/libvpl-tools/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+IUSE="dri +drm opencl test +vaapi wayland X"
+RESTRICT="!test? ( test )"
+
+REQUIRED_USE="
+	dri? ( X )
+	opencl? ( X )
+	vaapi? ( drm )
+	wayland? ( vaapi )
+	X? ( vaapi )
+"
+
+RDEPEND="
+	drm? ( x11-libs/libdrm[video_cards_intel] )
+	opencl? ( virtual/opencl )
+	vaapi? ( media-libs/libva[X?,wayland?,drm(+)?] )
+	wayland? (
+		dev-libs/wayland
+	)
+	X? (
+		x11-libs/libX11
+		x11-libs/libxcb
+	)
+	x11-libs/libpciaccess
+	>=media-libs/libvpl-2.11.0:=
+"
+
+DEPEND="${RDEPEND}
+	wayland? (
+		dev-libs/wayland-protocols
+	)
+"
+
+BDEPEND="virtual/pkgconfig"
+
+PATCHES=( "${FILESDIR}"/${PN}-1.2.0_do-not-fortify-source.patch )
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_SHARED_LIBS=ON
+		-DBUILD_TESTS="$(usex test)"
+
+		-DBUILD_EXPERIMENTAL="$(usex X)"
+		-DTOOLS_ENABLE_X11="$(usex X)"
+		-DTOOLS_ENABLE_SCREEN_CAPTURE="$(usex X)"
+		-DTOOLS_ENABLE_RENDER="$(usex X)"
+		-DTOOLS_ENABLE_OPENCL="$(usex opencl)"
+
+		-DENABLE_DRI3="$(usex dri)"
+		-DENABLE_DRM="$(usex drm)"
+		-DENABLE_VA="$(usex vaapi)"
+		-DENABLE_WAYLAND="$(usex wayland)"
+		-DENABLE_X11="$(usex X)"
+
+		-DCMAKE_INSTALL_PREFIX="${EPREFIX}/usr"
+		-DCMAKE_INSTALL_SYSCONFDIR="${EPREFIX}/etc"
+	)
+	cmake_src_configure
+}