[gentoo-commits] repo/gentoo:master commit in: x11-misc/sddm/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     abe4262e4d69fcc001a45f4d35cd9d944134301c
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Thu Aug 29 16:48:57 2024 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Thu Aug 29 19:02:33 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=abe4262e

x11-misc/sddm: drop 0.21.0

Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 x11-misc/sddm/Manifest           |   1 -
 x11-misc/sddm/sddm-0.21.0.ebuild | 152 ---------------------------------------
 2 files changed, 153 deletions(-)

diff --git a/x11-misc/sddm/Manifest b/x11-misc/sddm/Manifest
index efdbfae3f486..5eaf19f0fc31 100644
--- a/x11-misc/sddm/Manifest
+++ b/x11-misc/sddm/Manifest
@@ -1,5 +1,4 @@
 DIST sddm-0.18.1-patchset.tar.xz 7860 BLAKE2B b79738c58f19ebac24dd790ba7613d85ae78bc0c5161d35249e13ddbac3acefff2753b8d92fa47a73a607b3105310ea5d05e1a5a170068030fe28420ffee88b1 SHA512 30ca961f065188d570b1498f9eea5aeafb31ab53b7e9ce41e98e26cba12f8c16a245fffb25ea4d84c6fb9037a24523cd41acc9a8b140a1420282435c9497d9b4
 DIST sddm-0.18.1.tar.xz 3402972 BLAKE2B 99ab43d374e9a3d318f692a6d496d8a6d68927af3c8e8fc2208d7355ec90649a14758b39f5733dd32f942ed569de88085576d4f5f8666f4f97079e0fb6dcb99e SHA512 ff0637600cda2f4da1f643f047f8ee822bd9651ae4ccbb614b9804175c97360ada7af93e07a7b63832f014ef6e7d1b5380ab2b8959f8024ea520fa5ff17efd60
 DIST sddm-0.21.0-pam.tar.xz 676 BLAKE2B 06a79f74a5833eca9877df4be8639311382d13061b21aa3627e6c4b07725878ded62221fca943440bacc143f6be2a23b2e0a2124012ff2c9fac82e1eded11144 SHA512 6d91eef2434346f7707122454522cf19f104994ac95d562417f6060a92b4e6c9792bebcccabac8290479200b4ba02fc4d92c6098c435c7ceda796d619d8913c2
-DIST sddm-0.21.0.tar.gz 3557266 BLAKE2B 849cb8b06b9510e5366ea28ef322c242db7d5a77d94c0a5a727f468209880a717055ad8b0c2f5a857852202a4d6bc1f68281fe0e0ab3c6a32327b5a4219af3a0 SHA512 2e8e460e7f318f20a406dcbb1a9fa1dc78b6a5b8d888bfbbaae22b9c642dbc49cf2ac682b4ea9ed847bbafa9bdc361ba08795e59cad970088b370caaaa70f458
 DIST sddm-0.21.0_p20240723.tar.gz 3557578 BLAKE2B b92feb20a39eaf34822b077fcb8b89a100ff65814f9b523b2a1a0ffd3592edf2e86fa8fbdfcd8b592756a0b4baf0b085e8c7b4ad2aaa2f08b90e25e580df9925 SHA512 1ea2f758099f86086aebf05a77b176227475c1eb9c21c77bc99b9bb5a2882ce087e020ae6a11585b793fe09a3567e0ea4d0c1632a5823b7be83e33882964de48

