[gentoo-commits] repo/gentoo:master commit in: net-analyzer/nagstamon/

["Hans de Graaff" <graaff@gentoo.org>]

commit:     e277a262ecb32e193bce510ec4f0b89a1f2154bb
Author:     Hans de Graaff <graaff <AT> gentoo <DOT> org>
AuthorDate: Sun May 19 07:14:51 2024 +0000
Commit:     Hans de Graaff <graaff <AT> gentoo <DOT> org>
CommitDate: Sun May 19 07:16:03 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e277a262

net-analyzer/nagstamon: use qt6 USE flag

This also drops x86 since that does not have PyQt6 keyworded.

Closes: https://bugs.gentoo.org/931957
Signed-off-by: Hans de Graaff <graaff <AT> gentoo.org>

 net-analyzer/nagstamon/nagstamon-3.14.0-r1.ebuild | 72 +++++++++++++++++++++++
 1 file changed, 72 insertions(+)

diff --git a/net-analyzer/nagstamon/nagstamon-3.14.0-r1.ebuild b/net-analyzer/nagstamon/nagstamon-3.14.0-r1.ebuild
new file mode 100644
index 000000000000..1458041bbc81
--- /dev/null
+++ b/net-analyzer/nagstamon/nagstamon-3.14.0-r1.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+DISTUTILS_USE_PEP517=setuptools
+
+inherit desktop distutils-r1 virtualx
+
+distutils_enable_tests pytest
+
+MY_PN="Nagstamon"
+MY_P="${MY_PN}-${PV/_p/-}"
+
+DESCRIPTION="systray monitor for displaying realtime status of several monitoring systems"
+HOMEPAGE="https://nagstamon.de"
+SRC_URI="https://github.com/HenriWahl/Nagstamon/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="qt6 test"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}
+	dev-python/lxml[${PYTHON_USEDEP}]
+	qt6? (  dev-python/PyQt6[gui,multimedia,svg,widgets,${PYTHON_USEDEP}] )
+	!qt6? (	dev-python/PyQt5[gui,multimedia,svg,widgets,${PYTHON_USEDEP}] )
+	dev-python/PySocks[${PYTHON_USEDEP}]
+	dev-python/beautifulsoup4[${PYTHON_USEDEP}]
+	dev-python/dbus-python[${PYTHON_USEDEP}]
+	dev-python/keyring[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/psutil[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	dev-python/cryptography[${PYTHON_USEDEP}]
+	dev-python/secretstorage[${PYTHON_USEDEP}]
+	>=dev-python/python-xlib-0.19[${PYTHON_USEDEP}]
+	dev-python/requests-kerberos[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? ( dev-python/pylint[${PYTHON_USEDEP}] )"
+
+PATCHES=( "${FILESDIR}/${PN}-3.14.0-setup.patch" )
+
+src_prepare() {
+	default_src_prepare
+
+	# pre-compressed already
+	rm Nagstamon/resources/nagstamon.1.gz || die
+	sed -e 's:\(nagstamon\.1\)\.gz:\1:' \
+		-e '/share/ s:^:#:' \
+		-i setup.py || die
+
+	mv ${PN}.py ${PN} || die
+
+	rm -rf "${S}/Nagstamon/thirdparty/Xlib/" || die
+}
+
+python_test() {
+	virtx epytest
+}
+
+distutils-r1_python_install_all() {
+	default
+
+	doman Nagstamon/resources/nagstamon.1
+	domenu Nagstamon/resources/nagstamon.desktop
+	doicon Nagstamon/resources/nagstamon.svg
+}