[gentoo-commits] repo/gentoo:master commit in: net-analyzer/testssl/

["Conrad Kostecki" <conikost@gentoo.org>]

commit:     78e9c04c590c559a8dbf88a740c85a04df0507cd
Author:     Michael Mair-Keimberger <mmk <AT> levelnine <DOT> at>
AuthorDate: Wed Jul  3 09:56:07 2024 +0000
Commit:     Conrad Kostecki <conikost <AT> gentoo <DOT> org>
CommitDate: Fri Jul  5 17:41:15 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=78e9c04c

net-analyzer/testssl: add 3.0.9

Signed-off-by: Michael Mair-Keimberger <mmk <AT> levelnine.at>
Closes: https://github.com/gentoo/gentoo/pull/37407
Signed-off-by: Conrad Kostecki <conikost <AT> gentoo.org>

 net-analyzer/testssl/Manifest             |  1 +
 net-analyzer/testssl/testssl-3.0.9.ebuild | 73 +++++++++++++++++++++++++++++++
 2 files changed, 74 insertions(+)

diff --git a/net-analyzer/testssl/Manifest b/net-analyzer/testssl/Manifest
index aaca702899cd..744d8087d8c1 100644
--- a/net-analyzer/testssl/Manifest
+++ b/net-analyzer/testssl/Manifest
@@ -1 +1,2 @@
 DIST testssl-3.0.8.tar.gz 9372229 BLAKE2B cf463236fb0812c2bc5fd5673d0d2d395fc405697817827ee8c660c96d789601a090b57febd48400e33fd9f28b23d42d432734b176b23a8e8ddf710c9b275485 SHA512 4634bc5dc57ad8910ca097b22d86511a26e855fb4dc7bef9550a795cb1f53a959b8472008756b40a670d7433ad56236b5a36fe0c88c15de99fdf586e9919b080
+DIST testssl-3.0.9.tar.gz 9381651 BLAKE2B 424569411022b68f105a20ad5b60db7c8994d1170482612ae7aed741230bd3fca43cd853dfb00660d5ba7cfdc717fa887a2fe9b6c59bbcef881f8f6473ccad3e SHA512 006180d175492f1cba6d056a92a57247725d4b68cddbebeea80a5d339d542f5103ddc8226f3a554775cb83bbef836a5d5bfc1bcf4fba7b18b9541473122ff720

diff --git a/net-analyzer/testssl/testssl-3.0.9.ebuild b/net-analyzer/testssl/testssl-3.0.9.ebuild
new file mode 100644
index 000000000000..9912fcbe13ac
--- /dev/null
+++ b/net-analyzer/testssl/testssl-3.0.9.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_PN="${PN}.sh"
+MY_PV="${PV/_p/-}"
+
+DESCRIPTION="Tool to check TLS/SSL cipher support"
+HOMEPAGE="https://testssl.sh/"
+SRC_URI="https://github.com/drwetter/${MY_PN}/archive/v${MY_PV}.tar.gz -> ${P}.tar.gz"
+S=${WORKDIR}/${MY_PN}-${MY_PV}
+
+LICENSE="GPL-2 bundled-openssl? ( openssl )"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="bundled-openssl kerberos"
+
+RDEPEND="
+	app-shells/bash[net]
+	net-dns/bind-tools
+	sys-apps/util-linux
+	sys-libs/ncurses:0
+	sys-process/procps
+	bundled-openssl? (
+		kerberos? (
+			sys-libs/zlib
+			virtual/krb5
+		)
+	)
+	!bundled-openssl? ( dev-libs/openssl:0 )
+"
+
+QA_PREBUILT="opt/${PN}/*"
+
+pkg_setup() {
+	if use amd64; then
+		if use kerberos; then
+			BUNDLED_OPENSSL="openssl.Linux.x86_64.krb"
+		else
+			BUNDLED_OPENSSL="openssl.Linux.x86_64"
+		fi
+	elif use x86; then
+		BUNDLED_OPENSSL="openssl.Linux.i686"
+	fi
+}
+
+src_prepare() {
+	default
+	sed -i ${PN}.sh \
+		-e 's|TESTSSL_INSTALL_DIR="${TESTSSL_INSTALL_DIR:-""}"|TESTSSL_INSTALL_DIR="/"|' \
+		-e 's|$TESTSSL_INSTALL_DIR/etc/|&testssl/|g' || die
+
+	if use bundled-openssl; then
+		sed -i ${PN}.sh \
+			-e "/find_openssl_binary()/a OPENSSL=\"/opt/${PN}/${BUNDLED_OPENSSL}\"" || die
+	fi
+}
+
+src_install() {
+	dodoc CHANGELOG.md CREDITS.md Readme.md
+	dodoc openssl-iana.mapping.html
+
+	dobin ${PN}.sh
+
+	insinto /etc/${PN}
+	doins etc/*
+
+	if use bundled-openssl; then
+		exeinto /opt/${PN}
+		use amd64 && doexe bin/${BUNDLED_OPENSSL}
+	fi
+}