[gentoo-commits] repo/gentoo:master commit in: dev-python/PyQt5/

["Ionen Wolkens" <ionen@gentoo.org>]

commit:     9ff196b80485ea3318cf5bc5a2afbcce591580bf
Author:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
AuthorDate: Fri Jul 19 12:12:14 2024 +0000
Commit:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
CommitDate: Fri Jul 19 14:39:14 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9ff196b8

dev-python/PyQt5: add 5.15.11

Signed-off-by: Ionen Wolkens <ionen <AT> gentoo.org>

 dev-python/PyQt5/Manifest             |   1 +
 dev-python/PyQt5/PyQt5-5.15.11.ebuild | 171 ++++++++++++++++++++++++++++++++++
 2 files changed, 172 insertions(+)

diff --git a/dev-python/PyQt5/Manifest b/dev-python/PyQt5/Manifest
index 75a7e4df030b..c706635f817c 100644
--- a/dev-python/PyQt5/Manifest
+++ b/dev-python/PyQt5/Manifest
@@ -1 +1,2 @@
 DIST PyQt5-5.15.10.tar.gz 3242654 BLAKE2B 55a4cedf1ac3fd0f2968ca07544d2248d1798f134b7490eb1d07663af9f1606543564a42d5478871f5dbfc0b249b73965fd0505261fd2872c724da6d28e5b61a SHA512 e62debe112210b68993377264448199b66a43fc5db13c583a25e210759f5cd945bd1056c1c19fb86bcf005c6904358dfb89e005d27167a349f1d55987a63013e
+DIST PyQt5-5.15.11.tar.gz 3216775 BLAKE2B 5bc6cb12b8189ec0767be891971a9fd35109236eb4753eb77940104b71bbf78db4ed2354c54adf5d45655a8ded1cb10033afc037d8a3604c5db3ea073d394e0c SHA512 e52ca215f65dbb035deff042112e26be38b77405a45caebdae3e626ffe6487c88c97c54bfa33cc83d96537daa82b67b7a1c621696538e154e5996714fc063a92

