[gentoo-commits] repo/gentoo:master commit in: dev-python/qiskit-terra/

["Michał Górny" <mgorny@gentoo.org>]

commit:     0ce701269baf5ea90c561243a776eee19163ddf2
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sat Mar  9 06:10:50 2024 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sat Mar  9 07:18:39 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=0ce70126

dev-python/qiskit-terra: Bump to 0.46.1

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/qiskit-terra/Manifest                   |   1 +
 dev-python/qiskit-terra/qiskit-terra-0.46.1.ebuild | 188 +++++++++++++++++++++
 2 files changed, 189 insertions(+)

diff --git a/dev-python/qiskit-terra/Manifest b/dev-python/qiskit-terra/Manifest
index 69fae1319f15..674fc138295c 100644
--- a/dev-python/qiskit-terra/Manifest
+++ b/dev-python/qiskit-terra/Manifest
@@ -40,6 +40,7 @@ DIST pyo3-ffi-0.19.2.crate 66500 BLAKE2B b4139fba31ef17017b6b60784e41ccda34931a0
 DIST pyo3-macros-0.19.2.crate 7173 BLAKE2B 8862f42a30929579b0b0bc2ba7f0b416518724480e197fa13288e49324e851f964183e1529b7f31bf5d4fe0ae194a412723b6b401100e66fba98bbcd9c283866 SHA512 852cc2792aa3d30d9ab8802a451be5617cae6536adced1bf0dde71704a3c7c1bfe862fba751b6d045249819a8ba5d87dfc50914d142a0b662f046498c06f8c2e
 DIST pyo3-macros-backend-0.19.2.crate 49962 BLAKE2B 9d8a032c2205f55d2431b6bbc40df153339e08479df3a8a65506ade7d1f3d17cfaf664cbd09eaec9acff3f5a248598e37427d0c5a531eaf527137803adf49834 SHA512 fd708e6fdbd54ef7c676bedc62070175bac6b8f7ae11231578196dbf552b163a8a2499a1266f786bb6bfb85517fe83610902137d59a5c42efcb1a27c4235a07e
 DIST qiskit-0.46.0.gh.tar.gz 10949616 BLAKE2B 35bb88f5d43582145a72945b0633665fb962ab27bde35ec7e290823cef41ae93bb4e0155728186d3eb9dfdb419efe014c127fcef12b69d93d259cba83ed3e57f SHA512 d9d6f485dc47301b045b9e9932d17f23306724cfd6fd32b730fba9f7366297dfd9151b9e80e634a8f641d0bea99c94b9e3e8e2ce9563fd82bd18b6bcf74d49d8
+DIST qiskit-0.46.1.gh.tar.gz 10952767 BLAKE2B 96143144de33d967fa91bc0fd21ef291c68ea4155ee0d6498d55597c5c2c00d9a53131c73b2b0c3c74594d631bc780c5d82fda1492ea9e025a96c1b6967031b1 SHA512 4fcca5c4d8e9c464e2164c315c80c4ba1e6f1a2d364dfd58b6354bd6a040f21d0cff31a67a5be27dcd4900ec136628ab679dd6e1e630534245441bd8c0587a07
 DIST quote-1.0.32.crate 28037 BLAKE2B 7b243ac7929f3b2e1d91a51a2dc2b11dd29bc017be9db588c83bd137609e2f991a4f3ff8682c7c11c177153e517c4f818285cce3237f435aa43ad0126c4bab6d SHA512 13cae36920dcbd0ad1978be63f20b35b8424d02b4d9992032fa78c7770d61d1fa7ec1532a48793cab48e703236b7bee7843041253b9e83700903228078b4c025
 DIST rand-0.8.5.crate 87113 BLAKE2B 516f26bb2a969d0d79e957818133f35d2c0b4d9f1b401098ea23c5b80d27599e842b9298c0c5e46e2a6cb6953857bf8a9fb71ec9366c5ce6708cf17df14f179c SHA512 8b33a8988906ba5e2057a9a84bdd11f867a5536c22f5056eec59ed4ec4e3a6da2fd773da4c0510d343762e5a4ea0f007db4c4a7cef87a47f90e36c1a84d86fb2
 DIST rand_chacha-0.3.1.crate 15251 BLAKE2B 645771b2c3e274f085e0837a20306b1d59f6e9032fba8eb38a6d1b30180d15e2f89ffa2a162bf6358da41e030098242d81e71dab4321980d0a4f6ddfc2974ce3 SHA512 8198c580b1b9b0429758ffa49cd8138fa3ce724f0dcf73c767ea7e55611d6a2e4c7cad9950896510def500ce4062b594386c947ac3d89425b4e5c9b04d0b8075

