[gentoo-commits] repo/gentoo:master commit in: dev-python/hishel/

["Michał Górny" <mgorny@gentoo.org>]

commit:     3d42c8bf35594d671eabe9bd9ce98cb9474e226e
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sat Jun  1 03:52:56 2024 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sat Jun  1 03:57:41 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=3d42c8bf

dev-python/hishel: Bump to 0.0.27

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/hishel/Manifest             |  1 +
 dev-python/hishel/hishel-0.0.27.ebuild | 74 ++++++++++++++++++++++++++++++++++
 2 files changed, 75 insertions(+)

diff --git a/dev-python/hishel/Manifest b/dev-python/hishel/Manifest
index e3dc6a0cc938..dae2a2438897 100644
--- a/dev-python/hishel/Manifest
+++ b/dev-python/hishel/Manifest
@@ -1,2 +1,3 @@
 DIST hishel-0.0.25.gh.tar.gz 825114 BLAKE2B dd7d7bec47700a1ab07976ba31b951adacf7e917dd7ba09419cc6e3b81f1b6609a1f7f14a6c176b0c151ed255cf099f3da60122717b2be9161bd41b7ba080f36 SHA512 16aec1ea495075b4932e1e9d16b07af060b49bb74faed097343bde99c5d2b656b36762b2f2d67fd46c31b700206eec77ecdfb364a1c2cd19bb67c3055abc9e98
 DIST hishel-0.0.26.gh.tar.gz 828246 BLAKE2B e8273020c3b69edc0a080940d8462d33c4eb6b6bbb6f0325975ef29e15d0f16c57a31406f24ae56ad651722ccf6ff704afcedb917417355f67b7536d80dc0c3f SHA512 1d5d55e2ad2743ac15b258c1246a21975c4e8bf5786e331d55acc6e5cb82c0393b23b7c00a5ea9f6f8070e5e3cf6d5f6d9755315403748259d99e6ce20ccd27f
+DIST hishel-0.0.27.gh.tar.gz 828343 BLAKE2B 57c42988bb64ef0a36bfe15527fae4a06cf1945609458266c29c0ba9423002c8c7c3beb0b1276dd4aa7d8b3a4f4575f5c8d570d7d66b97ea757988f3e673b651 SHA512 c348bc7ef236a9379f4c45f3cfa3eb74ea1c11be3b3dc533e7864c788d029137720de7612210873971d8ccd6768379ee26a4782c6c7fdf87ce4e4028489b6012

diff --git a/dev-python/hishel/hishel-0.0.27.ebuild b/dev-python/hishel/hishel-0.0.27.ebuild
new file mode 100644
index 000000000000..07503f286cee
--- /dev/null
+++ b/dev-python/hishel/hishel-0.0.27.ebuild
@@ -0,0 +1,74 @@
+# Copyright 2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{10..12} )
+inherit distutils-r1
+
+DESCRIPTION="An elegant HTTP Cache implementation for HTTPX and HTTP Core"
+HOMEPAGE="
+	https://github.com/karpetrosyan/hishel
+	https://pypi.org/project/hishel/
+"
+SRC_URI="https://github.com/karpetrosyan/${PN}/archive/refs/tags/${PV}.tar.gz -> ${P}.gh.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+
+RDEPEND="
+	dev-python/httpx[${PYTHON_USEDEP}]
+	dev-python/typing-extensions[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	${RDEPEND}
+	dev-python/hatch-fancy-pypi-readme[${PYTHON_USEDEP}]
+	test? (
+		dev-db/redis
+		dev-python/anyio[${PYTHON_USEDEP}]
+		dev-python/boto3[${PYTHON_USEDEP}]
+		dev-python/moto[${PYTHON_USEDEP}]
+		dev-python/redis[${PYTHON_USEDEP}]
+		dev-python/trio[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	sed -e 's:mock_s3:mock_aws:g' \
+		-e '/import anysqlite/ d' \
+		-i tests/_async/test_storages.py \
+		tests/_sync/test_storages.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+src_test() {
+	local EPYTEST_DESELECT=(
+		# tests that need anysqlite
+		tests/_async/test_storages.py::test_sqlitestorage
+		tests/_async/test_storages.py::test_sqlite_expired
+		tests/_async/test_storages.py::test_sqlite_ttl_after_hits
+	)
+
+	local redis_pid="${T}"/redis.pid
+	local redis_port=6379
+
+	einfo "Starting Redis"
+	"${EPREFIX}"/usr/sbin/redis-server - <<- EOF
+		daemonize yes
+		pidfile ${redis_pid}
+		port ${redis_port}
+		bind 127.0.0.1 ::1
+	EOF
+
+	# Run the tests
+	distutils-r1_src_test
+
+	# Clean up afterwards
+	kill "$(<"${redis_pid}")" || die
+}