[gentoo-commits] repo/gentoo:master commit in: sci-libs/cartopy/

["Thomas Beierlein" <tomjbe@gentoo.org>]

commit:     799053cd56a029141f62c3fd252dd6ad5cdfa098
Author:     Thomas Beierlein <tomjbe <AT> gentoo <DOT> org>
AuthorDate: Thu Apr 18 11:09:15 2024 +0000
Commit:     Thomas Beierlein <tomjbe <AT> gentoo <DOT> org>
CommitDate: Thu Apr 18 11:10:42 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=799053cd

sci-libs/cartopy: add 0.22.0

Signed-off-by: Thomas Beierlein <tomjbe <AT> gentoo.org>

 sci-libs/cartopy/Manifest              |  1 +
 sci-libs/cartopy/cartopy-0.22.0.ebuild | 85 ++++++++++++++++++++++++++++++++++
 2 files changed, 86 insertions(+)

diff --git a/sci-libs/cartopy/Manifest b/sci-libs/cartopy/Manifest
index d3c5f7633dcf..454beee85fa2 100644
--- a/sci-libs/cartopy/Manifest
+++ b/sci-libs/cartopy/Manifest
@@ -1 +1,2 @@
 DIST cartopy-0.21.1.gh.tar.gz 10815884 BLAKE2B 4137f593b6ce35270f9df5016529250a07c57ec5a95843db8740eb494f55109b5129cf72153b0216e4f786771bf5cedde3caaecd40175fe9ad5c6fb65ad84788 SHA512 de1d09ee3bf6af13bcc7cc4bb1f7c13335ba67e05d2ad64efa0fb00bdb74c7e13c6fc44822d5ac1d70ee7d39b2322280c1395dc66119b9ecd94ca26014e413a1
+DIST cartopy-0.22.0.gh.tar.gz 10907762 BLAKE2B 0524efb2359f72da4e73cc74c41b03f4e335163dea4b86f5b8907b2a20521ce81a42fceebbdd7e582315b33aed0dfdf159469dfa13516c9c46a8f887f847fa21 SHA512 195cc69170c826240e03918de39925459c94c36b76f1a87b8ec3bca7c00ed577eb8c727ccda1511c0f691ac5aea043d3d02d7bfb603624548e63c9a7dc644ad5

diff --git a/sci-libs/cartopy/cartopy-0.22.0.ebuild b/sci-libs/cartopy/cartopy-0.22.0.ebuild
new file mode 100644
index 000000000000..cfc80da1d172
--- /dev/null
+++ b/sci-libs/cartopy/cartopy-0.22.0.ebuild
@@ -0,0 +1,85 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_SINGLE_IMPL=1
+DISTUTILS_EXT=1
+PYTHON_COMPAT=( python3_{9..11} )
+
+DISTUTILS_USE_PEP517=setuptools
+inherit distutils-r1 multiprocessing virtualx
+
+MY_PV=${PV/_beta/b}
+MY_P=${PN}-${MY_PV}
+
+DESCRIPTION="Python package for geospatial data processing and analysis"
+HOMEPAGE="https://scitools.org.uk/cartopy"
+SRC_URI="https://github.com/SciTools/${PN}/archive/v${MY_PV}.tar.gz -> ${P}.gh.tar.gz"
+S="${WORKDIR}"/${MY_P}
+
+LICENSE="LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	sci-libs/gdal[python,${PYTHON_SINGLE_USEDEP}]
+	sci-libs/geos
+	$(python_gen_cond_dep '
+		>=dev-python/numpy-1.19[${PYTHON_USEDEP}]
+		dev-python/shapely[${PYTHON_USEDEP}]
+		dev-python/six[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		dev-python/scipy[${PYTHON_USEDEP}]
+		dev-python/pillow[jpeg,${PYTHON_USEDEP}]
+		dev-python/pyproj[${PYTHON_USEDEP}]
+		sci-libs/pyshp[${PYTHON_USEDEP}]
+	')
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	$(python_gen_cond_dep '
+		dev-python/setuptools-scm[${PYTHON_USEDEP}]
+		dev-python/cython[${PYTHON_USEDEP}]
+	')
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/filelock[${PYTHON_USEDEP}]
+			dev-python/mock[${PYTHON_USEDEP}]
+			dev-python/flufl-lock[${PYTHON_USEDEP}]
+			dev-python/pytest-mpl[${PYTHON_USEDEP}]
+			dev-python/pytest-xdist[${PYTHON_USEDEP}]
+		')
+	)
+"
+
+EPYTEST_IGNORE=(
+	# Require network access, not covered by markers
+	lib/cartopy/tests/mpl/test_crs.py
+	lib/cartopy/tests/mpl/test_gridliner.py
+)
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+
+	# Prepare matplotlib backend for test suite
+	export MPLCONFIGDIR="${T}"
+	echo "backend : Agg" > "${MPLCONFIGDIR}"/matplotlibrc || die
+
+	sed -i -e "s/exclude =/#exclude =/" pyproject.toml || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	cd "${BUILD_DIR}" || die
+
+	# Drop all tests needing network access
+	virtx epytest -n "$(makeopts_jobs)" -m "not network and not natural_earth" || die "test failed"
+}