From: "Maciej Barć" <xgqt@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Subject: [gentoo-commits] repo/gentoo:master commit in: app-emacs/lsp-mode/
Date: Tue, 14 May 2024 22:21:06 +0000 (UTC) [thread overview]
Message-ID: <1715725259.84969d77a3e29ac73f9af4ed52bec08be10662b7.xgqt@gentoo> (raw)
commit: 84969d77a3e29ac73f9af4ed52bec08be10662b7
Author: Maciej Barć <xgqt <AT> gentoo <DOT> org>
AuthorDate: Tue May 14 22:16:55 2024 +0000
Commit: Maciej Barć <xgqt <AT> gentoo <DOT> org>
CommitDate: Tue May 14 22:20:59 2024 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=84969d77
app-emacs/lsp-mode: add live 9999 version
Signed-off-by: Maciej Barć <xgqt <AT> gentoo.org>
app-emacs/lsp-mode/lsp-mode-9999.ebuild | 68 +++++++++++++++++++++++++++++++++
1 file changed, 68 insertions(+)
diff --git a/app-emacs/lsp-mode/lsp-mode-9999.ebuild b/app-emacs/lsp-mode/lsp-mode-9999.ebuild
new file mode 100644
index 000000000000..a9d91c1ecc48
--- /dev/null
+++ b/app-emacs/lsp-mode/lsp-mode-9999.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+NEED_EMACS=27.1
+
+inherit elisp
+
+DESCRIPTION="Emacs client/library for the Language Server Protocol"
+HOMEPAGE="https://emacs-lsp.github.io/lsp-mode/
+ https://github.com/emacs-lsp/lsp-mode/"
+
+if [[ "${PV}" == *9999* ]] ; then
+ inherit git-r3
+
+ EGIT_REPO_URI="https://github.com/emacs-lsp/${PN}.git"
+else
+ SRC_URI="https://github.com/emacs-lsp/${PN}/archive/${PV}.tar.gz
+ -> ${P}.tar.gz"
+
+ KEYWORDS="~amd64 ~arm64"
+fi
+
+LICENSE="GPL-3+"
+SLOT="0"
+
+RDEPEND="
+ >=app-emacs/dash-2.18.0
+ >=app-emacs/f-0.20.0
+ app-emacs/ht
+ app-emacs/lv
+ app-emacs/markdown-mode
+ app-emacs/spinner
+"
+BDEPEND="
+ ${RDEPEND}
+ test? (
+ app-emacs/deferred
+ app-emacs/ecukes
+ app-emacs/el-mock
+ app-emacs/espuds
+ app-emacs/flycheck
+ app-emacs/undercover
+ )
+"
+
+BYTECOMPFLAGS="-L . -L clients"
+ELISP_REMOVE="
+ test/lsp-clangd-test.el
+ test/lsp-common-test.el
+ test/lsp-integration-test.el
+" # Remove failing tests.
+
+DOCS=( AUTHORS CHANGELOG.org README.md refcard )
+SITEFILE="50${PN}-gentoo.el"
+
+elisp-enable-tests ert-runner "${S}" -t "!no-win" -t "!org"
+
+src_compile() {
+ elisp_src_compile
+ elisp-compile clients/*.el
+}
+
+src_install() {
+ elisp_src_install
+ elisp-install "${PN}/clients" clients/*
+}
next reply other threads:[~2024-05-14 22:21 UTC|newest]
Thread overview: 12+ messages / expand[flat|nested] mbox.gz Atom feed top
2024-05-14 22:21 Maciej Barć [this message]
-- strict thread matches above, loose matches on Subject: below --
2024-05-14 22:21 [gentoo-commits] repo/gentoo:master commit in: app-emacs/lsp-mode/ Maciej Barć
2024-05-12 22:41 Sam James
2024-04-06 16:27 Maciej Barć
2024-01-18 17:25 Sam James
2024-01-14 17:54 Arthur Zamarin
2023-12-19 2:39 Maciej Barć
2023-10-18 17:00 Maciej Barć
2023-04-18 0:35 Maciej Barć
2023-03-23 9:00 Sam James
2022-06-23 15:39 Maciej Barć
2022-04-25 20:54 Maciej Barć
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=1715725259.84969d77a3e29ac73f9af4ed52bec08be10662b7.xgqt@gentoo \
--to=xgqt@gentoo.org \
--cc=gentoo-commits@lists.gentoo.org \
--cc=gentoo-dev@lists.gentoo.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox