[gentoo-commits] repo/gentoo:master commit in: app-editors/gnome-text-editor/

["Mart Raudsepp" <leio@gentoo.org>]

commit:     a5173074dad5910aeb475da4634e095cbe9fd5f9
Author:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
AuthorDate: Sat Mar  9 14:54:44 2024 +0000
Commit:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
CommitDate: Sat Mar  9 15:33:28 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=a5173074

app-editors/gnome-text-editor: add 45.3

Signed-off-by: Mart Raudsepp <leio <AT> gentoo.org>

 app-editors/gnome-text-editor/Manifest             |  1 +
 .../gnome-text-editor-45.3.ebuild                  | 57 ++++++++++++++++++++++
 2 files changed, 58 insertions(+)

diff --git a/app-editors/gnome-text-editor/Manifest b/app-editors/gnome-text-editor/Manifest
index 4985486cafce..952cbb1dfa3a 100644
--- a/app-editors/gnome-text-editor/Manifest
+++ b/app-editors/gnome-text-editor/Manifest
@@ -1 +1,2 @@
 DIST gnome-text-editor-45.1.tar.xz 618116 BLAKE2B c847ebb7293f959912447491c423fd814cf4084d0f80d04c5933f883e07f826251e6b332f2d69f318e32fb81764d11d0e04dab2129a63a01394c9470d8cc81cd SHA512 8e16f0e9f2bc264a890eb9c648d74cc64bd487dae8a7e9d8198e16e8abc97f9fba3f3521d15777b681ee17b23a9e8032e382cd8a438eeddd857a28d8cb069c30
+DIST gnome-text-editor-45.3.tar.xz 618756 BLAKE2B 45a6a78a665f833b0fb2e179125224e1d3757390deee5845b750bbc13368cd9b0b8521b290e42a2c5be82e2e7d78bab5e3aad256d1c87eade22547696807a8ba SHA512 d9fbdbb0dfbb5d10dc1b817f9ebf114a63e20724c3c230da683c8b7f1332371acf869c723a7067dbdafb5b4df23529944b40e5ec212e52a5a3220ca725388c95

diff --git a/app-editors/gnome-text-editor/gnome-text-editor-45.3.ebuild b/app-editors/gnome-text-editor/gnome-text-editor-45.3.ebuild
new file mode 100644
index 000000000000..59aba2671d33
--- /dev/null
+++ b/app-editors/gnome-text-editor/gnome-text-editor-45.3.ebuild
@@ -0,0 +1,57 @@
+# Copyright 2022-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org gnome2-utils meson xdg
+
+DESCRIPTION="A simple text editor for the GNOME desktop"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/gnome-text-editor"
+S="${WORKDIR}/gnome-text-editor-${PV/_/.}"
+
+LICENSE="GPL-3+ CC-BY-SA-3.0"
+SLOT="0"
+
+IUSE="spell"
+
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+
+DEPEND="
+	>=dev-libs/glib-2.73.0:2
+	>=gui-libs/gtk-4.7:4
+	>=gui-libs/gtksourceview-5.5.0:5
+	>=gui-libs/libadwaita-1.4_alpha:1
+	app-text/editorconfig-core-c
+	x11-libs/cairo
+	spell? (
+		>=app-text/enchant-2.2.0:2
+		dev-libs/icu:=
+	)
+"
+RDEPEND="${DEPEND}
+	gnome-base/gsettings-desktop-schemas
+"
+BDEPEND="
+	dev-util/glib-utils
+	dev-util/itstool
+	>=sys-devel/gettext-0.21
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature spell enchant)
+		-Dbugreport_url="https://bugs.gentoo.org"
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}