[gentoo-commits] repo/gentoo:master commit in: net-dialup/xl2tpd/

["Sam James" <sam@gentoo.org>]

commit:     e876bbbcba2e9e3192693e894ef4f38557de74be
Author:     Jaco Kroon <jaco <AT> uls <DOT> co <DOT> za>
AuthorDate: Wed Nov 20 22:23:43 2024 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sun Nov 24 23:18:34 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e876bbbc

net-dialup/xl2tpd: drop 1.3.18-r1

Signed-off-by: Jaco Kroon <jaco <AT> uls.co.za>
Closes: https://github.com/gentoo/gentoo/pull/39392
Signed-off-by: Sam James <sam <AT> gentoo.org>

 net-dialup/xl2tpd/xl2tpd-1.3.18-r1.ebuild | 68 -------------------------------
 1 file changed, 68 deletions(-)

diff --git a/net-dialup/xl2tpd/xl2tpd-1.3.18-r1.ebuild b/net-dialup/xl2tpd/xl2tpd-1.3.18-r1.ebuild
deleted file mode 100644
index 6bc1880d53d6..000000000000
--- a/net-dialup/xl2tpd/xl2tpd-1.3.18-r1.ebuild
+++ /dev/null
@@ -1,68 +0,0 @@
-# Copyright 1999-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit systemd toolchain-funcs tmpfiles
-
-DESCRIPTION="A modern version of the Layer 2 Tunneling Protocol (L2TP) daemon"
-HOMEPAGE="https://github.com/xelerance/xl2tpd"
-SRC_URI="https://github.com/xelerance/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
-
-LICENSE="GPL-2+"
-SLOT="0"
-KEYWORDS="amd64 ~arm arm64 ~loong ~mips ~ppc ppc64 ~riscv x86"
-IUSE="+kernel"
-
-DEPEND="
-	net-libs/libpcap
-	>=sys-kernel/linux-headers-2.6"
-
-RDEPEND="
-	${DEPEND}
-	net-dialup/ppp"
-
-DOCS=( CREDITS README.md BUGS CHANGES TODO doc/README.patents )
-
-PATCHES=(
-	"${FILESDIR}/xl2tpd-1.3.18-r1-close-calls-when-pppd-terminates.patch"
-)
-
-src_prepare() {
-	default
-	sed -e 's:/var/run/:/run/:' -i \
-		file.h \
-		l2tp.h \
-		xl2tpd-control.c \
-		doc/l2tp-secrets.5 \
-		doc/xl2tpd.8 \
-		doc/xl2tpd.conf.5 \
-		|| die "Error updating /var/run to /run"
-}
-
-src_compile() {
-	tc-export CC
-	local OSFLAGS="-DLINUX"
-	use kernel && OSFLAGS+=" -DUSE_KERNEL"
-	emake OSFLAGS="${OSFLAGS}"
-}
-
-src_install() {
-	emake PREFIX=/usr DESTDIR="${D}" install
-
-	newinitd "${FILESDIR}"/xl2tpd-init-r1 xl2tpd
-
-	systemd_dounit "${FILESDIR}"/xl2tpd.service
-	dotmpfiles "${FILESDIR}"/xl2tpd.conf
-
-	einstalldocs
-
-	insinto /etc/xl2tpd
-	newins doc/l2tpd.conf.sample xl2tpd.conf
-	insopts -m 0600
-	newins doc/l2tp-secrets.sample l2tp-secrets
-}
-
-pkg_postinst() {
-	tmpfiles_process xl2tpd.conf
-}