[gentoo-commits] repo/gentoo:master commit in: dev-dotnet/dotnet-sdk-bin/

["Maciej Barć" <xgqt@gentoo.org>]

commit:     f35587f358896e44c049d807988245a172c24074
Author:     Maciej Barć <xgqt <AT> gentoo <DOT> org>
AuthorDate: Tue Nov 19 19:01:50 2024 +0000
Commit:     Maciej Barć <xgqt <AT> gentoo <DOT> org>
CommitDate: Tue Nov 19 19:52:05 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f35587f3

dev-dotnet/dotnet-sdk-bin: drop old 9.0.100.1.24452.12_rc

Signed-off-by: Maciej Barć <xgqt <AT> gentoo.org>

 dev-dotnet/dotnet-sdk-bin/Manifest                 |   6 -
 .../dotnet-sdk-bin-9.0.100.1.24452.12_rc.ebuild    | 174 ---------------------
 2 files changed, 180 deletions(-)

diff --git a/dev-dotnet/dotnet-sdk-bin/Manifest b/dev-dotnet/dotnet-sdk-bin/Manifest
index d84575e99458..2a23f271de35 100644
--- a/dev-dotnet/dotnet-sdk-bin/Manifest
+++ b/dev-dotnet/dotnet-sdk-bin/Manifest
@@ -40,9 +40,3 @@ DIST dotnet-sdk-9.0.100-linux-musl-arm.tar.gz 203641766 BLAKE2B a9c4d75c502d0a34
 DIST dotnet-sdk-9.0.100-linux-musl-arm64.tar.gz 204170026 BLAKE2B c00768a33984e68de7c1f27c87f37b1cf5555e5df0db8e61071ce06740bde24bb8de3b20d4132db307c6083e75fec5b5bb8b29ad947b27fcbf9d9496f878321e SHA512 dae06d007327f6f53f50cb3a2884b93cd2fcbb73c756a8ac5ff673617f9bdf00093932f3a83652211fc2eeb57c271078644ef5c28a42897d8397f76d0e89586d
 DIST dotnet-sdk-9.0.100-linux-musl-x64.tar.gz 209088176 BLAKE2B bc33f90a7f2aa5e64289e36b33724ef89f710d32211c05f6371853424a3140dce0336c15d50c6ae0d44dcc55aba22378c2d236096395c69a0b45d61b6bb4ab3b SHA512 e2032e6b4ed99adb3a92b7e041ea895ee09c6ed2455a1f68e55ed53bd613c8c20ef4aa5c434393bb5fdbc2f5635a83067f77451fe2fd3febcee264fe077acdaa
 DIST dotnet-sdk-9.0.100-linux-x64.tar.gz 209148140 BLAKE2B 4fa610ddb4a4df326f591b0b588252402de1fa5910b94c49ca278d06bfd65385c63689e415adf0c3d64ab47a8eb0b2c4fe21bdd5a57224f3ef90b5a293961b6f SHA512 7f69bda047de1f952286be330a5e858171ded952d1aa24169e62212f90a27149e63b636c88ad313a6e3ec860da31f8c547ff4ab6808103a070f7fb26ba99c1c7
