[gentoo-commits] repo/gentoo:master commit in: sys-apps/cpu-x/

["Ben Kohler" <bkohler@gentoo.org>]

commit:     9969b81fdd0cd92874b64fe228ad7300d08004f1
Author:     Ben Kohler <bkohler <AT> gentoo <DOT> org>
AuthorDate: Mon Apr 29 17:06:58 2024 +0000
Commit:     Ben Kohler <bkohler <AT> gentoo <DOT> org>
CommitDate: Tue Apr 30 14:31:44 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9969b81f

sys-apps/cpu-x: add 5.0.4

Signed-off-by: Ben Kohler <bkohler <AT> gentoo.org>

 sys-apps/cpu-x/Manifest           |  1 +
 sys-apps/cpu-x/cpu-x-5.0.4.ebuild | 83 +++++++++++++++++++++++++++++++++++++++
 2 files changed, 84 insertions(+)

diff --git a/sys-apps/cpu-x/Manifest b/sys-apps/cpu-x/Manifest
index 15307b475385..0e3ac9cf9384 100644
--- a/sys-apps/cpu-x/Manifest
+++ b/sys-apps/cpu-x/Manifest
@@ -1,2 +1,3 @@
 DIST cpu-x-5.0.2.tar.gz 1975214 BLAKE2B 2b4cccdf96cc789a6c7b8a9e8124b380de681adabcd55cda05b5f0b97661a68feab9a434c1bcb8e092c529502d3472fd7385a7fbe5339fb93f4808ba2546b92d SHA512 3677207af8ea233a5bc1e435f501f4dffbe555486b048f5b51ac818cb458d52ab7ac94830ab83e992772e339de93464b3d4cd92798b8f49a272fd5292484de7e
 DIST cpu-x-5.0.3.tar.gz 1988476 BLAKE2B f1f693d6c7df5f8f342ac8326539febcc95df1ccd154cb013b215ea50d9f8bec70e894d7cbf76f08d454c73a8a2e450296144e9c6af4ed92a07b95df6c705901 SHA512 d9a29a5303101a6c00d9145265d85acec865833f175246bde550ba2dff24a924c1b2de7579b3d8e20aa163092d269af9bbb24e073585d3e18a2c726e48d9be41
+DIST cpu-x-5.0.4.tar.gz 1995465 BLAKE2B 6e3982040400a2bbdb7fba0cac24f1b183792693fff13fd223d1194a5bc57acd9b0dde407016f4f0039705759f0e57da472dc634a237e9d89c7c7d23e9cfa6b9 SHA512 134f8a8fe6782279f7288d891a66b3d426b0e173de3d5445367c94029aa9d33348d037f5bca25690aff16f00d261777a71de6847991e564578099b03ff398453

diff --git a/sys-apps/cpu-x/cpu-x-5.0.4.ebuild b/sys-apps/cpu-x/cpu-x-5.0.4.ebuild
new file mode 100644
index 000000000000..8d213e15a20a
--- /dev/null
+++ b/sys-apps/cpu-x/cpu-x-5.0.4.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_PN="CPU-X"
+
+inherit cmake gnome2-utils xdg
+
+DESCRIPTION="A Free software that gathers information on CPU, motherboard and more"
+HOMEPAGE="https://thetumultuousunicornofdarkness.github.io/CPU-X/"
+SRC_URI="https://github.com/TheTumultuousUnicornOfDarkness/${MY_PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="-* ~amd64"
+IUSE="+cpu force-libstatgrab +gpu gui +ncurses +nls opencl +pci test vulkan"
+RESTRICT="!test? ( test )"
+
+COMMON_DEPEND="
+	dev-libs/glib:2
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf:2
+	x11-libs/pango
+	force-libstatgrab? ( sys-libs/libstatgrab )
+	!force-libstatgrab? ( sys-process/procps:= )
+	gui? ( dev-cpp/gtkmm:3.0
+		>=x11-libs/gtk+-3.12:3 )
+	cpu? ( >=dev-libs/libcpuid-0.6.0:= )
+	gpu? ( >=media-libs/glfw-3.3
+		media-libs/libglvnd )
+	pci? ( sys-apps/pciutils )
+	ncurses? ( sys-libs/ncurses:=[tinfo] )
+	opencl? ( virtual/opencl )
+	vulkan? ( media-libs/vulkan-loader
+		>=dev-util/vulkan-headers-1.3.151 )
+"
+
+DEPEND="
+	test? (
+		sys-apps/grep[pcre]
+		sys-apps/mawk
+		sys-apps/nawk
+	)
+
+	${COMMON_DEPEND}
+"
+
+BDEPEND="
+	dev-lang/nasm
+	nls? ( sys-devel/gettext )
+"
+
+RDEPEND="${COMMON_DEPEND}"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+src_configure() {
+	local mycmakeargs=(
+		-DFORCE_LIBSTATGRAB=$(usex force-libstatgrab)
+		-DWITH_GETTEXT=$(usex nls)
+		-DWITH_GTK=$(usex gui)
+		-DWITH_LIBCPUID=$(usex cpu)
+		-DWITH_LIBGLFW=$(usex gpu)
+		-DWITH_LIBPCI=$(usex pci)
+		-DWITH_LIBSTATGRAB=OFF
+		-DWITH_NCURSES=$(usex ncurses)
+		-DWITH_OPENCL=$(usex opencl)
+		-DWITH_VULKAN=$(usex vulkan)
+	)
+	use gui && mycmakeargs+=( -DGSETTINGS_COMPILE=OFF )
+
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}