[gentoo-commits] repo/gentoo:master commit in: app-misc/ebusd/

[gentoo-commits] repo/gentoo:master commit in: app-misc/ebusd/

[Conrad Kostecki]

commit:     873749210ae9f03be99cec8c8045c68e75d3603e
Author:     Conrad Kostecki <conikost <AT> gentoo <DOT> org>
AuthorDate: Sat Nov  2 12:30:22 2024 +0000
Commit:     Conrad Kostecki <conikost <AT> gentoo <DOT> org>
CommitDate: Sat Nov  2 12:31:11 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=87374921

app-misc/ebusd: add 24.1

Signed-off-by: Conrad Kostecki <conikost <AT> gentoo.org>

 app-misc/ebusd/Manifest          |  1 +
 app-misc/ebusd/ebusd-24.1.ebuild | 97 ++++++++++++++++++++++++++++++++++++++++
 2 files changed, 98 insertions(+)

diff --git a/app-misc/ebusd/Manifest b/app-misc/ebusd/Manifest
index d3d06c704d6f..cad87b2dc9b1 100644
--- a/app-misc/ebusd/Manifest
+++ b/app-misc/ebusd/Manifest
@@ -1 +1,2 @@
 DIST ebusd-23.3.tar.gz 583788 BLAKE2B c61bf76e0c451672432689aeaf10b317adb52729ea0872cb01dca22e1f7ac12091d287dd082b87361ce37846b1d74c869588964f3dc71e82ffd00c4555e27150 SHA512 acf155d36e99db1c9c2ff04eabbfddba8493f2566b6691f609c86af0e42e3cb0594618fd51e874e475cfc7b9c742d1e010099f38e19c21f52c953ebcfb0f2ea2
+DIST ebusd-24.1.tar.gz 595318 BLAKE2B 40bbedf1af983c8bbb123b8774b013d02e8f49d653e729d5b6bf78cda50d70ff5b09bfe5993714cf311d5b90777bf6e6616557cef881120b0cad56fc7a5ac0e9 SHA512 a4ab5e21f345894c29b7af84f46f93ac4a3ee658d69ca7fb002d52233e8c041043df328212cbeae4f01220e7a6bf4ec8a26ad3757eb0cf6da157d237f5b6b0b6

diff --git a/app-misc/ebusd/ebusd-24.1.ebuild b/app-misc/ebusd/ebusd-24.1.ebuild
new file mode 100644
index 000000000000..4cbc1244471c
--- /dev/null
+++ b/app-misc/ebusd/ebusd-24.1.ebuild
@@ -0,0 +1,97 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools systemd
+
+DESCRIPTION="Daemon for communication with eBUS heating systems"
+HOMEPAGE="
+	https://ebusd.de
+	https://github.com/john30/ebusd
+"
+SRC_URI="https://github.com/john30/${PN}/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+contrib doc knx mqtt +ssl test"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	dev-libs/openssl:0=
+	mqtt? ( app-misc/mosquitto )
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	doc? (
+		app-text/doxygen
+		media-gfx/graphviz
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-23.3-gentoo.patch"
+	"${FILESDIR}/${PN}-23.3-htmlpath.patch"
+)
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	# KNXd is currently not packaged in Gentoo
+	local myeconfargs=(
+		$(use_with contrib)
+		$(usex doc '--with-docs' '')
+		$(use_with knx)
+		$(use_with mqtt)
+		$(use_with ssl)
+
+		--localstatedir="${EPREFIX}/var"
+		--without-knxd
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+	default
+
+	if use test; then
+		pushd src/lib/ebus/test || die
+			emake
+		popd || die
+
+		if use contrib; then
+			pushd src/lib/ebus/contrib/test || die
+				emake
+			popd || die
+		fi
+	fi
+}
+
+src_test() {
+	pushd src/lib/ebus/test || die
+		./test_filereader >/dev/null && \
+		./test_data >/dev/null && \
+		./test_message >/dev/null && \
+		./test_symbol >/dev/null && \
+		einfo "standard: OK!" || die
+	popd || die
+
+	if use contrib; then
+		pushd src/lib/ebus/contrib/test || die
+			./test_contrib >/dev/null && einfo "contrib: OK!" || die
+		popd || die
+	fi
+}
+
+src_install() {
+	default
+	use doc && dodoc -r docs/html
+	newinitd "${FILESDIR}"/ebusd.initd-r1 ebusd
+	newconfd "${FILESDIR}"/ebusd.confd ebusd
+	systemd_newunit "${FILESDIR}"/ebusd.service-r1 ebusd.service
+}

[gentoo-commits] repo/gentoo:master commit in: app-misc/ebusd/

[Conrad Kostecki]

commit:     105c00fa490aeee613b853f0e8c5009f5861485b
Author:     Conrad Kostecki <conikost <AT> gentoo <DOT> org>
AuthorDate: Fri Dec  6 22:59:54 2024 +0000
Commit:     Conrad Kostecki <conikost <AT> gentoo <DOT> org>
CommitDate: Fri Dec  6 23:11:27 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=105c00fa

app-misc/ebusd: amd64 x86 stable

Signed-off-by: Conrad Kostecki <conikost <AT> gentoo.org>

 app-misc/ebusd/ebusd-24.1.ebuild | 2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)

diff --git a/app-misc/ebusd/ebusd-24.1.ebuild b/app-misc/ebusd/ebusd-24.1.ebuild
index 4cbc1244471c..450fd60f1c65 100644
--- a/app-misc/ebusd/ebusd-24.1.ebuild
+++ b/app-misc/ebusd/ebusd-24.1.ebuild
@@ -14,7 +14,7 @@ SRC_URI="https://github.com/john30/${PN}/archive/refs/tags/${PV}.tar.gz -> ${P}.
 
 LICENSE="GPL-3+"
 SLOT="0"
-KEYWORDS="~amd64 ~x86"
+KEYWORDS="amd64 x86"
 IUSE="+contrib doc knx mqtt +ssl test"
 RESTRICT="!test? ( test )"