[gentoo-commits] repo/gentoo:master commit in: dev-python/spyder/

["Andrew Ammerlaan" <andrewammerlaan@gentoo.org>]

commit:     665b5cdf523208df0b27bf466a9893aacadb9bbb
Author:     Andrew Ammerlaan <andrewammerlaan <AT> gentoo <DOT> org>
AuthorDate: Tue Sep 24 08:40:18 2024 +0000
Commit:     Andrew Ammerlaan <andrewammerlaan <AT> gentoo <DOT> org>
CommitDate: Tue Sep 24 08:40:18 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=665b5cdf

dev-python/spyder: add 6.0.1

Closes: https://bugs.gentoo.org/939912
Signed-off-by: Andrew Ammerlaan <andrewammerlaan <AT> gentoo.org>

 dev-python/spyder/Manifest            |   2 +
 dev-python/spyder/spyder-6.0.1.ebuild | 195 ++++++++++++++++++++++++++++++++++
 2 files changed, 197 insertions(+)

diff --git a/dev-python/spyder/Manifest b/dev-python/spyder/Manifest
index 3b3e5cd9684b..b3a96f862612 100644
--- a/dev-python/spyder/Manifest
+++ b/dev-python/spyder/Manifest
@@ -1,3 +1,5 @@
 DIST spyder-5.5.6.gh.tar.gz 16304234 BLAKE2B 9d14b96901276ced1644eef8dd57539036aecb067ee361b6581368b371d56b2008350969224992a35fe10ee177babca7f3e941f43b4cc3f432f6d0dec9104ead SHA512 93ce6ac2e71bd4e81ca4a630a6fe152d1bf3c83d6e5c01dda8f3e5ad2735de1948a86642f5bc589c90616935e997526b26367ce178905ad2b80faf81f36f9164
 DIST spyder-6.0.0.gh.tar.gz 15687128 BLAKE2B 23319f167eb61fecc477dd3b3deab2d62a1c12109033f262ba31e349b26ba92524bde0399ca2f8ae6ff6bbcbf400360882b92b888644b9d9767f5d894e5c06b6 SHA512 3445481df35707e103646ada5fb7eef94b1b36fdbec31e15d3cb7608f637fcf21238fec0f5747f8c7a1b5bb9770ed5355b4f0fab0f9db57bc888306c6a14c003
+DIST spyder-6.0.1.gh.tar.gz 15703963 BLAKE2B 5d4488fffe4889e5609a73c849172a08ed192dfe027940e8931da2ff4d809e52ddf3095c75813ca65225a372e86aece698fd83d5844aa76c5837f98d9c95c137 SHA512 034474c7feb341c5a0f6837ce2c0de6b6a6cc435c63e6d346c389977374b59a1b201495f2d6a692241245d81abda02dbd2a30c57c706506d23033c7347ccade0
 DIST spyder-docs-6951e02799fc7cd1f29456f1d93cfdcb570dad27.gh.tar.gz 93033557 BLAKE2B 395dd2a8ddb6e1b1408ba46cbe0fa452c1f2e69da1f3b6176401ff7395ace1463e63c696e13ee0b79f992b0ceca86228ad113f95ed7873db1b970452bc679f89 SHA512 c631e720e3ca49413482df294fb032285cf217ba94de299c37cb073e4e2bdeb629d16a139db17c569c74c628c50789c90d6085383886d32fa26b942711ccedc0
+DIST spyder-docs-d153e129b426b4fc95b1d66e692bf8a78cf40790.gh.tar.gz 93358065 BLAKE2B 7ad139ac9496d1817b0a8a69ba84bbbcd92081c5dd1d885011cbf8cc8cb4180f84a95222a0d89b3d41c352cb64e9ef87a8b31220e3d14e3efc63994f0623f07a SHA512 701e20113ae7b4894a4c08db967fbd7cbfbc894c4e5db74ad98451ebd03b8858ddfb3910238659f79a28e5e6cc9f76e05967ad7d8c4e27b0b5e6ea0551b2ceac