-DIST dotnet-sdk-9.0.100-rc.1.24452.12-linux-arm.tar.gz 198009391 BLAKE2B 2cf5963bfa9e43e89a9213e1c8188f4378334efe43394958aefd43e44ed69cd380de75ad1ed29f21c64d14e6e06dac7165e1071e9977deaedf9db776e9a4dad0 SHA512 f31a4a2c3080a921cfdd71933d1f57c2f57ff4c43f5a0ad6f52640bc791e54f8c0526d8e1206ad21f8682357a53cf6d488a8b01107e7c34beafe2c8c3425dd8c
-DIST dotnet-sdk-9.0.100-rc.1.24452.12-linux-arm64.tar.gz 198908952 BLAKE2B d188a3fbf93bb8f72d4c5e0be5729d7fb1fb63bc6e46122d8cc935917966ef3a34f648260bc2b9b8d00cc6d8b48f4cbeec137167ec287a14163a05edea413875 SHA512 f5742537128801c199a127266175066058788a26e8a603cbd26a1c16e9ef33a5d418e4790a3cea722d7de483eee8b68e0de4bb1dfdf279713369ed3b4d163a11
-DIST dotnet-sdk-9.0.100-rc.1.24452.12-linux-musl-arm.tar.gz 198139808 BLAKE2B 9229e45144e69fc61d8a968e377b1b1fd8b37d9dd6415ca1e48a5588b815daa83e519b225256c4e96d0cc1e4d9cc1f4ac5d955cf4e20556e1ced6f9826b72e13 SHA512 8480900e14bd1034f586c3e17402be2f04cab250d79b4d1dda3aa887e9fafa683ad388adf7f25b5c7b0dc433375ce1c272b3d9419636e6db0f7bf300e841a0a5
-DIST dotnet-sdk-9.0.100-rc.1.24452.12-linux-musl-arm64.tar.gz 198816947 BLAKE2B 22d235a094b21c5c2fd7cce4805017c3f8ab588315aafb559ce4944600e717489212aa6f388b7e3b784e8884aa8ebdd841b868a794316db4e50ba7cff8734b72 SHA512 656bfa4e7c4a3ee280b99eaffa620b09b89b3a3b9f6d33c9d787c1f8938b84afb5aa43d80546e81a2bfd532770c282c59aea167f50d01a57027a2061e595f0e9
-DIST dotnet-sdk-9.0.100-rc.1.24452.12-linux-musl-x64.tar.gz 203678090 BLAKE2B 6aa341185b68d33c4479b223f48308c43bb416e177174c43884f6a32537ebae10dc2c4225a8d119ceb7209fbfca9faf4ea7416a5cb3981e6c295e11e0abb6b6b SHA512 b1d8004cf9c3ffb530fbb3d4259174cb076a32ba00268daa43dbf452fe6d46ccf979a63d7f53ae70a2fa7a101a9df1bd3b840552ac92a852119bb7385a65f65f
-DIST dotnet-sdk-9.0.100-rc.1.24452.12-linux-x64.tar.gz 203613000 BLAKE2B 75d2682a2c9543fc79276f93e5ae1f1323f6a6b1d8aa61daff35b288b6424ef803d8a26846f982afe571688e83ebb6df76ab6678708addf422537edcc35aba0b SHA512 e8130817b779d0104a6eee33d98d97c3fad1c336013435f47c0e9e22370172b75da37ade76e49dec7cbe696884390d2e6941cc69e2bad5593d6d1c6b41083051

