[gentoo-commits] repo/gentoo:master commit in: dev-python/nox/

["Michał Górny" <mgorny@gentoo.org>]

commit:     18f320d793d0014d1fbeaf56c7d733428f1b45e0
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Thu Oct 10 03:49:55 2024 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Thu Oct 10 05:03:13 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=18f320d7

dev-python/nox: Bump to 2024.10.09

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/nox/Manifest              |  1 +
 dev-python/nox/nox-2024.10.09.ebuild | 69 ++++++++++++++++++++++++++++++++++++
 2 files changed, 70 insertions(+)

diff --git a/dev-python/nox/Manifest b/dev-python/nox/Manifest
index 2b683a9536d3..6591608fdfe5 100644
--- a/dev-python/nox/Manifest
+++ b/dev-python/nox/Manifest
@@ -1 +1,2 @@
 DIST nox-2024.04.15.gh.tar.gz 4001096 BLAKE2B 22a332afe499811be23876760e33be60dac200b686aa19fb7fe7b92315e2681f874a4c175419e3b4dc9eb709bb98821a99d3a7bf2d7dfa756894e5d1265e46e7 SHA512 99143b4c372e40c5b436ef786e72582eae3182513e9763cb76eb123dcb4d16de8b0585a21119c3513fe9aae4bb6d9d19b16f3129a42f3addf2878e6e7f044ebb
+DIST nox-2024.10.09.gh.tar.gz 4003528 BLAKE2B 51bf42870eac462fdb87e897c225c8262703ccc222d5c463e45d91acf08e4211153f60f72450e3fb964d4ca386501bfa88559e8cff38d55aa2f22310a17d7911 SHA512 51d1f70ba94d01abd10ba3a12896facd13a7a2881496221b6fa9d0a43ff947303b0cc975a29169a3d9e0174277e23e0bc4b1137b2774c1abffa23a48c9d69a11

diff --git a/dev-python/nox/nox-2024.10.09.ebuild b/dev-python/nox/nox-2024.10.09.ebuild
new file mode 100644
index 000000000000..49b36144860b
--- /dev/null
+++ b/dev-python/nox/nox-2024.10.09.ebuild
@@ -0,0 +1,69 @@
+# Copyright 2023-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( pypy3 python3_{10..13} )
+
+inherit distutils-r1
+
+DESCRIPTION="Flexible test automation for Python"
+HOMEPAGE="
+	https://github.com/wntrblm/nox/
+	https://pypi.org/project/nox/
+"
+SRC_URI="
+	https://github.com/wntrblm/nox/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+
+RDEPEND="
+	>=dev-python/argcomplete-1.9.4[${PYTHON_USEDEP}]
+	>=dev-python/colorlog-2.6.1[${PYTHON_USEDEP}]
+	>=dev-python/packaging-20.9[${PYTHON_USEDEP}]
+	>=dev-python/virtualenv-20.14.1[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/tomli-1[${PYTHON_USEDEP}]
+	' 3.10)
+"
+BDEPEND="
+	test? (
+		dev-python/py[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# remove upper bounds from dependencies
+	sed -i -e 's:<[0-9.]*,::' pyproject.toml || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# TODO: conda?
+		'tests/test_sessions.py::TestSessionRunner::test__create_venv_options[nox.virtualenv.CondaEnv.create-conda-CondaEnv]'
+		# Internet
+		tests/test_virtualenv.py::test_uv_install
+	)
+
+	case ${EPYTHON} in
+		pypy3)
+			EPYTEST_DESELECT+=(
+				# hardcoded CPython assumption
+				tests/test_tox_to_nox.py::test_skipinstall
+				tests/test_tox_to_nox.py::test_trivial
+				tests/test_tox_to_nox.py::test_usedevelop
+			)
+			;;
+	esac
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -o tmp_path_retention_policy=all
+}