[gentoo-commits] repo/gentoo:master commit in: gnome-extra/gnome-calculator/

["Pacho Ramos" <pacho@gentoo.org>]

commit:     ab4376f96f96d3a4672518cb6de2763d0a42d8fd
Author:     Guillermo Joandet <gjoandet <AT> gmail <DOT> com>
AuthorDate: Wed May  8 03:59:38 2024 +0000
Commit:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
CommitDate: Tue Jul 16 08:40:32 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ab4376f9

gnome-extra/gnome-calculator: Bump to 46.1

Signed-off-by: Guillermo Joandet <gjoandet <AT> gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/34677
Signed-off-by: Pacho Ramos <pacho <AT> gentoo.org>

 gnome-extra/gnome-calculator/Manifest              |  1 +
 .../gnome-calculator/gnome-calculator-46.1.ebuild  | 74 ++++++++++++++++++++++
 2 files changed, 75 insertions(+)

diff --git a/gnome-extra/gnome-calculator/Manifest b/gnome-extra/gnome-calculator/Manifest
index 6b3016dd7bca..e8b743374957 100644
--- a/gnome-extra/gnome-calculator/Manifest
+++ b/gnome-extra/gnome-calculator/Manifest
@@ -1 +1,2 @@
 DIST gnome-calculator-45.0.2.tar.xz 1100744 BLAKE2B a013985dc6227ae1a3bff30d92740ea4b18765ce5486171a0d0aaf3feae89357f1fe47ede26175a546a01e5b49206a2768de9f5cd62de8f1ee01645bae213614 SHA512 93248846f285badd4ef4303a31cfa6926deb1d37b0ba8ef7b1971795e092c115004c6bb666469a9e8e02a8e55e8f44d34cff6b88c0816888dc42c36fa1148b2e
+DIST gnome-calculator-46.1.tar.xz 1121236 BLAKE2B b6dbd7b0d7cb38f0f9081fcf409b5e7df0d45cfcee5220880d9971066ac9984cb439e74ebc8fa6c73c6c9b7e2ece6aa4db3503da4f5ecab7c5d6fd5b5ca452a3 SHA512 b859a35e614ea5415fbb7a03663f1bf184e7f108882c2093511142d8c067e42f6dd11973cc047552bdd9a74d8ee7e39a00ca42009bea739d2b088b2f90affde1

diff --git a/gnome-extra/gnome-calculator/gnome-calculator-46.1.ebuild b/gnome-extra/gnome-calculator/gnome-calculator-46.1.ebuild
new file mode 100644
index 000000000000..8aa1b533b6f1
--- /dev/null
+++ b/gnome-extra/gnome-calculator/gnome-calculator-46.1.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org gnome2-utils meson vala virtualx xdg
+
+DESCRIPTION="A calculator application for GNOME"
+HOMEPAGE="https://wiki.gnome.org/Apps/Calculator"
+
+LICENSE="GPL-3+"
+SLOT="0"
+IUSE="+introspection test"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
+
+# gtksourceview vapi definitions in dev-lang/vala itself are too old, and newer vala removes them
+# altogether, thus we need them installed by gtksourceview[vala]
+RDEPEND="
+	>=dev-libs/glib-2.40.0:2
+	dev-libs/libxml2:2
+	>=net-libs/libsoup-3.4.0:3.0
+	>=dev-libs/libgee-0.20.0:0.8=
+	dev-libs/mpc:=
+	dev-libs/mpfr:0=
+	>=gui-libs/gtk-4.11.4:4
+	>=gui-libs/libadwaita-1.4_alpha:1
+	>=gui-libs/gtksourceview-5.3.0:5
+	introspection? ( >=dev-libs/gobject-introspection-1.58:= )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-libs/appstream-glib
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	$(vala_depend)
+	net-libs/libsoup:3.0[vala]
+	gui-libs/gtksourceview:5[vala]
+	gui-libs/libhandy:1[vala]
+"
+
+src_prepare() {
+	default
+	vala_setup
+	xdg_environment_reset
+}
+
+src_configure() {
+	local emesonargs=(
+		-Ddisable-ui=false
+		#-Dvala-version # doesn't do anything in 3.34
+		$(meson_use !introspection disable-introspection)
+		$(meson_use test ui-tests)
+		-Dgcalc=true
+		-Dgci=true
+		-Dapp=true
+		-Ddoc=false
+	)
+	meson_src_configure
+}
+
+src_test() {
+	XDG_SESSION_TYPE=x11 virtx dbus-run-session meson test -C "${BUILD_DIR}" || die 'tests failed'
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}