[gentoo-commits] repo/gentoo:master commit in: dev-python/pyquery/

["Michał Górny" <mgorny@gentoo.org>]

commit:     18ab2fc5c7cde5dbd58c4b408e578287b9aea517
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sat Jun 15 13:11:56 2024 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sat Jun 15 13:14:32 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=18ab2fc5

dev-python/pyquery: Merge py3.13 revbump back

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/pyquery/pyquery-2.0.0-r1.ebuild | 61 ------------------------------
 dev-python/pyquery/pyquery-2.0.0.ebuild    | 20 +++++-----
 2 files changed, 11 insertions(+), 70 deletions(-)

diff --git a/dev-python/pyquery/pyquery-2.0.0-r1.ebuild b/dev-python/pyquery/pyquery-2.0.0-r1.ebuild
deleted file mode 100644
index 52f4f8a405c6..000000000000
--- a/dev-python/pyquery/pyquery-2.0.0-r1.ebuild
+++ /dev/null
@@ -1,61 +0,0 @@
-# Copyright 1999-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( python3_{10..13} pypy3 )
-
-inherit distutils-r1 optfeature pypi
-
-DESCRIPTION="A jQuery-like library for python"
-HOMEPAGE="
-	https://github.com/gawel/pyquery/
-	https://pypi.org/project/pyquery/
-"
-
-LICENSE="BSD"
-SLOT="0"
-KEYWORDS="~amd64"
-
-RDEPEND="
-	>=dev-python/lxml-2.1[${PYTHON_USEDEP}]
-	>=dev-python/cssselect-1.2.0[${PYTHON_USEDEP}]
-	>=dev-python/webob-1.1.9[${PYTHON_USEDEP}]
-"
-DEPEND="
-	test? (
-		dev-python/beautifulsoup4[${PYTHON_USEDEP}]
-		dev-python/requests[${PYTHON_USEDEP}]
-		dev-python/webtest[${PYTHON_USEDEP}]
-		dev-python/webob[${PYTHON_USEDEP}]
-	)
-"
-
-distutils_enable_tests pytest
-
-python_test() {
-	local EPYTEST_DESELECT=(
-		# needs network
-		tests/test_pyquery.py::TestWebScrappingEncoding::test_get
-		# known breakage, can't do much about it unless we force old
-		# libxml2 for everyone, sigh
-		# https://github.com/gawel/pyquery/issues/248
-		tests/test_pyquery.py::TestXMLNamespace::test_selector_html
-	)
-	case ${EPYTHON} in
-		python3.1[23])
-			EPYTEST_DESELECT+=(
-				# doctest failing because of changed repr()
-				# https://github.com/gawel/pyquery/issues/249
-				pyquery/pyquery.py::pyquery.pyquery.PyQuery.serialize_dict
-			)
-			;;
-	esac
-
-	epytest
-}
-
-pkg_postinst() {
-	optfeature "Support for BeautifulSoup3 as a parser backend" dev-python/beautifulsoup4
-}

diff --git a/dev-python/pyquery/pyquery-2.0.0.ebuild b/dev-python/pyquery/pyquery-2.0.0.ebuild
index a72d907f5f71..53a5466a739b 100644
--- a/dev-python/pyquery/pyquery-2.0.0.ebuild
+++ b/dev-python/pyquery/pyquery-2.0.0.ebuild
@@ -1,10 +1,10 @@
-# Copyright 1999-2023 Gentoo Authors
+# Copyright 1999-2024 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
 
 DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( python3_{10..12} pypy3 )
+PYTHON_COMPAT=( python3_{10..13} pypy3 )
 
 inherit distutils-r1 optfeature pypi
 
@@ -43,13 +43,15 @@ python_test() {
 		# https://github.com/gawel/pyquery/issues/248
 		tests/test_pyquery.py::TestXMLNamespace::test_selector_html
 	)
-	if [[ ${EPYTHON} == python3.12 ]]; then
-		EPYTEST_DESELECT+=(
-			# doctest failing because of changed repr()
-			# https://github.com/gawel/pyquery/issues/249
-			pyquery/pyquery.py::pyquery.pyquery.PyQuery.serialize_dict
-		)
-	fi
+	case ${EPYTHON} in
+		python3.1[23])
+			EPYTEST_DESELECT+=(
+				# doctest failing because of changed repr()
+				# https://github.com/gawel/pyquery/issues/249
+				pyquery/pyquery.py::pyquery.pyquery.PyQuery.serialize_dict
+			)
+			;;
+	esac
 
 	epytest
 }