diff --git a/dev-python/qiskit-terra/qiskit-terra-0.46.1.ebuild b/dev-python/qiskit-terra/qiskit-terra-0.46.1.ebuild
new file mode 100644
index 000000000000..922260acb3d5
--- /dev/null
+++ b/dev-python/qiskit-terra/qiskit-terra-0.46.1.ebuild
@@ -0,0 +1,188 @@
+# Copyright 2022-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..11} )
+
+CRATES="
+	ahash@0.8.3
+	allocator-api2@0.2.16
+	autocfg@1.1.0
+	bitflags@1.3.2
+	cfg-if@1.0.0
+	crossbeam-deque@0.8.3
+	crossbeam-epoch@0.9.15
+	crossbeam-utils@0.8.16
+	either@1.9.0
+	equivalent@1.0.1
+	fixedbitset@0.4.2
+	getrandom@0.2.10
+	hashbrown@0.12.3
+	hashbrown@0.14.0
+	indexmap@1.9.3
+	indexmap@2.0.1
+	indoc@1.0.9
+	itertools@0.10.5
+	libc@0.2.147
+	libm@0.2.7
+	lock_api@0.4.10
+	matrixmultiply@0.3.7
+	memoffset@0.9.0
+	ndarray@0.15.6
+	num-bigint@0.4.4
+	num-complex@0.4.4
+	num-integer@0.1.45
+	num-traits@0.2.16
+	numpy@0.19.0
+	once_cell@1.18.0
+	parking_lot@0.12.1
+	parking_lot_core@0.9.8
+	petgraph@0.6.3
+	ppv-lite86@0.2.17
+	priority-queue@1.3.2
+	proc-macro2@1.0.66
+	pyo3-build-config@0.19.2
+	pyo3-ffi@0.19.2
+	pyo3-macros-backend@0.19.2
+	pyo3-macros@0.19.2
+	pyo3@0.19.2
+	quote@1.0.32
+	rand@0.8.5
+	rand_chacha@0.3.1
+	rand_core@0.6.4
+	rand_distr@0.4.3
+	rand_pcg@0.3.1
+	rawpointer@0.2.1
+	rayon-cond@0.2.0
+	rayon-core@1.12.0
+	rayon@1.8.0
+	redox_syscall@0.3.5
+	rustc-hash@1.1.0
+	rustworkx-core@0.13.2
+	scopeguard@1.2.0
+	smallvec@1.11.1
+	syn@1.0.109
+	target-lexicon@0.12.11
+	unicode-ident@1.0.11
+	unindent@0.1.11
+	version_check@0.9.4
+	wasi@0.11.0+wasi-snapshot-preview1
+	windows-targets@0.48.2
+	windows_aarch64_gnullvm@0.48.2
+	windows_aarch64_msvc@0.48.2
+	windows_i686_gnu@0.48.2
+	windows_i686_msvc@0.48.2
+	windows_x86_64_gnu@0.48.2
+	windows_x86_64_gnullvm@0.48.2
+	windows_x86_64_msvc@0.48.2
+"
+
+inherit cargo distutils-r1 multiprocessing optfeature
+
+MY_P=qiskit-${PV}
+DESCRIPTION="Terra is the foundation on which Qiskit is built"
+HOMEPAGE="
+	https://github.com/Qiskit/qiskit/
+	https://pypi.org/project/qiskit-terra/
+"
+SRC_URI="
+	https://github.com/Qiskit/qiskit/archive/${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+	${CARGO_CRATE_URIS}
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="Apache-2.0"
+# Dependent crate licenses
+LICENSE+="
+	Apache-2.0 Apache-2.0-with-LLVM-exceptions BSD-2 MIT
+	Unicode-DFS-2016
+	|| ( LGPL-3 MPL-2.0 )
+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="+visualization"
+
+RDEPEND="
+	>=dev-python/rustworkx-0.13.0[${PYTHON_USEDEP}]
+	>=dev-python/numpy-1.17[${PYTHON_USEDEP}]
+	>=dev-python/ply-3.10[${PYTHON_USEDEP}]
+	>=dev-python/psutil-5[${PYTHON_USEDEP}]
+	>=dev-python/scipy-1.5[${PYTHON_USEDEP}]
+	>=dev-python/sympy-1.3[${PYTHON_USEDEP}]
+	>=dev-python/dill-0.3[${PYTHON_USEDEP}]
+	>=dev-python/python-constraint-1.4[${PYTHON_USEDEP}]
+	>=dev-python/python-dateutil-2.8.0[${PYTHON_USEDEP}]
+	>=dev-python/stevedore-3.0.0[${PYTHON_USEDEP}]
+	>=dev-python/symengine-0.11.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		dev-python/typing-extensions[${PYTHON_USEDEP}]
+	' 3.10)
+	visualization? (
+		>=dev-python/matplotlib-3.3[${PYTHON_USEDEP}]
+		>=dev-python/ipywidgets-7.3.0[${PYTHON_USEDEP}]
+		dev-python/pydot[${PYTHON_USEDEP}]
+		>=dev-python/pillow-4.2.1[${PYTHON_USEDEP}]
+		>=dev-python/pylatexenc-1.4[${PYTHON_USEDEP}]
+		>=dev-python/seaborn-0.9.0[${PYTHON_USEDEP}]
+		>=dev-python/pygments-2.4[${PYTHON_USEDEP}]
+	)
+"
+BDEPEND="
+	>=dev-python/cython-0.27.1[${PYTHON_USEDEP}]
+	test? (
+		app-text/poppler[png]
+		>=dev-python/ddt-1.4.4[${PYTHON_USEDEP}]
+		>=dev-python/hypothesis-4.24.3[${PYTHON_USEDEP}]
+		>=dev-python/networkx-2.2[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+		<dev-python/qiskit-aer-0.13[${PYTHON_USEDEP}]
+		>=sci-libs/scikit-learn-0.20.0[${PYTHON_USEDEP}]
+	)
+"
+
+# Files built without CFLAGS/LDFLAGS, acceptable for rust
+QA_FLAGS_IGNORED="
+	usr/lib.*/py.*/site-packages/qiskit/_accelerate.*.so
+	usr/lib.*/py.*/site-packages/qiskit/_qasm2.*.so
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# strip forcing -Werror from tests that also leaks to other packages
+	sed -i -e '/filterwarnings.*error/d' qiskit/test/base.py || die
+	# sigh
+	find -name 'test_*.py' -exec sed -i -e \
+		's:assertRaises(DeprecationWarning):assertWarns(DeprecationWarning):' \
+		{} + || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# TODO
+		test/python/circuit/test_equivalence.py::TestEquivalenceLibraryVisualization::test_equivalence_draw
+		test/python/transpiler/test_unitary_synthesis_plugin.py::TestUnitarySynthesisPlugin
+		test/python/visualization/test_dag_drawer.py::TestDagDrawer::test_dag_drawer_no_register
+	)
+
+	local EPYTEST_IGNORE=(
+		# Breaks xdist
+		test/python/qasm2/test_parse_errors.py
+	)
+
+	rm -rf qiskit || die
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	# Run the Python test suite rather than everything under test/ which
+	# includes the 'randomized' suite. Upstream run that in a separate CI job.
+	# Note: use -p timeout --timeout 500 if debugging hanging tests.
+	epytest -p xdist -n "$(makeopts_jobs)" --dist=worksteal test/python
+}
+
+pkg_postinst() {
+	optfeature "qiskit.circuit.classicalfunction support" dev-python/tweedledum
+}