[gentoo-commits] repo/gentoo:master commit in: dev-libs/criterion/

["Conrad Kostecki" <conikost@gentoo.org>]

commit:     97e989e02fc713607c71cb6948ec8e4390b2b671
Author:     Tomáš Mózes <hydrapolic <AT> gmail <DOT> com>
AuthorDate: Tue May 28 15:54:07 2024 +0000
Commit:     Conrad Kostecki <conikost <AT> gentoo <DOT> org>
CommitDate: Sat Jun 22 19:09:51 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=97e989e0

dev-libs/criterion: enable py3.12

Bug: https://bugs.gentoo.org/929407
Signed-off-by: Tomáš Mózes <hydrapolic <AT> gmail.com>
Signed-off-by: Conrad Kostecki <conikost <AT> gentoo.org>

 dev-libs/criterion/criterion-2.4.1-r1.ebuild | 71 ++++++++++++++++++++++++++++
 1 file changed, 71 insertions(+)

diff --git a/dev-libs/criterion/criterion-2.4.1-r1.ebuild b/dev-libs/criterion/criterion-2.4.1-r1.ebuild
new file mode 100644
index 000000000000..9ac50fdbef62
--- /dev/null
+++ b/dev-libs/criterion/criterion-2.4.1-r1.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit flag-o-matic meson python-any-r1
+
+DEBUGBREAK_COMMIT="6b79ec8d8f8d4603111f580a0537f8f31c484c32"
+KLIB_COMMIT="cdb7e9236dc47abf8da7ebd702cc6f7f21f0c502"
+NANOPB_COMMIT="c9124132a604047d0ef97a09c0e99cd9bed2c818"
+
+DESCRIPTION="Cross platform unit testing framework for C and C++"
+HOMEPAGE="https://github.com/Snaipe/Criterion"
+SRC_URI="https://github.com/Snaipe/Criterion/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz
+	https://github.com/scottt/debugbreak/archive/${DEBUGBREAK_COMMIT}.tar.gz -> debugbreak-${DEBUGBREAK_COMMIT}.tar.gz
+	https://github.com/attractivechaos/klib/archive/${KLIB_COMMIT}.tar.gz -> klib-${KLIB_COMMIT}.tar.gz
+	https://github.com/nanopb/nanopb/archive/${NANOPB_COMMIT}.tar.gz -> nanopb-${NANOPB_COMMIT}.tar.gz"
+
+S="${WORKDIR}/Criterion-${PV}"
+LICENSE="BSD-2 MIT ZLIB"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="dev-libs/nanomsg:=
+	dev-libs/libgit2:=
+	dev-libs/libffi:="
+DEPEND="${RDEPEND}
+	>=dev-libs/boxfort-0.1.4
+	test? (
+		$(python_gen_any_dep 'dev-util/cram[${PYTHON_USEDEP}]')
+	)"
+BDEPEND="dev-build/cmake
+	virtual/pkgconfig"
+
+python_check_deps() {
+	has_version "dev-util/cram[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+
+	rm -r dependencies/{debugbreak,klib} || die
+	mv "${WORKDIR}/debugbreak-${DEBUGBREAK_COMMIT}" dependencies/debugbreak || die
+	mv "${WORKDIR}/klib-${KLIB_COMMIT}" dependencies/klib || die
+	mv "${WORKDIR}/nanopb-${NANOPB_COMMIT}" subprojects/nanopb || die
+}
+
+src_configure() {
+	# -Werror=lto-type-mismatch
+	# https://bugs.gentoo.org/855674
+	# https://github.com/Snaipe/Criterion/issues/524
+	filter-lto
+
+	# bug 906379
+	use elibc_musl && append-cppflags -D_LARGEFILE64_SOURCE
+
+	local emesonargs=(
+		-Dsamples=$(usex test true false)
+		-Dtests=$(usex test true false)
+	)
+
+	meson_src_configure
+}