diff --git a/x11-misc/sddm/sddm-0.21.0.ebuild b/x11-misc/sddm/sddm-0.21.0.ebuild
deleted file mode 100644
index ca86d169665e..000000000000
--- a/x11-misc/sddm/sddm-0.21.0.ebuild
+++ /dev/null
@@ -1,152 +0,0 @@
-# Copyright 1999-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-PAM_TAR="${PN}-0.21.0-pam"
-if [[ ${PV} == *9999* ]]; then
-	inherit git-r3
-	EGIT_REPO_URI="https://github.com/${PN}/${PN}.git"
-else
-	SRC_URI="https://github.com/${PN}/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
-	KEYWORDS="amd64 ~arm arm64 ~loong ~ppc64 ~riscv x86"
-fi
-
-QTMIN=5.15.12
-inherit cmake linux-info optfeature pam systemd tmpfiles
-
-DESCRIPTION="Simple Desktop Display Manager"
-HOMEPAGE="https://github.com/sddm/sddm"
-SRC_URI+=" https://dev.gentoo.org/~asturm/distfiles/${PAM_TAR}.tar.xz"
-
-LICENSE="GPL-2+ MIT CC-BY-3.0 CC-BY-SA-3.0 public-domain"
-SLOT="0"
-IUSE="+elogind systemd test"
-
-REQUIRED_USE="^^ ( elogind systemd )"
-RESTRICT="!test? ( test )"
-
-COMMON_DEPEND="
-	acct-group/sddm
-	acct-user/sddm
-	>=dev-qt/qtcore-${QTMIN}:5
-	>=dev-qt/qtdbus-${QTMIN}:5
-	>=dev-qt/qtdeclarative-${QTMIN}:5
-	>=dev-qt/qtgui-${QTMIN}:5
-	>=dev-qt/qtnetwork-${QTMIN}:5
-	sys-libs/pam
-	x11-libs/libXau
-	x11-libs/libxcb:=
-	elogind? ( sys-auth/elogind[pam] )
-	systemd? ( sys-apps/systemd:=[pam] )
-	!systemd? ( sys-power/upower )
-"
-DEPEND="${COMMON_DEPEND}
-	test? ( >=dev-qt/qttest-${QTMIN}:5 )
-"
-RDEPEND="${COMMON_DEPEND}
-	x11-base/xorg-server
-	!systemd? ( gui-libs/display-manager-init )
-"
-BDEPEND="
-	dev-python/docutils
-	>=dev-qt/linguist-tools-${QTMIN}:5
-	kde-frameworks/extra-cmake-modules:0
-	virtual/pkgconfig
-"
-
-PATCHES=(
-	# Downstream patches
-	"${FILESDIR}/${PN}-0.20.0-respect-user-flags.patch"
-	"${FILESDIR}/${P}-Xsession.patch" # bug 611210
-)
-
-pkg_setup() {
-	local CONFIG_CHECK="~DRM"
-	use kernel_linux && linux-info_pkg_setup
-}
-
-src_unpack() {
-	[[ ${PV} == *9999* ]] && git-r3_src_unpack
-	default
-}
-
-src_prepare() {
-	touch 01gentoo.conf || die
-
-cat <<-EOF >> 01gentoo.conf
-[General]
-# Remove qtvirtualkeyboard as InputMethod default
-InputMethod=
-EOF
-
-	cmake_src_prepare
-
-	if ! use test; then
-		sed -e "/^find_package/s/ Test//" -i CMakeLists.txt || die
-		cmake_comment_add_subdirectory test
-	fi
-
-	if use systemd; then
-		sed -e "/pam_elogind.so/s/elogind/systemd/" \
-			-i "${WORKDIR}"/${PAM_TAR}/${PN}-greeter.pam || die
-	fi
-}
-
-src_configure() {
-	local mycmakeargs=(
-		-DBUILD_MAN_PAGES=ON
-		-DBUILD_WITH_QT6=OFF # default theme (and others) not yet compatible
-		-DDBUS_CONFIG_FILENAME="org.freedesktop.sddm.conf"
-		-DINSTALL_PAM_CONFIGURATION=OFF
-		-DRUNTIME_DIR=/run/sddm
-		-DSYSTEMD_TMPFILES_DIR="/usr/lib/tmpfiles.d"
-		-DNO_SYSTEMD=$(usex !systemd)
-		-DUSE_ELOGIND=$(usex elogind)
-	)
-	cmake_src_configure
-}
-
-src_install() {
-	cmake_src_install
-
-	insinto /etc/sddm.conf.d/
-	doins "${S}"/01gentoo.conf
-
-	# with systemd logs are sent to journald, so no point to bother in that case
-	if ! use systemd; then
-		insinto /etc/logrotate.d
-		newins "${FILESDIR}/sddm.logrotate" sddm
-	fi
-
-	newpamd "${WORKDIR}"/${PAM_TAR}/${PN}.pam ${PN}
-	newpamd "${WORKDIR}"/${PAM_TAR}/${PN}-autologin.pam ${PN}-autologin
-	newpamd "${WORKDIR}"/${PAM_TAR}/${PN}-greeter.pam ${PN}-greeter
-}
-
-pkg_postinst() {
-	tmpfiles_process "${PN}.conf"
-
-	elog "NOTE: If SDDM startup appears to hang then entropy pool is too low."
-	elog "This can be fixed by configuring one of the following:"
-	elog "  - Enable CONFIG_RANDOM_TRUST_CPU in linux kernel"
-	elog "  - # emerge sys-apps/haveged && rc-update add haveged boot"
-	elog "  - # emerge sys-apps/rng-tools && rc-update add rngd boot"
-	elog
-	elog "SDDM example config can be shown with:"
-	elog "  ${EROOT}/usr/bin/sddm --example-config"
-	elog "Use ${EROOT}/etc/sddm.conf.d/ directory to override specific options."
-	elog
-	elog "For more information on how to configure SDDM, please visit the wiki:"
-	elog "  https://wiki.gentoo.org/wiki/SDDM"
-	if has_version x11-drivers/nvidia-drivers; then
-		elog
-		elog "  Nvidia GPU owners in particular should pay attention"
-		elog "  to the troubleshooting section."
-	fi
-
-	optfeature "Weston DisplayServer support (EXPERIMENTAL)" "dev-libs/weston[kiosk]"
-	optfeature "KWin DisplayServer support (EXPERIMENTAL)" "kde-plasma/kwin"
-
-	systemd_reenable sddm.service
-}