[gentoo-commits] repo/gentoo:master commit in: lxqt-base/lxqt-session/

["Jimi Huotari" <chiitoo@gentoo.org>]

commit:     a0e6793b1a84965f96bb8ffc89f45fa4a7808bd5
Author:     Jimi Huotari <chiitoo <AT> gentoo <DOT> org>
AuthorDate: Thu Nov  7 14:29:37 2024 +0000
Commit:     Jimi Huotari <chiitoo <AT> gentoo <DOT> org>
CommitDate: Thu Nov  7 23:11:49 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=a0e6793b

lxqt-base/lxqt-session: add 2.1.0

Signed-off-by: Jimi Huotari <chiitoo <AT> gentoo.org>

 lxqt-base/lxqt-session/Manifest                  |  1 +
 lxqt-base/lxqt-session/lxqt-session-2.1.0.ebuild | 58 ++++++++++++++++++++++++
 2 files changed, 59 insertions(+)

diff --git a/lxqt-base/lxqt-session/Manifest b/lxqt-base/lxqt-session/Manifest
index f4a75b973fd9..b8d5ccd040e4 100644
--- a/lxqt-base/lxqt-session/Manifest
+++ b/lxqt-base/lxqt-session/Manifest
@@ -1,2 +1,3 @@
 DIST lxqt-session-1.4.0.tar.xz 188324 BLAKE2B 508509a783f747c3dd72984264056466d8f9ef901b4a7731fbecca575951c528231cdb71a799ab7d617ed86c29d9026d9feb8fbb2b795a39958c1948d75812c2 SHA512 4f5731969582222eef9d0d2f2b37c4a160c3c6469f3a16cb4b1804ba76a9320d36b0ed91cada6ee905339ed8cfbd443851804086d978424c4d79045cc90e1629
 DIST lxqt-session-2.0.0.tar.xz 194480 BLAKE2B 18954f9d440ad8a553b9ccf0aa6bb28a971e7d2010a5b8f0dc32080d5829654bdbc5dd5bd292a0285b1e75af4e0cb0fe4585061e86814c0976c69824015719b4 SHA512 c0b8bbcb666b55b0218bfe1e6669fff0de44a89986dae9afb17ae169e13a2816ef56e62d0b9210449023113a8066d45ccef4fa54b0a5c08c60c2ca4311f142ed
+DIST lxqt-session-2.1.0.tar.xz 212308 BLAKE2B 4036295e6cb61b8f94ee0c56e46c3792894de55f32de0dcd2d121881d1f68450bf9fa9c36f0b9740cb6eaccbbd11aa8e210eaa77e16e97c8f03de1008def4d00 SHA512 b0f70ef1f166fd5c48394f66794c655f1a26411d69c831f671c07ca5eaf9434d2902fbcda507f3b75b69d165a6e234a774c5f8f3f85d7cb924fa3152866d88b5

diff --git a/lxqt-base/lxqt-session/lxqt-session-2.1.0.ebuild b/lxqt-base/lxqt-session/lxqt-session-2.1.0.ebuild
new file mode 100644
index 000000000000..3f3742a379aa
--- /dev/null
+++ b/lxqt-base/lxqt-session/lxqt-session-2.1.0.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="LXQt Session Manager"
+HOMEPAGE="https://lxqt-project.org/"
+
+MY_PV="$(ver_cut 1-2)"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/lxqt/${PN}.git"
+else
+	SRC_URI="https://github.com/lxqt/${PN}/releases/download/${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+fi
+
+LICENSE="LGPL-2.1 LGPL-2.1+"
+SLOT="0"
+IUSE="+udev"
+
+BDEPEND="
+	>=dev-qt/qttools-6.6:6[linguist]
+	>=dev-util/lxqt-build-tools-2.1.0
+"
+DEPEND="
+	>=app-misc/qtxdg-tools-4.1.0
+	>=dev-libs/libqtxdg-4.1.0
+	>=dev-qt/qtbase-6.6:6[dbus,gui,widgets]
+	kde-frameworks/kwindowsystem:6[X]
+	kde-plasma/layer-shell-qt:6
+	=lxqt-base/liblxqt-${MY_PV}*:=
+	sys-process/procps:=
+	x11-libs/libX11
+	x11-misc/xdg-user-dirs
+	udev? ( virtual/libudev:= )
+"
+RDEPEND="${DEPEND}"
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_LIBUDEV=$(usex udev)
+	)
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+	doman lxqt-config-session/man/*.1 lxqt-session/man/*.1
+
+	newenvd - 91lxqt-config-dir <<- _EOF_
+		XDG_CONFIG_DIRS='${EPREFIX}/usr/share'
+	_EOF_
+}