diff --git a/dev-python/PyQt5/PyQt5-5.15.11.ebuild b/dev-python/PyQt5/PyQt5-5.15.11.ebuild
new file mode 100644
index 000000000000..45dd2af8a8f1
--- /dev/null
+++ b/dev-python/PyQt5/PyQt5-5.15.11.ebuild
@@ -0,0 +1,171 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=sip
+PYPI_NO_NORMALIZE=1
+PYTHON_COMPAT=( python3_{10..13} )
+inherit distutils-r1 flag-o-matic multiprocessing pypi qmake-utils
+
+DESCRIPTION="Python bindings for the Qt framework"
+HOMEPAGE="https://www.riverbankcomputing.com/software/pyqt/"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
+
+IUSE="
+	bluetooth dbus debug declarative designer examples gles2-only gui help location
+	multimedia network opengl positioning printsupport sensors serialport speech
+	sql +ssl svg testlib webchannel websockets widgets x11extras xmlpatterns
+"
+
+# The requirements below were extracted from the qmake_QT declarations
+# in project.py and from the output of 'grep -r "%Import " ${S}/sip'
+REQUIRED_USE="
+	bluetooth? ( gui )
+	declarative? ( gui network )
+	designer? ( widgets )
+	help? ( gui widgets )
+	location? ( positioning )
+	multimedia? ( gui network )
+	opengl? ( gui widgets )
+	positioning? ( gui )
+	printsupport? ( gui widgets )
+	sensors? ( gui )
+	serialport? ( gui )
+	sql? ( widgets )
+	svg? ( gui widgets )
+	testlib? ( widgets )
+	webchannel? ( network )
+	websockets? ( network )
+	widgets? ( gui )
+	xmlpatterns? ( network )
+"
+
+# Minimal supported version of Qt.
+QT_PV="5.15:5"
+
+DEPEND="
+	>=dev-qt/qtcore-${QT_PV}
+	>=dev-qt/qtxml-${QT_PV}
+	bluetooth? ( >=dev-qt/qtbluetooth-${QT_PV} )
+	dbus? (
+		dev-python/dbus-python[${PYTHON_USEDEP}]
+		>=dev-qt/qtdbus-${QT_PV}
+		sys-apps/dbus
+	)
+	declarative? ( >=dev-qt/qtdeclarative-${QT_PV}[widgets?] )
+	designer? ( >=dev-qt/designer-${QT_PV} )
+	gui? ( >=dev-qt/qtgui-${QT_PV}[gles2-only=] )
+	help? ( >=dev-qt/qthelp-${QT_PV} )
+	location? ( >=dev-qt/qtlocation-${QT_PV} )
+	multimedia? ( >=dev-qt/qtmultimedia-${QT_PV}[widgets?] )
+	network? ( >=dev-qt/qtnetwork-${QT_PV}[ssl=] )
+	opengl? ( >=dev-qt/qtopengl-${QT_PV} )
+	positioning? ( >=dev-qt/qtpositioning-${QT_PV} )
+	printsupport? ( >=dev-qt/qtprintsupport-${QT_PV} )
+	sensors? ( >=dev-qt/qtsensors-${QT_PV} )
+	serialport? ( >=dev-qt/qtserialport-${QT_PV} )
+	speech? ( >=dev-qt/qtspeech-${QT_PV} )
+	sql? ( >=dev-qt/qtsql-${QT_PV} )
+	svg? ( >=dev-qt/qtsvg-${QT_PV} )
+	testlib? ( >=dev-qt/qttest-${QT_PV} )
+	webchannel? ( >=dev-qt/qtwebchannel-${QT_PV} )
+	websockets? ( >=dev-qt/qtwebsockets-${QT_PV} )
+	widgets? ( >=dev-qt/qtwidgets-${QT_PV} )
+	x11extras? ( >=dev-qt/qtx11extras-${QT_PV} )
+	xmlpatterns? ( >=dev-qt/qtxmlpatterns-${QT_PV} )
+"
+RDEPEND="
+	${DEPEND}
+	>=dev-python/PyQt5-sip-12.15:=[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/PyQt-builder-1.14.1[${PYTHON_USEDEP}]
+	>=dev-python/sip-6.8.6[${PYTHON_USEDEP}]
+	>=dev-qt/qtcore-${QT_PV}
+	dbus? ( virtual/pkgconfig )
+"
+
+src_prepare() {
+	default
+
+	# hack: PyQt-builder runs qmake without our arguments and calls g++
+	# or clang++ depending on what qtbase was built with, not used for
+	# building but fails with -native-symlinks
+	mkdir "${T}"/cxx || die
+	local cxx
+	! cxx=$(type -P "${CHOST}"-g++) || ln -s -- "${cxx}" "${T}"/cxx/g++ || die
+	! cxx=$(type -P "${CHOST}"-clang++) || ln -s -- "${cxx}" "${T}"/cxx/clang++ || die
+	PATH=${T}/cxx:${PATH}
+}
+
+python_configure_all() {
+	append-cxxflags ${CPPFLAGS} # respect CPPFLAGS notably for DISTUTILS_EXT=1
+
+	pyqt_use_enable() {
+		local state=$(usex ${1} --enable= --disable=)
+		shift
+		echo ${*/#/${state}}
+	}
+
+	DISTUTILS_ARGS=(
+		--jobs="$(makeopts_jobs)"
+		--qmake="$(qt5_get_bindir)"/qmake
+		--qmake-setting="$(qt5_get_qmake_args)"
+		--verbose
+		--confirm-license
+
+		--enable=pylupdate
+		--enable=pyrcc
+		--enable=Qt
+		--enable=QtCore
+		$(pyqt_use_enable bluetooth QtBluetooth)
+		$(pyqt_use_enable dbus QtDBus)
+		$(pyqt_use_enable declarative QtQml QtQuick \
+			$(usev widgets QtQuickWidgets))
+		$(pyqt_use_enable designer QtDesigner)
+		$(pyqt_use_enable gui QtGui \
+			$(use gles2-only && echo _QOpenGLFunctions_ES2 || echo _QOpenGLFunctions_{2_0,2_1,4_1_Core}))
+		$(pyqt_use_enable help QtHelp)
+		$(pyqt_use_enable location QtLocation)
+		$(pyqt_use_enable multimedia QtMultimedia \
+			$(usev widgets QtMultimediaWidgets))
+		$(pyqt_use_enable network QtNetwork)
+		$(pyqt_use_enable opengl QtOpenGL)
+		$(pyqt_use_enable positioning QtPositioning)
+		$(pyqt_use_enable printsupport QtPrintSupport)
+		$(pyqt_use_enable sensors QtSensors)
+		$(pyqt_use_enable serialport QtSerialPort)
+		$(pyqt_use_enable speech QtTextToSpeech)
+		$(pyqt_use_enable sql QtSql)
+		$(pyqt_use_enable svg QtSvg)
+		$(pyqt_use_enable testlib QtTest)
+		$(pyqt_use_enable webchannel QtWebChannel)
+		$(pyqt_use_enable websockets QtWebSockets)
+		$(pyqt_use_enable widgets QtWidgets)
+		$(pyqt_use_enable x11extras QtX11Extras)
+		--enable=QtXml
+		$(pyqt_use_enable xmlpatterns QtXmlPatterns)
+
+		$(usev debug '--debug --qml-debug --tracing')
+
+		$(usev !dbus --no-dbus-python)
+		# note: upstream currently intentionally skips installing these two
+		# plugins when using wheels w/ pep517 so, *if* something does need
+		# them, it will need to be handled manually
+		$(usev !declarative --no-qml-plugin)
+		$(usev !designer --no-designer-plugin)
+
+		$(usev gles2-only --disabled-feature=PyQt_Desktop_OpenGL)
+		$(usev !ssl --disabled-feature=PyQt_SSL)
+	)
+}
+
+python_install_all() {
+	einstalldocs
+	use examples && dodoc -r examples
+}