diff --git a/dev-dotnet/dotnet-sdk-bin/dotnet-sdk-bin-9.0.100.1.24452.12_rc.ebuild b/dev-dotnet/dotnet-sdk-bin/dotnet-sdk-bin-9.0.100.1.24452.12_rc.ebuild
deleted file mode 100644
index 8b4a486015bb..000000000000
--- a/dev-dotnet/dotnet-sdk-bin/dotnet-sdk-bin-9.0.100.1.24452.12_rc.ebuild
+++ /dev/null
@@ -1,174 +0,0 @@
-# Copyright 1999-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-REAL_PV="$(ver_cut 1-3)-rc.$(ver_cut 4-6)"
-
-SDK_SLOT="$(ver_cut 1-2)"
-RUNTIME_SLOT="${SDK_SLOT}.0"
-
-DESCRIPTION=".NET is a free, cross-platform, open-source developer platform"
-HOMEPAGE="https://dotnet.microsoft.com/
-	https://github.com/dotnet/dotnet/"
-SRC_URI="
-amd64? (
-	elibc_glibc? (
-		https://dotnetcli.azureedge.net/dotnet/Sdk/${REAL_PV}/dotnet-sdk-${REAL_PV}-linux-x64.tar.gz
-	)
-	elibc_musl? (
-		https://dotnetcli.azureedge.net/dotnet/Sdk/${REAL_PV}/dotnet-sdk-${REAL_PV}-linux-musl-x64.tar.gz
-	)
-)
-arm? (
-	elibc_glibc? (
-		https://dotnetcli.azureedge.net/dotnet/Sdk/${REAL_PV}/dotnet-sdk-${REAL_PV}-linux-arm.tar.gz
-	)
-	elibc_musl? (
-		https://dotnetcli.azureedge.net/dotnet/Sdk/${REAL_PV}/dotnet-sdk-${REAL_PV}-linux-musl-arm.tar.gz
-	)
-)
-arm64? (
-	elibc_glibc? (
-		https://dotnetcli.azureedge.net/dotnet/Sdk/${REAL_PV}/dotnet-sdk-${REAL_PV}-linux-arm64.tar.gz
-	)
-	elibc_musl? (
-		https://dotnetcli.azureedge.net/dotnet/Sdk/${REAL_PV}/dotnet-sdk-${REAL_PV}-linux-musl-arm64.tar.gz
-	)
-)
-"
-S="${WORKDIR}"
-
-LICENSE="MIT"
-SLOT="${SDK_SLOT}/${RUNTIME_SLOT}"
-# See bug https://bugs.gentoo.org/932377
-# KEYWORDS=""
-
-# STRIP="llvm-strip" corrupts some executables when using the patchelf hack,
-# bug https://bugs.gentoo.org/923430
-RESTRICT="splitdebug strip"
-
-# Currently unsupported in ::gentoo.
-# CURRENT_NUGETS_DEPEND="
-# 	~dev-dotnet/dotnet-runtime-nugets-${RUNTIME_SLOT}
-# "
-EXTRA_NUGETS_DEPEND="
-	~dev-dotnet/dotnet-runtime-nugets-6.0.33
-	~dev-dotnet/dotnet-runtime-nugets-7.0.20
-	~dev-dotnet/dotnet-runtime-nugets-8.0.8
-"
-NUGETS_DEPEND="
-	${CURRENT_NUGETS_DEPEND}
-	${EXTRA_NUGETS_DEPEND}
-"
-
-RDEPEND="
-	app-crypt/mit-krb5:0/0
-	dev-libs/icu
-	dev-util/lttng-ust:0/2.12
-	sys-libs/zlib:0/1
-"
-BDEPEND="
-	dev-util/patchelf
-"
-IDEPEND="
-	app-eselect/eselect-dotnet
-"
-PDEPEND="
-	${NUGETS_DEPEND}
-"
-
-QA_PREBUILT="*"
-
-MUSL_BAD_LINKS=(
-	apphost
-	createdump
-	dotnet
-	libSystem.Globalization.Native.so
-	libSystem.IO.Compression.Native.so
-	libSystem.Native.so
-	libSystem.Net.Security.Native.so
-	libSystem.Security.Cryptography.Native.OpenSsl.so
-	libclrgc.so
-	libclrjit.so
-	libcoreclr.so
-	libcoreclrtraceptprovider.so
-	libdbgshim.so
-	libhostfxr.so
-	libhostpolicy.so
-	libmscordaccore.so
-	libmscordbi.so
-	libnethost.so
-	singlefilehost
-)
-MUSL_BAD_SONAMES=(
-	libc.musl-aarch64.so.1
-	libc.musl-armv7.so.1
-	libc.musl-x86_64.so.1
-)
-
-src_prepare() {
-	default
-
-	# Fix musl libc SONAME links, bug https://bugs.gentoo.org/894760
-	if use elibc_musl ; then
-		local musl_bad_link
-		local musl_bad_link_path
-		local musl_bad_soname
-
-		for musl_bad_link in "${MUSL_BAD_LINKS[@]}" ; do
-			while read -r musl_bad_link_path ; do
-				# Skip if file either does not end with ".so" or is not executable.
-				# Using "case" here for easier matching in case we have to add
-				# a special exception.
-				case "${musl_bad_link_path}" in
-					*.so )
-						:
-						;;
-					* )
-						if [[ ! -x "${musl_bad_link_path}" ]] ; then
-							continue
-						fi
-						;;
-				esac
-
-				einfo "Fixing musl libc link for ${musl_bad_link_path}"
-
-				for musl_bad_soname in "${MUSL_BAD_SONAMES[@]}" ; do
-					patchelf --remove-needed "${musl_bad_soname}" "${musl_bad_link_path}" || die
-				done
-
-				patchelf --add-needed libc.so "${musl_bad_link_path}" || die
-			done < <(find . -type f -name "${musl_bad_link}")
-		done
-	fi
-
-	# Remove static libraries, bug https://bugs.gentoo.org/825774
-	find ./packs -type f -name "libnethost.a" -delete || die
-}
-
-src_install() {
-	local dest="opt/${PN}-${SDK_SLOT}"
-	dodir "${dest%/*}"
-
-	# Create a magic workloads file, bug #841896
-	local featureband="$(( $(ver_cut 3) / 100 * 100 ))"       # e.g. 404 -> 400
-	local workloads="metadata/workloads/${SDK_SLOT}.${featureband}"
-
-	mkdir -p "${S}/${workloads}" || die
-	touch "${S}/${workloads}/userlocal" || die
-
-	mv "${S}" "${ED}/${dest}" || die
-	mkdir "${S}" || die
-
-	fperms 0755 "/${dest}"
-	dosym "../../${dest}/dotnet" "/usr/bin/dotnet-bin-${SDK_SLOT}"
-}
-
-pkg_postinst() {
-	eselect dotnet update ifunset
-}
-
-pkg_postrm() {
-	eselect dotnet update ifunset
-}