[gentoo-commits] repo/gentoo:master commit in: x11-apps/igt-gpu-tools/

["Matt Turner" <mattst88@gentoo.org>]

commit:     3594c97e66fe202b79de95d0efc6578604e021b4
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Mon Dec 16 18:49:21 2024 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Mon Dec 16 18:53:32 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=3594c97e

x11-apps/igt-gpu-tools: Version bump to 1.30

Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 x11-apps/igt-gpu-tools/Manifest                  |   1 +
 x11-apps/igt-gpu-tools/igt-gpu-tools-1.30.ebuild | 105 +++++++++++++++++++++++
 2 files changed, 106 insertions(+)

diff --git a/x11-apps/igt-gpu-tools/Manifest b/x11-apps/igt-gpu-tools/Manifest
index f69cc606fd4e..d3dd6933467d 100644
--- a/x11-apps/igt-gpu-tools/Manifest
+++ b/x11-apps/igt-gpu-tools/Manifest
@@ -1 +1,2 @@
 DIST igt-gpu-tools-1.29.tar.xz 2944444 BLAKE2B 8d34a2b1a9dfc6d8a23be6d2a45436f531e98f0aa8b05346d5a4f2232d4904fc12cb7a986ee335b2a9a31760de10cfed0d92b7de6052ed75baeadc190c5ebee9 SHA512 1bce6cc916b79bee3562cdee945444bfe925efac37c0df61f8adc17b1aade752cb2e31a05c0dc5de5f2c54256f3319cab7ee45014d5d910e16cca50accd2d1ed
+DIST igt-gpu-tools-1.30.tar.xz 3079568 BLAKE2B 0be7a31d5ca472d6011abc271d4fd5c1c34e7e458a510dab1d99e56bed87d9923a757aced407e5b2cf72b37c074d62fe3fcdefb0fc75c43f439650f129b51005 SHA512 be0af7c7b3bbf6d47ac5267b6be9af356cfd148f2588d624635e642299df0ab0a825bc1498c6ba2b9f8b6c1e4f0126b6fdf22c82548bfa1df1906efad492db60

diff --git a/x11-apps/igt-gpu-tools/igt-gpu-tools-1.30.ebuild b/x11-apps/igt-gpu-tools/igt-gpu-tools-1.30.ebuild
new file mode 100644
index 000000000000..7610ba673ffb
--- /dev/null
+++ b/x11-apps/igt-gpu-tools/igt-gpu-tools-1.30.ebuild
@@ -0,0 +1,105 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+EGIT_REPO_URI="https://gitlab.freedesktop.org/drm/${PN}.git"
+if [[ ${PV} = *9999* ]]; then
+	GIT_ECLASS="git-r3"
+fi
+
+PYTHON_COMPAT=( python3_{10..13} )
+inherit ${GIT_ECLASS} meson python-any-r1
+
+DESCRIPTION="Intel GPU userland tools"
+
+HOMEPAGE="https://gitlab.freedesktop.org/drm/igt-gpu-tools"
+if [[ ${PV} != *9999* ]]; then
+	KEYWORDS="~amd64 ~x86"
+	SRC_URI="https://www.x.org/releases/individual/app/${P}.tar.xz"
+fi
+LICENSE="MIT"
+SLOT="0"
+IUSE="chamelium man overlay runner tests unwind valgrind video_cards_amdgpu video_cards_intel video_cards_nouveau X xv"
+REQUIRED_USE="
+	|| ( video_cards_amdgpu video_cards_intel video_cards_nouveau )
+	overlay? (
+		video_cards_intel
+		|| ( X xv )
+	)
+	runner? ( tests )
+"
+RESTRICT="test"
+
+RDEPEND="
+	dev-libs/elfutils
+	dev-libs/glib:2
+	sys-apps/kmod
+	sys-libs/zlib:=
+	sys-process/procps:=
+	virtual/libudev:=
+	>=x11-libs/cairo-1.12.0[X?]
+	>=x11-libs/libdrm-2.4.82[video_cards_amdgpu?,video_cards_intel?,video_cards_nouveau?]
+	>=x11-libs/libpciaccess-0.10
+	x11-libs/pixman
+	chamelium? (
+		dev-libs/xmlrpc-c:=[curl]
+		sci-libs/gsl:=
+		media-libs/alsa-lib
+	)
+	overlay? (
+		>=x11-libs/libXrandr-1.3
+		xv? (
+			x11-libs/libX11
+			x11-libs/libXext
+			x11-libs/libXv
+		)
+	)
+	runner? ( dev-libs/json-c:= )
+	unwind? ( sys-libs/libunwind:= )
+	valgrind? ( dev-debug/valgrind )
+	"
+DEPEND="${RDEPEND}
+	man? ( dev-python/docutils )
+	overlay? (
+		>=dev-util/peg-0.1.18
+		x11-base/xorg-proto
+	)
+	video_cards_intel? (
+		app-alternatives/yacc
+		app-alternatives/lex
+	)
+"
+BDEPEND="${PYTHON_DEPS}"
+
+src_prepare() {
+	sed -e "s/find_program('rst2man-3'/find_program('rst2man.py', 'rst2man-3'/" -i man/meson.build
+	default_src_prepare
+}
+
+src_configure() {
+	local gpus=""
+	use video_cards_amdgpu  && gpus+="amdgpu,"
+	use video_cards_intel   && gpus+="intel,"
+	use video_cards_nouveau && gpus+="nouveau,"
+
+	local overlay_backends=""
+	use overlay && use xv && overlay_backends+="xv,"
+	use overlay && use X && overlay_backends+="x,"
+
+	local emesonargs=(
+		$(meson_feature overlay)
+		-Doverlay_backends=${overlay_backends%?}
+		$(meson_feature chamelium)
+		$(meson_feature valgrind)
+		$(meson_feature man)
+		-Dtestplan=disabled
+		-Dsphinx=disabled
+		-Ddocs=disabled
+		$(meson_feature tests)
+		-Dxe_driver=disabled
+		-Dlibdrm_drivers=${gpus%?}
+		$(meson_feature unwind libunwind)
+		$(meson_feature runner)
+	)
+	meson_src_configure
+}