[gentoo-commits] repo/gentoo:master commit in: media-radio/ax25-apps/

["Thomas Beierlein" <tomjbe@gentoo.org>]

commit:     592c58d93087f740f229951301f3f722b6b4859b
Author:     Filip Kobierski <fkobi <AT> pm <DOT> me>
AuthorDate: Thu Aug  1 16:56:31 2024 +0000
Commit:     Thomas Beierlein <tomjbe <AT> gentoo <DOT> org>
CommitDate: Wed Aug  7 06:43:53 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=592c58d9

media-radio/ax25-apps: bump EAPI & fix issues

- update HOMEPAGE & SRC_URI
- add slot operator
- move `eapply_user`
- remove --force flag from rm & change the command
- remove virtual/pkgconfig from RDEPEND
- remove IUSE
- add comment

Signed-off-by: Filip Kobierski <fkobi <AT> pm.me>
Closes: https://github.com/gentoo/gentoo/pull/37887
Signed-off-by: Thomas Beierlein <tomjbe <AT> gentoo.org>

 .../ax25-apps/ax25-apps-0.0.8_rc5-r1.ebuild        | 57 ++++++++++++++++++++++
 1 file changed, 57 insertions(+)

diff --git a/media-radio/ax25-apps/ax25-apps-0.0.8_rc5-r1.ebuild b/media-radio/ax25-apps/ax25-apps-0.0.8_rc5-r1.ebuild
new file mode 100644
index 000000000000..b2cbb93ef638
--- /dev/null
+++ b/media-radio/ax25-apps/ax25-apps-0.0.8_rc5-r1.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+MY_P="${P/_/-}"
+
+DESCRIPTION="Basic AX.25 (Amateur Radio) user tools, additional daemons"
+HOMEPAGE="
+	https://linux-ax25.in-berlin.de/
+	https://packet-radio.net/ax-25/
+" # NOTE: ...in-berlin.de does not work but subdomains do
+SRC_URI="
+	https://linux-ax25.in-berlin.de/pub/${PN}/${MY_P}.tar.gz
+	https://ham.packet-radio.net/packet/ax25/ax25-apps/${MY_P}.tar.gz
+"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+
+RDEPEND="
+	>=dev-libs/libax25-0.0.12_rc2:=
+	sys-libs/ncurses:=
+	!dev-ruby/listen
+"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+src_prepare() {
+	# fix missing prototype for malloc
+	sed -i -e "/^#include /i #include <stdlib.h>" ax25ipd/routing.c || die
+	eapply "${FILESDIR}"/${PN}-0.0.8_rc5-tinfo.patch
+	eapply_user
+	eautoreconf
+}
+
+src_install() {
+	default
+
+	newinitd "${FILESDIR}"/ax25ipd.rc ax25ipd
+	newinitd "${FILESDIR}"/ax25mond.rc ax25mond
+	newinitd "${FILESDIR}"/ax25rtd.rc ax25rtd
+
+	# HACK: one should not create instead of removing
+	rm -r "${ED}"/usr/share/doc/${PF} || die
+
+	dodoc AUTHORS ChangeLog NEWS README ax25ipd/README.ax25ipd \
+		ax25rtd/README.ax25rtd ax25ipd/HISTORY.ax25ipd ax25rtd/TODO.ax25rtd
+
+	dodir /var/lib/ax25/ax25rtd
+	touch "${ED}"/var/lib/ax25/ax25rtd/ax25_route || die
+	touch "${ED}"/var/lib/ax25/ax25rtd/ip_route || die
+}