[gentoo-commits] repo/gentoo:master commit in: sci-mathematics/manifold/

["Sam James" <sam@gentoo.org>]

commit:     b0de2d77915a2db22466744bc4c78809e5a1b6b9
Author:     Chris Mayo <aklhfex <AT> gmail <DOT> com>
AuthorDate: Mon Nov 11 19:34:19 2024 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sat Nov 16 21:39:05 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b0de2d77

sci-mathematics/manifold: new package, add 3.0.0_pre20241108

Signed-off-by: Chris Mayo <aklhfex <AT> gmail.com>
Signed-off-by: Sam James <sam <AT> gentoo.org>

 sci-mathematics/manifold/Manifest                  |  1 +
 .../manifold/manifold-3.0.0_pre20241108.ebuild     | 63 ++++++++++++++++++++++
 2 files changed, 64 insertions(+)

diff --git a/sci-mathematics/manifold/Manifest b/sci-mathematics/manifold/Manifest
new file mode 100644
index 000000000000..fd902480b99b
--- /dev/null
+++ b/sci-mathematics/manifold/Manifest
@@ -0,0 +1 @@
+DIST manifold-3.0.0_pre20241108.tar.gz 29138377 BLAKE2B 4b12bf934ad1bef70aa24dad84898cef62dcd2cade2f2c7314775cc50f07ff952d7686b1585bcf1bab492a905d17f4cd14ebc1b56eba666b72a2bbc255ca685b SHA512 fb871468613bedb84d558e124f3ed8ebe90fb1377047c3a519a64d212b4a28332719e070e7730ac3dcd2360d518f773dda040e37da1e86d7bd768fc8c1ffee0a

diff --git a/sci-mathematics/manifold/manifold-3.0.0_pre20241108.ebuild b/sci-mathematics/manifold/manifold-3.0.0_pre20241108.ebuild
new file mode 100644
index 000000000000..69c4db1a7054
--- /dev/null
+++ b/sci-mathematics/manifold/manifold-3.0.0_pre20241108.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+COMMIT=66bca6e3fdfce0f590ca84edc1a6256502636f4b
+PYTHON_COMPAT=( python3_{10..13} )
+inherit cmake python-single-r1
+
+DESCRIPTION="Geometry library for topological robustness"
+HOMEPAGE="https://github.com/elalish/manifold"
+SRC_URI="https://github.com/elalish/manifold/archive/${COMMIT}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${PN}-${COMMIT}"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+
+IUSE="debug python test"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+RESTRICT="!test? ( test ) mirror"
+
+RDEPEND="
+	dev-cpp/tbb
+	sci-mathematics/clipper2
+	python? ( ${PYTHON_DEPS}
+		$(python_gen_cond_dep '
+			dev-python/numpy[${PYTHON_USEDEP}]
+		')
+	)
+	"
+DEPEND="
+	python? (
+		$(python_gen_cond_dep '
+			>=dev-python/nanobind-2.1.0[${PYTHON_USEDEP}]
+		')
+	)
+	test? ( dev-cpp/gtest )
+	${RDEPEND}"
+
+src_configure() {
+	local mycmakeargs=(
+		-DMANIFOLD_CROSS_SECTION=ON
+		-DMANIFOLD_DEBUG=$(usex debug)
+		-DMANIFOLD_DOWNLOADS=OFF
+		-DMANIFOLD_EXPORT=OFF
+		-DMANIFOLD_JSBIND=OFF
+		-DMANIFOLD_PAR=ON
+		-DMANIFOLD_PYBIND=$(usex python)
+		-DMANIFOLD_TEST=$(usex test)
+	)
+	if use debug; then
+		mycmakeargs+=(
+			-DMANIFOLD_FLAGS=-ggdb
+		)
+	fi
+	cmake_src_configure
+}
+
+src_test() {
+	"${BUILD_DIR}"/test/manifold_test || die
+}