[gentoo-commits] repo/gentoo:master commit in: x11-misc/xkeyboard-config/

["Matt Turner" <mattst88@gentoo.org>]

commit:     d3dec3d8599eea9296b842a989a6358c860127e9
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Wed Oct  2 14:52:51 2024 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Wed Oct  2 15:12:54 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d3dec3d8

x11-misc/xkeyboard-config: Version bump to 2.43

Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 x11-misc/xkeyboard-config/Manifest                 |  1 +
 .../xkeyboard-config/xkeyboard-config-2.43.ebuild  | 66 ++++++++++++++++++++++
 2 files changed, 67 insertions(+)

diff --git a/x11-misc/xkeyboard-config/Manifest b/x11-misc/xkeyboard-config/Manifest
index 63727b9b98bd..d80903f1c0d1 100644
--- a/x11-misc/xkeyboard-config/Manifest
+++ b/x11-misc/xkeyboard-config/Manifest
@@ -1 +1,2 @@
 DIST xkeyboard-config-2.42.tar.xz 910192 BLAKE2B 1b49a9bdf9e6ad2c196b8c4cc93803a2b4ce804148a7eb55616672db5c4d3eb289e2de931ee8b08a2152dd542a9f2d1e00ba8cca7651d7f33b570ed4a5f4c57b SHA512 654436ae21b9deb3b193847403b652cc5c19aa665a9c9168598fc6ac7af83ac04d40684d9eb99dd4db97c21e5100cfeed06b25e2b041eb9fdf3c05ef95a891a9
+DIST xkeyboard-config-2.43.tar.xz 925424 BLAKE2B 89cf4872305ce3358185ed63f0ff2f0dc90205d50d51b4b881256e0762b12a74f30d0905a75e5feff2f0fef09d94bee778a8cbe83cdf6e048653e8eb42f53087 SHA512 6daf885bf8794cf03d5b447b90ca1666f87e9c609a344e02bb90edca360eb64b24f80a92ed570aa75b4ea62245b3998f6df3757f7e02c4015cdfecee5378a0d4

diff --git a/x11-misc/xkeyboard-config/xkeyboard-config-2.43.ebuild b/x11-misc/xkeyboard-config/xkeyboard-config-2.43.ebuild
new file mode 100644
index 000000000000..d4e67dee2a23
--- /dev/null
+++ b/x11-misc/xkeyboard-config/xkeyboard-config-2.43.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{11..13} )
+inherit meson python-any-r1
+
+DESCRIPTION="X keyboard configuration database"
+HOMEPAGE="https://www.freedesktop.org/wiki/Software/XKeyboardConfig/ https://gitlab.freedesktop.org/xkeyboard-config/xkeyboard-config"
+
+if [[ ${PV} == 9999 ]]; then
+	EGIT_REPO_URI="https://gitlab.freedesktop.org/xkeyboard-config/xkeyboard-config.git"
+	inherit git-r3
+else
+	SRC_URI="https://www.x.org/releases/individual/data/${PN}/${P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	dev-lang/perl
+	dev-libs/libxslt
+	sys-devel/gettext
+	${PYTHON_DEPS}
+	test? (
+		x11-apps/xkbcomp
+		x11-libs/libxkbcommon
+		$(python_gen_any_dep '
+			dev-python/pycountry[${PYTHON_USEDEP}]
+			dev-python/pytest-xdist[${PYTHON_USEDEP}]
+			dev-python/pytest[${PYTHON_USEDEP}]
+		')
+	)
+"
+
+python_check_deps() {
+	use test || return 0
+	python_has_version \
+		"dev-python/pycountry[${PYTHON_USEDEP}]" \
+		"dev-python/pytest-xdist[${PYTHON_USEDEP}]" \
+		"dev-python/pytest[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	eapply_user
+
+	# Remove pytest timeout
+	sed -i -e "/test('pytest'/,/)$/ { s/timeout: [0-9]*/timeout: 0/ }" meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dxkb-base="${EPREFIX}/usr/share/X11/xkb"
+		-Dcompat-rules=true
+	)
+	meson_src_configure
+}