[gentoo-commits] repo/gentoo:master commit in: dev-games/clanlib/

["Eli Schwartz" <eschwartz@gentoo.org>]

commit:     81d83040e872fba7f5fbd318f56e01e3aa69a1e9
Author:     Eli Schwartz <eschwartz93 <AT> gmail <DOT> com>
AuthorDate: Sun Jun 30 23:55:45 2024 +0000
Commit:     Eli Schwartz <eschwartz <AT> gentoo <DOT> org>
CommitDate: Wed Jul  3 22:36:47 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=81d83040

dev-games/clanlib: update EAPI 7 -> 8

Signed-off-by: Eli Schwartz <eschwartz93 <AT> gmail.com>
Signed-off-by: Eli Schwartz <eschwartz <AT> gentoo.org>

 dev-games/clanlib/clanlib-0.8.1-r3.ebuild | 106 ++++++++++++++++++++++++++++++
 dev-games/clanlib/clanlib-2.3.7-r4.ebuild |   2 +-
 dev-games/clanlib/clanlib-4.1.0-r1.ebuild |  77 ++++++++++++++++++++++
 3 files changed, 184 insertions(+), 1 deletion(-)

diff --git a/dev-games/clanlib/clanlib-0.8.1-r3.ebuild b/dev-games/clanlib/clanlib-0.8.1-r3.ebuild
new file mode 100644
index 000000000000..91061dde6339
--- /dev/null
+++ b/dev-games/clanlib/clanlib-0.8.1-r3.ebuild
@@ -0,0 +1,106 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools flag-o-matic
+
+DESCRIPTION="Multi-platform game development library"
+HOMEPAGE="https://github.com/sphair/ClanLib"
+SRC_URI="mirror://gentoo/ClanLib-${PV}.tgz"
+S="${WORKDIR}"/ClanLib-${PV}
+
+LICENSE="ZLIB"
+SLOT="0.8"
+# Not big endian safe! #82779
+KEYWORDS="~amd64 ~x86"
+IUSE="doc ipv6 mikmod opengl sdl static-libs vorbis"
+
+# opengl keyword does not drop the GL/GLU requirement.
+# Autoconf files need to be fixed
+RDEPEND="
+	media-libs/alsa-lib
+	media-libs/libpng:0
+	virtual/jpeg:0
+	virtual/glu
+	virtual/opengl
+	x11-libs/libXi
+	x11-libs/libXmu
+	x11-libs/libXxf86vm
+	mikmod? ( media-libs/libmikmod )
+	sdl? (
+		media-libs/libsdl[X]
+		media-libs/sdl-gfx
+	)
+	vorbis? ( media-libs/libvorbis )
+"
+DEPEND="
+	${RDEPEND}
+	x11-base/xorg-proto
+"
+
+PATCHES=(
+	"${FILESDIR}/${P}-ndebug.patch"
+	"${FILESDIR}/${P}-gcc43.patch"
+	"${FILESDIR}/${P}-gcc44.patch"
+	"${FILESDIR}/${P}-gcc47.patch"
+	"${FILESDIR}/${P}-gcc6.patch"
+	"${FILESDIR}/${P}-llvm.patch"
+	"${FILESDIR}/${P}-libpng15.patch"
+	"${FILESDIR}/${P}-docbuilder.patch"
+	"${FILESDIR}/${P}-glibc2.34.patch"
+	"${FILESDIR}/${P}-gcc12.patch"
+	"${FILESDIR}"/${P}-makefile-duplicate-headers.patch
+)
+
+DOCS=(
+	CODING_STYLE CREDITS NEWS PATCHES
+	README{,.anjuta,.distros,.kdevelop,.sdl,.upgrade} INSTALL.linux
+)
+
+src_prepare() {
+	default
+	eautoreconf
+	# See #739358
+	sed -i -e "s:libdir=\${exec_prefix}/lib:libdir=@libdir@:g" \
+		pkgconfig/*.pc.in || die
+}
+
+src_configure() {
+	# -Werror=strict-aliasing
+	# https://bugs.gentoo.org/855308
+	# Fixed in newer versions
+	# Do not trust with LTO either.
+	append-flags -fno-strict-aliasing
+	filter-lto
+
+	# clanSound only controls mikmod/vorbis so there's
+	# no need to pass --{en,dis}able-clanSound ...
+	# clanDisplay only controls X, SDL, OpenGL plugins
+	# so no need to pass --{en,dis}able-clanDisplay
+	# also same reason why we don't have to use clanGUI
+	econf \
+		--enable-dyn \
+		--enable-clanNetwork \
+		$(use_enable x86 asm386) \
+		$(use_enable doc docs) \
+		$(use_enable opengl clanGL) \
+		$(use_enable sdl clanSDL) \
+		$(use_enable vorbis clanVorbis) \
+		$(use_enable mikmod clanMikMod) \
+		$(use_enable ipv6 getaddr) \
+		$(use_enable static-libs static)
+}
+
+src_install() {
+	default
+
+	if use doc ; then
+		dodir /usr/share/doc/${PF}/html
+		mv "${D}"/usr/share/doc/clanlib/* "${D}"/usr/share/doc/${PF}/html/ || die
+		rm -rf "${D}"/usr/share/doc/clanlib
+		cp -r Examples Resources "${D}"/usr/share/doc/${PF}/ || die
+	fi
+
+	find "${ED}" -name '*.la' -delete || die
+}

diff --git a/dev-games/clanlib/clanlib-2.3.7-r4.ebuild b/dev-games/clanlib/clanlib-2.3.7-r4.ebuild
index 6ba2413bff53..24cbee039a3e 100644
--- a/dev-games/clanlib/clanlib-2.3.7-r4.ebuild
+++ b/dev-games/clanlib/clanlib-2.3.7-r4.ebuild
@@ -1,7 +1,7 @@
 # Copyright 1999-2024 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=7
+EAPI=8
 
 inherit autotools toolchain-funcs
 

diff --git a/dev-games/clanlib/clanlib-4.1.0-r1.ebuild b/dev-games/clanlib/clanlib-4.1.0-r1.ebuild
new file mode 100644
index 000000000000..8ddb515551e2
--- /dev/null
+++ b/dev-games/clanlib/clanlib-4.1.0-r1.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools toolchain-funcs
+
+MY_PN=ClanLib
+
+DESCRIPTION="Multi-platform game development library"
+HOMEPAGE="https://github.com/sphair/ClanLib"
+SRC_URI="https://github.com/sphair/${MY_PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+LICENSE="ZLIB"
+SLOT="4.1"
+KEYWORDS="~amd64 ~x86" #not big endian safe #82779
+IUSE="cpu_flags_x86_sse2 doc examples ipv6 opengl +sound static-libs X"
+REQUIRED_USE="opengl? ( X )"
+
+RDEPEND="
+	sys-libs/zlib
+	X? (
+		media-libs/freetype:2
+		media-libs/fontconfig
+		x11-libs/libX11
+		opengl? (
+			virtual/opengl
+			x11-libs/libXrender
+		)
+	)
+	sound? ( media-libs/alsa-lib )"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	doc? (
+		app-text/doxygen
+		dev-lang/perl
+		media-gfx/graphviz
+	)"
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		$(use_enable doc docs)
+		$(use_enable cpu_flags_x86_sse2 sse2)
+		$(use_enable opengl clanGL)
+		$(use_enable opengl clanUI)
+		$(use_enable X clanDisplay)
+		$(use_enable sound clanSound)
+		$(use_enable ipv6 getaddr)
+		$(use_enable static-libs static)
+	)
+
+	tc-export PKG_CONFIG
+
+	econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+	default
+	use doc && emake html
+}
+
+src_install() {
+	default
+
+	use doc && emake DESTDIR="${D}" install-html
+	use examples && dodoc -r Examples Resources
+
+	# package provides .pc files
+	find "${ED}" -name '*.la' -delete || die
+}