From: "Patrick McLean" <chutzpah@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Subject: [gentoo-commits] repo/gentoo:master commit in: dev-python/thriftpy2/
Date: Wed, 24 Apr 2024 15:26:00 +0000 (UTC) [thread overview]
Message-ID: <1713972348.0e6ce184e7eaa62128b58794041717cd555c74dd.chutzpah@gentoo> (raw)
commit: 0e6ce184e7eaa62128b58794041717cd555c74dd
Author: Patrick McLean <chutzpah <AT> gentoo <DOT> org>
AuthorDate: Wed Apr 24 15:25:14 2024 +0000
Commit: Patrick McLean <chutzpah <AT> gentoo <DOT> org>
CommitDate: Wed Apr 24 15:25:48 2024 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=0e6ce184
dev-python/thriftpy2: Revbump, add py312 (bug #929518)
Closes: https://bugs.gentoo.org/929518
Signed-off-by: Patrick McLean <chutzpah <AT> gentoo.org>
dev-python/thriftpy2/thriftpy2-0.4.20-r1.ebuild | 57 +++++++++++++++++++++++++
1 file changed, 57 insertions(+)
diff --git a/dev-python/thriftpy2/thriftpy2-0.4.20-r1.ebuild b/dev-python/thriftpy2/thriftpy2-0.4.20-r1.ebuild
new file mode 100644
index 000000000000..a763b9df7329
--- /dev/null
+++ b/dev-python/thriftpy2/thriftpy2-0.4.20-r1.ebuild
@@ -0,0 +1,57 @@
+# Copyright 2021-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit distutils-r1 flag-o-matic pypi
+
+DESCRIPTION="Pure python approach of Apache Thrift"
+HOMEPAGE="
+ https://github.com/Thriftpy/thriftpy2/
+ https://pypi.org/project/thriftpy2/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+ dev-python/ply[${PYTHON_USEDEP}]
+ dev-python/six[${PYTHON_USEDEP}]
+"
+BDEPEND="
+ dev-python/cython[${PYTHON_USEDEP}]
+ test? (
+ dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+ dev-python/tornado[${PYTHON_USEDEP}]
+ )
+"
+
+distutils_enable_tests pytest
+
+src_compile() {
+ # -Werror=strict-aliasing
+ # https://bugs.gentoo.org/857105
+ # https://github.com/Thriftpy/thriftpy2/issues/246
+ #
+ # Don't trust this to LTO
+ append-flags -fno-strict-aliasing
+ filter-lto
+
+ distutils-r1_src_compile
+}
+
+python_test() {
+ local EPYTEST_DESELECT=(
+ tests/test_tornado.py::TornadoRPCTestCase::test_asynchronous_exception
+ tests/test_tornado.py::TornadoRPCTestCase::test_asynchronous_result
+ )
+
+ pushd tests >/dev/null || die
+ epytest
+ popd >/dev/null || die
+}
next reply other threads:[~2024-04-24 15:26 UTC|newest]
Thread overview: 22+ messages / expand[flat|nested] mbox.gz Atom feed top
2024-04-24 15:26 Patrick McLean [this message]
-- strict thread matches above, loose matches on Subject: below --
2024-09-17 16:03 [gentoo-commits] repo/gentoo:master commit in: dev-python/thriftpy2/ Arthur Zamarin
2024-07-23 3:40 Eli Schwartz
2024-07-06 5:39 Michał Górny
2024-07-06 5:29 Michał Górny
2024-06-30 17:00 Michał Górny
2024-05-29 4:17 Michał Górny
2024-05-07 17:45 Michał Górny
2024-04-24 15:26 Patrick McLean
2024-03-03 23:18 Sam James
2024-02-29 4:18 Michał Górny
2024-02-28 4:03 Michał Górny
2023-09-28 16:56 Michał Górny
2023-08-06 12:30 Michał Górny
2023-05-04 16:56 Michał Górny
2023-01-27 20:10 Michał Górny
2022-11-17 6:15 Michał Górny
2022-11-14 5:07 Michał Górny
2022-11-09 6:55 Michał Górny
2022-06-16 16:43 Patrick McLean
2021-08-14 21:01 Michał Górny
2021-07-01 18:42 Patrick McLean
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=1713972348.0e6ce184e7eaa62128b58794041717cd555c74dd.chutzpah@gentoo \
--to=chutzpah@gentoo.org \
--cc=gentoo-commits@lists.gentoo.org \
--cc=gentoo-dev@lists.gentoo.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox