[gentoo-commits] repo/gentoo:master commit in: app-emulation/ruffle/

["Ionen Wolkens" <ionen@gentoo.org>]

commit:     bf03d907550f079365e9e16afa88837ff180846e
Author:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
AuthorDate: Fri Nov 29 02:41:23 2024 +0000
Commit:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
CommitDate: Fri Nov 29 03:11:42 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=bf03d907

app-emulation/ruffle: drop 0_p20240929-r1

Signed-off-by: Ionen Wolkens <ionen <AT> gentoo.org>

 app-emulation/ruffle/Manifest                     |   2 -
 app-emulation/ruffle/ruffle-0_p20240929-r1.ebuild | 118 ----------------------
 2 files changed, 120 deletions(-)

diff --git a/app-emulation/ruffle/Manifest b/app-emulation/ruffle/Manifest
index 06b2e8ca1dc1..0cd7d44eb07c 100644
--- a/app-emulation/ruffle/Manifest
+++ b/app-emulation/ruffle/Manifest
@@ -1,4 +1,2 @@
-DIST ruffle-nightly-2024-09-29-vendor.tar.xz 68100452 BLAKE2B 31644cd0015e54ac784be531587c2d44412dcf68dbefd391df44268b31925262bf6ea676ab0a5cbf15d81494109db328b4519742bff61558608a3baf795ff8bc SHA512 1ee34f2fdecb5cc2bf5fdf7d728185a74ca72caf2295096842e557a321e54bc9ae4812c46f18ef42c2033703e26ef4edb124fc0a2a7ad8a9dfb2671473082a31
-DIST ruffle-nightly-2024-09-29.tar.gz 93467899 BLAKE2B 9a9c10686e161ce913892279378bca6c4aea67397bad6fb500e18d5362ee9c6303fcb20238dd8e1fbdb3cbeaa2eaa623eb3b5f2b8c7c9f2ca061c1edb5cc239b SHA512 1a835c5fcb7e6420cea5680af6d14e0bf8d889823b5f2617373aeec88511a31300441c869b53e01e32900e8cb1b2a9e69d52434dc4586354d266a8b6a99af2bb
 DIST ruffle-nightly-2024-10-27-vendor.tar.xz 68393412 BLAKE2B 16a3cb7a16900d21c91e900d0dc8b1036120abd2168fea2482473bb9c2170de4e1d5619fad15dd8b9df44228b93167f1b722311f7f54a5dff1a9c78682fdf04a SHA512 d085af00d4417e961bf7e05b7af1c70f222ac1277c701d67ce99084f85648eba521273269732d74ddc281fb71c8762646cd15c6f1f1a05da788f04ea302696b0
 DIST ruffle-nightly-2024-10-27.tar.gz 93507412 BLAKE2B fcbcd5639bffa8fd1157e1f19765e7ea6721073fc9af6579562a5412d1d07086f53de7d099001ab4eb1b4d497077f09dd1a6da6eaf92c71f12cd1c61633d6f78 SHA512 19790a6641c61ef7e2c1ec94039452c06ea95273de2868198a307d21da955d4196ae33e0807c8f8c74e3f996dc8e26bebdd59ad8bdfa40c9fe6a8afcc745e91f

diff --git a/app-emulation/ruffle/ruffle-0_p20240929-r1.ebuild b/app-emulation/ruffle/ruffle-0_p20240929-r1.ebuild
deleted file mode 100644
index 47beaf5f8067..000000000000
--- a/app-emulation/ruffle/ruffle-0_p20240929-r1.ebuild
+++ /dev/null
@@ -1,118 +0,0 @@
-# Copyright 2021-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-RUST_MIN_VER="1.81.0"
-
-inherit cargo desktop optfeature xdg
-
-if [[ ${PV} == 9999 ]]; then
-	EGIT_REPO_URI="https://github.com/ruffle-rs/ruffle.git"
-	inherit git-r3
-else
-	MY_PV=nightly-${PV:3:4}-${PV:7:2}-${PV:9:2}
-	MY_P=${PN}-${MY_PV}
-	SRC_URI="
-		https://github.com/ruffle-rs/ruffle/archive/refs/tags/${MY_PV}.tar.gz
-			-> ${MY_P}.tar.gz
-		https://dev.gentoo.org/~ionen/distfiles/${MY_P}-vendor.tar.xz
-	"
-	S=${WORKDIR}/${MY_P}
-	KEYWORDS="amd64"
-fi
-
-DESCRIPTION="Flash Player emulator written in Rust"
-HOMEPAGE="https://ruffle.rs/"
-
-LICENSE="|| ( Apache-2.0 MIT )"
-LICENSE+="
-	Apache-2.0 BSD-2 BSD Boost-1.0 CC0-1.0 ISC UbuntuFontLicense-1.0 MIT
-	MPL-2.0 OFL-1.1 openssl Unicode-3.0 Unicode-DFS-2016 ZLIB
-" # crates
-SLOT="0"
-IUSE="test"
-RESTRICT="!test? ( test )"
-
-# dlopen: libX* (see winit+x11-dl crates)
-RDEPEND="
-	media-libs/alsa-lib
-	virtual/libudev:=
-	x11-libs/libX11
-	x11-libs/libXcursor
-	x11-libs/libXrandr
-	x11-libs/libXrender
-"
-DEPEND="
-	${RDEPEND}
-	x11-base/xorg-proto
-"
-BDEPEND="
-	virtual/jre:*
-	virtual/pkgconfig
-"
-
-QA_FLAGS_IGNORED="usr/bin/${PN}.*"
-
-PATCHES=(
-	"${FILESDIR}"/${PN}-0_p20231216-skip-render-tests.patch
-)
-
-src_unpack() {
-	if [[ ${PV} == 9999 ]]; then
-		git-r3_src_unpack
-		cargo_live_src_unpack
-	else
-		cargo_src_unpack
-	fi
-}
-
-src_configure() {
-	local workspaces=(
-		ruffle_{desktop,scanner}
-		exporter
-		$(usev test tests)
-	)
-
-	cargo_src_configure "${workspaces[@]/#/--package=}"
-}
-
-src_test() {
-	local skip=(
-		# may need more investigation, strangely "pass" (xfail) when
-		# RUSTFLAGS is unset, skip for now (bug #915726)
-		--skip from_avmplus/as3/Types/Int/wraparound
-	)
-
-	cargo_src_test -- "${skip[@]}"
-}
-
-src_install() {
-	dodoc README.md
-
-	newicon web/packages/extension/assets/images/icon180.png ${PN}.png
-	make_desktop_entry ${PN} ${PN^} ${PN} "AudioVideo;Player;Emulator;" \
-		"MimeType=application/x-shockwave-flash;application/vnd.adobe.flash.movie;"
-
-	cd "$(cargo_target_dir)" || die
-	newbin ${PN}_desktop ${PN}
-	newbin exporter ${PN}_exporter
-	dobin ${PN}_scanner
-}
-
-pkg_postinst() {
-	xdg_pkg_postinst
-
-	if [[ ! ${REPLACING_VERSIONS} ]]; then
-		elog "${PN} is experimental software that is still under heavy development"
-		elog "and only receiving nightly releases. Plans in Gentoo is to update"
-		elog "roughly every months if no known major regressions (feel free to"
-		elog "report if you feel a newer nightly is needed ahead of time)."
-		elog
-		elog "There is currently no plans to support wasm builds / browser"
-		elog "extensions, this provides the desktop viewer and other tools."
-	fi
-
-	optfeature "h264 video decoding" media-libs/openh264
-	optfeature "the in-application file picker" sys-apps/xdg-desktop-portal
-}