From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1611222-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
key-exchange X25519 server-signature RSA-PSS (2048 bits))
(No client certificate requested)
by finch.gentoo.org (Postfix) with ESMTPS id B7E6F158041
for <garchives@archives.gentoo.org>; Fri, 15 Mar 2024 06:25:28 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id C7046E29CB;
Fri, 15 Mar 2024 06:25:27 +0000 (UTC)
Received: from smtp.gentoo.org (smtp.gentoo.org [IPv6:2001:470:ea4a:1:5054:ff:fec7:86e4])
(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
key-exchange X25519 server-signature RSA-PSS (4096 bits))
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id AE382E29CB
for <gentoo-commits@lists.gentoo.org>; Fri, 15 Mar 2024 06:25:27 +0000 (UTC)
Received: from oystercatcher.gentoo.org (oystercatcher.gentoo.org [148.251.78.52])
(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
key-exchange X25519 server-signature RSA-PSS (4096 bits))
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id EA92B33BE19
for <gentoo-commits@lists.gentoo.org>; Fri, 15 Mar 2024 06:25:26 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id 8939314A8
for <gentoo-commits@lists.gentoo.org>; Fri, 15 Mar 2024 06:25:25 +0000 (UTC)
From: "Viorel Munteanu" <ceamac@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Viorel Munteanu" <ceamac@gentoo.org>
Message-ID: <1710483912.89da9215d95bf0ff8b055ab0daee3cbe22c5ddb8.ceamac@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: app-misc/fastfetch/
X-VCS-Repository: repo/gentoo
X-VCS-Files: app-misc/fastfetch/Manifest app-misc/fastfetch/fastfetch-2.8.9.ebuild
X-VCS-Directories: app-misc/fastfetch/
X-VCS-Committer: ceamac
X-VCS-Committer-Name: Viorel Munteanu
X-VCS-Revision: 89da9215d95bf0ff8b055ab0daee3cbe22c5ddb8
X-VCS-Branch: master
Date: Fri, 15 Mar 2024 06:25:25 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: 3bb8aa1e-b5d1-422a-bf4f-f626aaa90ff1
X-Archives-Hash: 7977b4b1a736f2791a3e284854b6e504
commit: 89da9215d95bf0ff8b055ab0daee3cbe22c5ddb8
Author: Viorel Munteanu <ceamac <AT> gentoo <DOT> org>
AuthorDate: Fri Mar 15 06:17:17 2024 +0000
Commit: Viorel Munteanu <ceamac <AT> gentoo <DOT> org>
CommitDate: Fri Mar 15 06:25:12 2024 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=89da9215
app-misc/fastfetch: add 2.8.9
Signed-off-by: Viorel Munteanu <ceamac <AT> gentoo.org>
app-misc/fastfetch/Manifest | 1 +
app-misc/fastfetch/fastfetch-2.8.9.ebuild | 115 ++++++++++++++++++++++++++++++
2 files changed, 116 insertions(+)
diff --git a/app-misc/fastfetch/Manifest b/app-misc/fastfetch/Manifest
index 7d8c9a5856cf..1095415db909 100644
--- a/app-misc/fastfetch/Manifest
+++ b/app-misc/fastfetch/Manifest
@@ -1,2 +1,3 @@
DIST fastfetch-2.7.1.tar.gz 1000565 BLAKE2B 061d2175bdca879bb4ef1a2f29fd73b99a7325fb8de66f05eb1203008c34ef20ff122e57a785ee0a5abb0251004023958abb1d158bc49cd1b34f9e02f3d1c6bc SHA512 55d897af532141d429aa5b58ab1516347f14597bf249b70f0d5ab27d11e235911858143fc32356255bef201cb44cdd7698e8d49094fb7e61c2e425a6c8ac5fa1
DIST fastfetch-2.8.8.tar.gz 1014055 BLAKE2B bf8145db1fdad1ae1c89f32b56d1e61b7b793492ed9e3e76bb9436ed456aeeef76543f52eb5d6ce52d389547abb9b59cd5760f5e8b7c6cd1350b0e7683fb8a76 SHA512 a39ae6cf59a6e2f95d138205892b46072cab35d6be7422ed3d22430050ea73284006aad99c8d6e195475b7e5b3ae40489f654cbd766e825e093b08f193a6fb23
+DIST fastfetch-2.8.9.tar.gz 1288003 BLAKE2B bf7f1d6af901292ba18ed7dcb50612ad76c035ccf169d4dffed38d08077474c854427907acb7734ec1566e4ad2a4648fbcfc18e3ba08cbccd2e4a7b52404e7aa SHA512 7680bef42070e74479dcbb813173faa6e0f45ae8c00c0eeecf79477551680eae3b0fed2ae9a0e13e647d8e99f310253f6291be1f5417ba5952a89dbcfc97f880
diff --git a/app-misc/fastfetch/fastfetch-2.8.9.ebuild b/app-misc/fastfetch/fastfetch-2.8.9.ebuild
new file mode 100644
index 000000000000..97a256518745
--- /dev/null
+++ b/app-misc/fastfetch/fastfetch-2.8.9.ebuild
@@ -0,0 +1,115 @@
+# Copyright 2022-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake flag-o-matic
+
+DESCRIPTION="Fast neofetch-like system information tool"
+HOMEPAGE="https://github.com/fastfetch-cli/fastfetch"
+if [[ ${PV} == *9999 ]]; then
+ inherit git-r3
+ EGIT_REPO_URI="https://github.com/fastfetch-cli/fastfetch.git"
+ [[ ${PV} == *0.1.9999 ]] && EGIT_BRANCH=master
+ [[ ${PV} == *0.2.9999 ]] && EGIT_BRANCH=dev
+ [[ "${EGIT_BRANCH}" == "" ]] && die "Please set a git branch"
+else
+ SRC_URI="https://github.com/fastfetch-cli/fastfetch/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+ KEYWORDS="~amd64 ~arm ~arm64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
+fi
+
+LICENSE="MIT nvidia-gpu? ( NVIDIA-NVLM )"
+SLOT="0"
+IUSE="X chafa dbus ddcutil drm gnome imagemagick networkmanager nvidia-gpu opencl opengl osmesa pulseaudio sqlite test vulkan wayland xcb xfce xrandr"
+RESTRICT="!test? ( test )"
+
+# note - qa-vdb will always report errors because fastfetch loads the libs dynamically
+# make sure to crank yyjson minimum version to match bundled version
+RDEPEND="
+ >=dev-libs/yyjson-0.8.0:=
+ sys-libs/zlib
+ X? ( x11-libs/libX11 )
+ chafa? ( media-gfx/chafa )
+ dbus? ( sys-apps/dbus )
+ ddcutil? ( app-misc/ddcutil:= )
+ drm? ( x11-libs/libdrm )
+ gnome? (
+ dev-libs/glib
+ gnome-base/dconf
+ )
+ imagemagick? ( media-gfx/imagemagick:= )
+ networkmanager? ( net-misc/networkmanager )
+ opencl? ( virtual/opencl )
+ opengl? ( media-libs/libglvnd[X] )
+ osmesa? ( media-libs/mesa[osmesa] )
+ pulseaudio? ( media-libs/libpulse )
+ sqlite? ( dev-db/sqlite:3 )
+ vulkan? (
+ media-libs/vulkan-loader
+ sys-apps/pciutils
+ )
+ wayland? ( dev-libs/wayland )
+ xcb? ( x11-libs/libxcb )
+ xfce? ( xfce-base/xfconf )
+ xrandr? ( x11-libs/libXrandr )
+"
+DEPEND="
+ ${RDEPEND}
+ vulkan? ( dev-util/vulkan-headers )
+"
+BDEPEND="virtual/pkgconfig"
+
+REQUIRED_USE="
+ xrandr? ( X )
+ chafa? ( imagemagick )
+"
+
+src_configure() {
+ local fastfetch_enable_imagemagick7=no
+ local fastfetch_enable_imagemagick6=no
+ if use imagemagick; then
+ fastfetch_enable_imagemagick7=$(has_version '>=media-gfx/imagemagick-7.0.0' && echo yes || echo no)
+ fastfetch_enable_imagemagick6=$(has_version '<media-gfx/imagemagick-7.0.0' && echo yes || echo no)
+ fi
+
+ local mycmakeargs=(
+ -DENABLE_RPM=no
+ -DENABLE_ZLIB=yes
+ -DENABLE_SYSTEM_YYJSON=yes
+
+ -DENABLE_CHAFA=$(usex chafa)
+ -DENABLE_DBUS=$(usex dbus)
+ -DENABLE_DCONF=$(usex gnome)
+ -DENABLE_DDCUTIL=$(usex ddcutil)
+ -DENABLE_DRM=$(usex drm)
+ -DENABLE_EGL=$(usex opengl)
+ -DENABLE_GIO=$(usex gnome)
+ -DENABLE_GLX=$(usex opengl)
+ -DENABLE_IMAGEMAGICK6=${fastfetch_enable_imagemagick6}
+ -DENABLE_IMAGEMAGICK7=${fastfetch_enable_imagemagick7}
+ -DENABLE_LIBNM=$(usex networkmanager)
+ -DENABLE_PROPRIETARY_GPU_DRIVER_API=$(usex nvidia-gpu)
+ -DENABLE_OPENCL=$(usex opencl)
+ -DENABLE_OSMESA=$(usex osmesa)
+ -DENABLE_PULSE=$(usex pulseaudio)
+ -DENABLE_SQLITE3=$(usex sqlite)
+ -DENABLE_VULKAN=$(usex vulkan)
+ -DENABLE_WAYLAND=$(usex wayland)
+ -DENABLE_X11=$(usex X)
+ -DENABLE_XCB=$(usex xcb)
+ -DENABLE_XCB_RANDR=$(usex xcb)
+ -DENABLE_XFCONF=$(usex xfce)
+ -DENABLE_XRANDR=$(usex xrandr)
+ -DBUILD_TESTS=$(usex test)
+ )
+
+ append-cppflags -DNDEBUG
+
+ cmake_src_configure
+}
+
+src_install() {
+ cmake_src_install
+
+ rm -r "${ED}"/usr/share/licenses || die
+}