diff --git a/dev-python/spyder/spyder-6.0.1.ebuild b/dev-python/spyder/spyder-6.0.1.ebuild
new file mode 100644
index 000000000000..de1b888b8ba3
--- /dev/null
+++ b/dev-python/spyder/spyder-6.0.1.ebuild
@@ -0,0 +1,195 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+DISTUTILS_USE_PEP517=setuptools
+
+inherit distutils-r1 optfeature xdg #virtualx
+
+# Commit of documentation to fetch
+DOCS_PV="d153e129b426b4fc95b1d66e692bf8a78cf40790"
+
+DESCRIPTION="The Scientific Python Development Environment"
+HOMEPAGE="
+	https://www.spyder-ide.org/
+	https://github.com/spyder-ide/spyder/
+	https://pypi.org/project/spyder/
+"
+SRC_URI="
+	https://github.com/spyder-ide/${PN}/archive/v${PV}.tar.gz -> ${P}.gh.tar.gz
+	https://github.com/spyder-ide/${PN}-docs/archive/${DOCS_PV}.tar.gz -> ${PN}-docs-${DOCS_PV}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	>=dev-python/aiohttp-3.9.3[${PYTHON_USEDEP}]
+	>=dev-python/asyncssh-2.14.0[${PYTHON_USEDEP}]
+	<dev-python/asyncssh-3.0.0[${PYTHON_USEDEP}]
+	>=dev-python/atomicwrites-1.2.0[${PYTHON_USEDEP}]
+	>=dev-python/chardet-2.0.0[${PYTHON_USEDEP}]
+	>=dev-util/cookiecutter-1.6.0[${PYTHON_USEDEP}]
+	>=dev-python/diff-match-patch-20181111[${PYTHON_USEDEP}]
+	>=dev-python/intervaltree-3.0.2[${PYTHON_USEDEP}]
+	>=dev-python/jellyfish-0.7[${PYTHON_USEDEP}]
+	>=dev-python/jsonschema-3.2.0[${PYTHON_USEDEP}]
+	>=dev-python/keyring-17.0.0[${PYTHON_USEDEP}]
+	>=dev-python/nbconvert-4.0[${PYTHON_USEDEP}]
+	>=dev-python/numpydoc-0.6.0[${PYTHON_USEDEP}]
+	>=dev-python/pexpect-4.4.0[${PYTHON_USEDEP}]
+	>=dev-python/pickleshare-0.4[${PYTHON_USEDEP}]
+	>=dev-python/psutil-5.3[${PYTHON_USEDEP}]
+	>=dev-python/PyGithub-2.3.0[${PYTHON_USEDEP}]
+	>=dev-python/pygments-2.0[${PYTHON_USEDEP}]
+	>=dev-python/pylint-venv-3.0.2[${PYTHON_USEDEP}]
+	>=dev-python/python-lsp-black-2.0.0[${PYTHON_USEDEP}]
+	<dev-python/python-lsp-black-3.0.0[${PYTHON_USEDEP}]
+	>=dev-python/pyls-spyder-0.4.0[${PYTHON_USEDEP}]
+	>=dev-python/pyuca-1.2[${PYTHON_USEDEP}]
+	>=dev-python/qdarkstyle-3.2.0[${PYTHON_USEDEP}]
+	<dev-python/qdarkstyle-3.3.0[${PYTHON_USEDEP}]
+	>=dev-python/qstylizer-0.2.2[${PYTHON_USEDEP}]
+	>=dev-python/qtawesome-1.3.1[${PYTHON_USEDEP}]
+	<dev-python/qtawesome-1.4.0[${PYTHON_USEDEP}]
+	>=dev-python/qtconsole-5.6.0[${PYTHON_USEDEP}]
+	<dev-python/qtconsole-5.7.0[${PYTHON_USEDEP}]
+	>=dev-python/QtPy-2.4.0[${PYTHON_USEDEP},quick,svg,webengine]
+	>=dev-python/rtree-0.9.7[${PYTHON_USEDEP}]
+	>=dev-python/sphinx-0.6.6[${PYTHON_USEDEP}]
+	>=dev-python/spyder-kernels-3.0.0[${PYTHON_USEDEP}]
+	<dev-python/spyder-kernels-3.1.0[${PYTHON_USEDEP}]
+	>=dev-python/superqt-0.6.2[${PYTHON_USEDEP}]
+	<dev-python/superqt-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/textdistance-4.2.0[${PYTHON_USEDEP}]
+	>=dev-python/three-merge-0.1.1[${PYTHON_USEDEP}]
+	>=dev-python/watchdog-0.10.3[${PYTHON_USEDEP}]
+	>=dev-python/yarl-1.9.4[${PYTHON_USEDEP}]
+"
+
+# BDEPEND="
+# 	test? (
+# 		dev-python/cython[${PYTHON_USEDEP}]
+# 		dev-python/flaky[${PYTHON_USEDEP}]
+# 		dev-python/matplotlib[tk,${PYTHON_USEDEP}]
+# 		dev-python/pandas[${PYTHON_USEDEP}]
+# 		dev-python/pillow[${PYTHON_USEDEP}]
+# 		dev-python/pytest-lazy-fixture[${PYTHON_USEDEP}]
+# 		dev-python/pytest-mock[${PYTHON_USEDEP}]
+# 		dev-python/pytest-order[${PYTHON_USEDEP}]
+# 		dev-python/pytest-qt[${PYTHON_USEDEP}]
+# 		dev-python/pytest-timeout[${PYTHON_USEDEP}]
+# 		dev-python/pyyaml[${PYTHON_USEDEP}]
+# 		dev-python/QtPy[${PYTHON_USEDEP}]
+# 		dev-python/scipy[${PYTHON_USEDEP}]
+# 		dev-python/sympy[${PYTHON_USEDEP}]
+# 	)"
+
+# Based on the courtesy of Arfrever
+# This patch removes a call to update-desktop-database during build
+# This fails because access is denied to this command during build
+PATCHES=(
+	"${FILESDIR}/${PN}-5.0.0-build.patch"
+)
+
+DOCS=(
+	"AUTHORS.txt"
+	"Announcements.md"
+	"CHANGELOG.md"
+	"CODE_OF_CONDUCT.md"
+	"CONTRIBUTING.md"
+	"NOTICE.txt"
+	"README.md"
+	"RELEASE.md"
+)
+
+# distutils_enable_tests pytest
+# TODO: Package sphinx-design
+# distutils_enable_sphinx docs/doc \
+# 	dev-python/sphinx-panels \
+# 	dev-python/pydata-sphinx-theme \
+# 	dev-python/sphinx-multiversion
+
+python_prepare_all() {
+	# move docs into workdir
+	mv ../spyder-docs-${DOCS_PV}* docs || die
+
+	# these dependencies are packaged separately:
+	#    dev-python/spyder-kernels,
+	#    dev-python/python-lsp-server,
+	#    dev-python/qdarkstyle
+	rm -r external-deps/* || die
+	# runs against things packaged in external-deps dir
+	rm conftest.py || die
+
+	# Do not depend on pyqt5<5.16, this dependency is carried by QtPy[pyqt5]
+	# Do not depend on pyqtwebengine<5.16, this dependency is carried by QtPy[webengine]
+	# Do not depend on parso and jedi, this is dependency is carried in python-lsp-server
+	# Do not depend on python-lsp-server, this dependency is carried in pyls-spyder
+	# Do not depend on ipython, this dependency is carried in spyder-kernels
+	# The explicit version requirements only make things more complicated, if e.g.
+	# pyls-spyder gains compatibility with a newer version of python-lsp-server
+	# in a new release it will take time for this information to propagate into
+	# the next spyder release. So just remove the dependency and let the other
+	# ebuilds handle the version requirements to speed things up and prevent
+	# issues such as Bug 803269.
+	sed -i \
+		-e "/'pyqt5[ 0-9<=>.,]*',/d" \
+		-e "/'pyqtwebengine[ 0-9<=>.,]*',/d" \
+		-e "/'python-lsp-server\[all\][ 0-9<=>.,]*',/d" \
+		-e "/'parso[ 0-9<=>.,]*',/d" \
+		-e "/'jedi[ 0-9<=>.,]*',/d" \
+		-e "/'pylint[ 0-9<=>.,]*',/d" \
+			setup.py || die
+		# -e "/'ipython[ 0-9<=>.,]*',/d" \
+	sed -i \
+		-e "/^PYLS_REQVER/c\PYLS_REQVER = '>=0.0.1'" \
+		-e "/^PYLSP_REQVER/c\PYLSP_REQVER = '>=0.0.1'" \
+		-e "/^PARSO_REQVER/c\PARSO_REQVER = '>=0.0.1'" \
+		-e "/^JEDI_REQVER/c\JEDI_REQVER = '>=0.0.1'" \
+		-e "/^PYLINT_REQVER/c\PYLINT_REQVER = '>=0.0.1'" \
+			spyder/dependencies.py || die
+		# -e "/^IPYTHON_REQVER/c\IPYTHON_REQVER = '>=0.0.1'" \
+
+	# do not check deps, fails because we removed dependencies above
+	sed -i -e 's:test_dependencies_for_spyder_setup_install_requires_in_sync:_&:' \
+		spyder/tests/test_dependencies_in_sync.py || die
+
+	# skip online test
+	rm spyder/widgets/github/tests/test_github_backend.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+# Calling pytest directly somehow passes the pytest arguments to spyder
+# causing an invalid argument error
+# python_test() {
+# 	virtx "${EPYTHON}" runtests.py
+# }
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	optfeature "2D/3D plotting in the Python and IPython consoles" dev-python/matplotlib
+	optfeature "View and edit DataFrames and Series in the Variable Explorer" dev-python/pandas
+	optfeature "View and edit two or three dimensional arrays in the Variable Explorer" dev-python/numpy
+	optfeature "Symbolic mathematics in the IPython console" dev-python/sympy
+	optfeature "Import Matlab workspace files in the Variable Explorer" dev-python/scipy
+	optfeature "Run Cython files in the IPython console" dev-python/cython
+	optfeature "The hdf5/h5py plugin" dev-python/h5py
+	optfeature "The line profiler plugin" dev-python/spyder-line-profiler
+	optfeature "Vim key bindings" dev-python/spyder-vim
+	optfeature "Unittest support" dev-python/spyder-unittest
+	optfeature "System terminal inside spyder" dev-python/spyder-terminal
+	optfeature "Jupyter notebook support" dev-python/spyder-notebook
+	# spyder-memory-profiler is not compatible with spyder-5.2+ yet
+	# optfeature "The memory profiler plugin" dev-python/spyder-memory-profiler
+	# spyder-reports not yet updated to >=spyder-4.0.0
+	# optfeature "Markdown reports using Pweave" dev-python/spyder-reports
+	# Plugins with no release yet:
+	# optfeature "Manage virtual environments and packages" dev-python/spyder-env-manager
+	# optfeature "VCS (e.g. git) integration" dev-python/spyder-vcs
+}