[gentoo-commits] repo/gentoo:master commit in: media-video/gaupol/

["Louis Sautier" <sbraz@gentoo.org>]

commit:     f073621344aa9fe7d81be87fe3c413dc0da9df58
Author:     Louis Sautier <sbraz <AT> gentoo <DOT> org>
AuthorDate: Sun Apr  7 14:13:34 2024 +0000
Commit:     Louis Sautier <sbraz <AT> gentoo <DOT> org>
CommitDate: Sun Apr  7 14:21:18 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f0736213

media-video/gaupol: add 1.14.1

Signed-off-by: Louis Sautier <sbraz <AT> gentoo.org>

 media-video/gaupol/Manifest             |  1 +
 media-video/gaupol/gaupol-1.14.1.ebuild | 69 +++++++++++++++++++++++++++++++++
 2 files changed, 70 insertions(+)

diff --git a/media-video/gaupol/Manifest b/media-video/gaupol/Manifest
index 441626b62638..df3da67cc1f4 100644
--- a/media-video/gaupol/Manifest
+++ b/media-video/gaupol/Manifest
@@ -1 +1,2 @@
 DIST gaupol-1.13.tar.gz 592830 BLAKE2B dcde1dd6c5e3e9624f0e7692c4d6cc14452733d1e35bc25de5deaa842cdb069250dee0b2d9eb75d1bb9f3c618c43457718ce91f5a6992ec7797fbb37366fc524 SHA512 ebe2accd962344c07201e46ceff3801483a4c68f9772d1fc868a93d8044b65987f7233eab675a9f3148bce686261a6b5c40d66d3f9471f9515713fbfb46a3f92
+DIST gaupol-1.14.1.tar.gz 593435 BLAKE2B f7ee1f2e70707f54204400d99107a1ee62b721e7ee0be76ce980a261b1b95349aefcc5907dc5cf956fd703a4372065576371cdf0466a32ee206d797b1500d53d SHA512 efaa9910496dcd683be40ff33bf68de313b852d6212f3f43c67e6433eb3b95b64c89707d1a69a54c9f772c44cf04f95ca76d705d396b376ac1c86c4bbe48e4e0

diff --git a/media-video/gaupol/gaupol-1.14.1.ebuild b/media-video/gaupol/gaupol-1.14.1.ebuild
new file mode 100644
index 000000000000..0caa08c6a2f9
--- /dev/null
+++ b/media-video/gaupol/gaupol-1.14.1.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit distutils-r1 virtualx xdg-utils
+
+DESCRIPTION="A subtitle editor for text-based subtitles"
+HOMEPAGE="https://otsaloma.io/gaupol/ https://github.com/otsaloma/gaupol/"
+SRC_URI="https://github.com/otsaloma/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="spell"
+
+RDEPEND="
+	app-text/iso-codes
+	dev-python/chardet[${PYTHON_USEDEP}]
+	dev-python/pygobject:3[${PYTHON_USEDEP}]
+	x11-libs/gtk+:3[introspection]
+	spell? ( app-text/gspell[introspection] )
+"
+BDEPEND="
+	sys-devel/gettext
+	test? (
+		app-dicts/myspell-en
+		app-text/enchant[hunspell]
+		app-text/gspell[introspection]
+	)
+"
+
+distutils_enable_tests pytest
+
+DOCS=( AUTHORS.md NEWS.md README.md README.aeidon.md )
+
+PATCHES=(
+	"${FILESDIR}/${PN}-1.12-fix-prefix.patch"
+)
+
+python_test() {
+	virtx epytest
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+	if [[ -z ${REPLACING_VERSIONS} ]]; then
+		elog "The integrated video player requires media-plugins/gst-plugins-gtk."
+		elog ""
+		elog "External video previewing support requires MPV, MPlayer or VLC."
+		if use spell; then
+			elog ""
+			elog "Spell-checking requires a dictionary, any of app-dicts/myspell-*"
+			elog "or app-text/aspell with the appropriate L10N variable."
+			elog ""
+			elog "Additionally, make sure that app-text/enchant has the correct flags enabled:"
+			elog "USE=hunspell for myspell dictionaries and USE=aspell for aspell dictionaries."
+		fi
+	fi
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}