[gentoo-commits] repo/gentoo:master commit in: media-sound/cava/

["Ionen Wolkens" <ionen@gentoo.org>]

commit:     929b34fedddb69597b7cb0eebdf65cebc82bec12
Author:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
AuthorDate: Thu Jun  6 12:53:23 2024 +0000
Commit:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
CommitDate: Thu Jun  6 13:19:00 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=929b34fe

media-sound/cava: drop 0.10.1

Signed-off-by: Ionen Wolkens <ionen <AT> gentoo.org>

 media-sound/cava/Manifest           |  1 -
 media-sound/cava/cava-0.10.1.ebuild | 85 -------------------------------------
 2 files changed, 86 deletions(-)

diff --git a/media-sound/cava/Manifest b/media-sound/cava/Manifest
index 06b58399e79c..52c7f5a5cdcb 100644
--- a/media-sound/cava/Manifest
+++ b/media-sound/cava/Manifest
@@ -1,2 +1 @@
-DIST cava-0.10.1.tar.gz 129520 BLAKE2B 181a511feb8b9a6806316264c27e963fe7827802d8e333c39d59a0e3f67dd57bea967b05aeb869455992b905afd9c6e3f568debb84155068cbef03621047da6b SHA512 8a71628bae6621ef925f5fed94659b07d9220e142c17514bed79e1105a9160494bf3978267c9de3ab6cd2126ece50419fb4245ccf190f3a299fc0cfb111be354
 DIST cava-0.10.2.tar.gz 130036 BLAKE2B 155a0152571a6b1b847340fe438389f58b963af047d4136595a8b2933a4ac5b1fff87600110765c7c1500072ebd8b730d971918b8701598526052d137465ac81 SHA512 c28ef5a89668b8f90a3b4cbf71b208dd067268d5ed9eca35ff3881bfab0fd7bf72efe2164f29af47ca7972637d8f1d6a86ff2b2e0c9c9221a1856d8dfa960065

diff --git a/media-sound/cava/cava-0.10.1.ebuild b/media-sound/cava/cava-0.10.1.ebuild
deleted file mode 100644
index 7251e5fe1301..000000000000
--- a/media-sound/cava/cava-0.10.1.ebuild
+++ /dev/null
@@ -1,85 +0,0 @@
-# Copyright 2022-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit autotools toolchain-funcs
-
-DESCRIPTION="Console-based Audio Visualizer for Alsa"
-HOMEPAGE="https://github.com/karlstav/cava/"
-SRC_URI="
-	https://github.com/karlstav/cava/archive/refs/tags/${PV}.tar.gz
-		-> ${P}.tar.gz
-"
-
-LICENSE="MIT Unlicense"
-SLOT="0"
-KEYWORDS="amd64 x86"
-IUSE="alsa jack +ncurses pipewire portaudio pulseaudio sdl sndio"
-
-RDEPEND="
-	dev-libs/iniparser:4
-	sci-libs/fftw:3.0=
-	alsa? ( media-libs/alsa-lib )
-	jack? ( virtual/jack )
-	ncurses? ( sys-libs/ncurses:= )
-	pipewire? ( media-video/pipewire:= )
-	portaudio? ( media-libs/portaudio )
-	pulseaudio? ( media-libs/libpulse )
-	sdl? (
-		media-libs/libglvnd
-		media-libs/libsdl2[opengl,video]
-	)
-	sndio? ( media-sound/sndio:= )
-"
-DEPEND="${RDEPEND}"
-BDEPEND="
-	virtual/pkgconfig
-	sdl? ( dev-build/autoconf-archive )
-"
-
-PATCHES=(
-	"${FILESDIR}"/${PN}-0.8.0-gentoo-iniparser4.patch
-)
-
-src_prepare() {
-	default
-
-	echo ${PV} > version || die
-	eautoreconf
-}
-
-src_configure() {
-	local econfargs=(
-		$(use_enable alsa input-alsa)
-		$(use_enable jack input-jack)
-		$(use_enable pipewire input-pipewire)
-		$(use_enable portaudio input-portaudio)
-		$(use_enable pulseaudio input-pulse)
-		$(use_enable sndio input-sndio)
-
-		$(use_enable ncurses output-ncurses)
-		$(use_enable sdl output-sdl)
-		# note: not behind USE=opengl and sdl2[opengl?] given have not gotten
-		# normal output-sdl to work without USE=opengl on sdl either way
-		$(use_enable sdl output-sdl_glsl)
-
-		GENTOO_SYSROOT="${ESYSROOT}" # see iniparser4.patch
-	)
-
-	# autoconf-archive (currently) does not support -lOpenGL for libglvnd[-X]
-	use sdl && econfargs+=( GL_LIBS="$($(tc-getPKG_CONFIG) --libs opengl || die)" )
-
-	econf "${econfargs[@]}"
-}
-
-pkg_postinst() {
-	if [[ ! ${REPLACING_VERSIONS##* } ]]; then
-		elog "A default ~/.config/cava/config will be created after initial"
-		elog "use of ${PN}, see it and ${EROOT}/usr/share/doc/${PF}/README*"
-		elog "for configuring audio input and more."
-	elif ver_test ${REPLACING_VERSIONS##* } -lt 0.9; then
-		elog "If used, the noise_reduction config option in ~/.config/cava/config needs"
-		elog "to be updated from taking a float to integer (e.g. replace 0.77 with 77)."
-	fi
-}