[gentoo-commits] repo/gentoo:master commit in: app-misc/gnote/

["Pacho Ramos" <pacho@gentoo.org>]

commit:     58b4009ee3e7d429dac9c24838a633d2b8854f6a
Author:     Guillermo Joandet <gjoandet <AT> gmail <DOT> com>
AuthorDate: Tue Jan 30 20:26:41 2024 +0000
Commit:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
CommitDate: Tue Jul 16 08:44:03 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=58b4009e

app-misc/gnote: Bump to 46.0

Signed-off-by: Guillermo Joandet <gjoandet <AT> gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/35105
Signed-off-by: Pacho Ramos <pacho <AT> gentoo.org>

 app-misc/gnote/gnote-46.0.ebuild | 64 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 64 insertions(+)

diff --git a/app-misc/gnote/gnote-46.0.ebuild b/app-misc/gnote/gnote-46.0.ebuild
new file mode 100644
index 000000000000..e0bd196b9d2c
--- /dev/null
+++ b/app-misc/gnote/gnote-46.0.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome2 meson readme.gentoo-r1
+
+DESCRIPTION="Desktop note-taking application"
+HOMEPAGE="https://wiki.gnome.org/Apps/Gnote"
+
+LICENSE="GPL-3+ FDL-1.1"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~riscv ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	>=dev-libs/glib-2.74:2[dbus]
+	>=dev-cpp/glibmm-2.74:2.68
+	>=dev-cpp/gtkmm-4.10.0:4.0
+	>=gui-libs/libadwaita-1
+	>=app-crypt/libsecret-0.8
+	>=dev-libs/libxml2-2:2
+	dev-libs/libxslt
+	>=sys-apps/util-linux-2.16
+	test? ( dev-libs/unittest++ )
+"
+RDEPEND="${DEPEND}
+	gnome-base/gsettings-desktop-schemas
+"
+BDEPEND="
+	dev-util/itstool
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	default
+
+	# Build system requires UnitTest++ >=1.5.1, but the .pc file doesn't
+	# specify a version
+	sed -i -e "/UnitTest++/ s/version: [^,]*,//" meson.build || die
+	if ! use test; then
+		sed -i -e "/unit_test_pp/ s/ = .*/ = disabler()/" meson.build || die
+	fi
+
+	if has_version net-fs/wdfs; then
+		DOC_CONTENTS="You have net-fs/wdfs installed. app-misc/gnote will use it to
+		synchronize notes."
+	else
+		DOC_CONTENTS="Gnote can use net-fs/wdfs to synchronize notes.
+		If you want to use that functionality just emerge net-fs/wdfs.
+		Gnote will automatically detect that you did and let you use it."
+	fi
+}
+
+src_install() {
+	meson_src_install
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+	readme.gentoo_print_elog
+}