[gentoo-commits] repo/gentoo:master commit in: x11-misc/picom/

["Bernard Cafarelli" <voyageur@gentoo.org>]

commit:     f32cd9254b679915209f85c2c2e405dabf911a0c
Author:     Bernard Cafarelli <voyageur <AT> gentoo <DOT> org>
AuthorDate: Tue Nov 12 08:57:29 2024 +0000
Commit:     Bernard Cafarelli <voyageur <AT> gentoo <DOT> org>
CommitDate: Tue Nov 12 09:13:16 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f32cd925

x11-misc/picom: add 12.4

Signed-off-by: Bernard Cafarelli <voyageur <AT> gentoo.org>

 x11-misc/picom/Manifest          |  1 +
 x11-misc/picom/picom-12.4.ebuild | 67 ++++++++++++++++++++++++++++++++++++++++
 2 files changed, 68 insertions(+)

diff --git a/x11-misc/picom/Manifest b/x11-misc/picom/Manifest
index 090e927bd725..4332e2cecf56 100644
--- a/x11-misc/picom/Manifest
+++ b/x11-misc/picom/Manifest
@@ -1,2 +1,3 @@
 DIST picom-11.2.tar.gz 308679 BLAKE2B d592dce3e67bc3df68cbece00cd4446ea6214b994d9ceffdd3d43a983e4a520f7a92c9c09bec12f49f18b4e581a4122c363f8de0c156bfe2e99fa09b04ec2196 SHA512 df8fc1a593e108b37be185129ac1f3a23c2ae648a04352c45b9d5888838e5754c68f2eb684f12f1ed4d973eca0aef83a61789f028c63bc2d0f0f38902232aadc
 DIST picom-12.3.tar.gz 673577 BLAKE2B 86d2a775ae5ef99fd1f9b9c07e803301b43898cbde8499e80d1cc6ab9f7774b417b76e6780448d53fd8585c522938dac697f811d1bd06d9d7c34dc292d0c6db3 SHA512 f158a517ad6bb6125dc718286663560d7a2297252ecaccef9f7620a1180d19f1c12e9bf7d0d91dadae458a45bbe94756a00c639395fbb8097f408b530c7066f6
+DIST picom-12.4.tar.gz 674046 BLAKE2B 60bfda067b0a9387f8d50030177f47795060f54c9b06deb4918c67077bcc1e991eaff444f9d64ae71f40f2cf0e59afe5a23e9ad6390533cfb972e93a86d9ceb4 SHA512 bbbf69cfe158148ed606372ecf7289b74b5262294a94018c8205c3f320a3bbcf0b893af6cfbe4e3ab2ffa02c6fa1ee66b9bc4d938c4cd645772a027db75f6db0

diff --git a/x11-misc/picom/picom-12.4.ebuild b/x11-misc/picom/picom-12.4.ebuild
new file mode 100644
index 000000000000..a9fd31dd11a2
--- /dev/null
+++ b/x11-misc/picom/picom-12.4.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..13} )
+inherit meson python-any-r1 virtualx xdg
+
+DESCRIPTION="A lightweight compositor for X11 (previously a compton fork)"
+HOMEPAGE="https://github.com/yshui/picom"
+SRC_URI="https://github.com/yshui/picom/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MPL-2.0 MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="dbus +doc +drm opengl pcre test"
+
+REQUIRED_USE="test? ( dbus )" # avoid "DBus support not compiled in!"
+RESTRICT="test" # but tests require dbus_next
+
+RDEPEND="dev-libs/libconfig:=
+	dev-libs/libev
+	dev-libs/uthash
+	x11-libs/libX11
+	x11-libs/libxcb
+	x11-libs/pixman
+	x11-libs/xcb-util
+	x11-libs/xcb-util-image
+	x11-libs/xcb-util-renderutil
+	dbus? ( sys-apps/dbus )
+	drm? ( x11-libs/libdrm )
+	opengl? (
+		media-libs/libepoxy
+		virtual/opengl
+	)
+	pcre? ( dev-libs/libpcre2:= )"
+DEPEND="${RDEPEND}
+	x11-base/xorg-proto"
+BDEPEND="virtual/pkgconfig
+	doc? ( dev-ruby/asciidoctor )
+	test? ( $(python_gen_any_dep 'dev-python/xcffib[${PYTHON_USEDEP}]') )
+"
+
+DOCS=( README.md picom.sample.conf )
+
+python_check_deps() {
+	python_has_version "dev-python/xcffib[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use dbus)
+		$(meson_use doc with_docs)
+		$(meson_use opengl)
+		$(meson_use pcre regex)
+	)
+
+	meson_src_configure
+}
+
+src_test() {
+	virtx "${S}/tests/run_tests.sh" "${BUILD_DIR}/src/${PN}"
+}