[gentoo-commits] repo/gentoo:master commit in: sys-apps/sg3_utils/

["Sam James" <sam@gentoo.org>]

commit:     4ea1b2361e90456b422cc08bc8d5c9f8e8241990
Author:     Eli Schwartz <eschwartz93 <AT> gmail <DOT> com>
AuthorDate: Fri Mar 15 04:12:17 2024 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Fri Mar 15 04:14:17 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=4ea1b236

sys-apps/sg3_utils: update EAPI 7 -> 8

Signed-off-by: Eli Schwartz <eschwartz93 <AT> gmail.com>
Signed-off-by: Sam James <sam <AT> gentoo.org>

 sys-apps/sg3_utils/sg3_utils-1.47-r2.ebuild | 48 +++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)

diff --git a/sys-apps/sg3_utils/sg3_utils-1.47-r2.ebuild b/sys-apps/sg3_utils/sg3_utils-1.47-r2.ebuild
new file mode 100644
index 000000000000..7713ea4da2c5
--- /dev/null
+++ b/sys-apps/sg3_utils/sg3_utils-1.47-r2.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit libtool
+
+DESCRIPTION="Apps for querying the sg SCSI interface"
+HOMEPAGE="https://sg.danny.cz/sg/"
+#SRC_URI="https://github.com/hreinecke/sg3_utils/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+SRC_URI="https://sg.danny.cz/sg/p/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0/${PV}"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="static-libs"
+
+RDEPEND="!sys-apps/rescan-scsi-bus"
+
+PATCHES=(
+	# Bug #828897
+	"${FILESDIR}"/${PN}-1.47-musl.patch
+)
+
+src_prepare() {
+	default
+	elibtoolize
+}
+
+src_configure() {
+	econf $(use_enable static-libs static)
+}
+
+src_install() {
+	default
+	dodoc COVERAGE doc/README examples/*.txt
+	newdoc scripts/README README.scripts
+
+	find "${ED}" -type f -name "*.la" -delete || die
+
+	# Better fix for bug 231089; some packages look for sgutils2
+	local path lib
+	path="/usr/$(get_libdir)"
+	for lib in "${ED}/"${path}/libsgutils2{,-${PV}}.*; do
+		lib=${lib##*/}
+		dosym "${lib}" "${path}/${lib/libsgutils2/libsgutils}"
+	done
+}