[gentoo-commits] repo/gentoo:master commit in: dev-scheme/guile-git/

["Maciej Barć" <xgqt@gentoo.org>]

commit:     f3f4e5a687182793aa835b9c2441faaa5cb2b222
Author:     Maciej Barć <xgqt <AT> gentoo <DOT> org>
AuthorDate: Tue Feb 27 21:05:22 2024 +0000
Commit:     Maciej Barć <xgqt <AT> gentoo <DOT> org>
CommitDate: Tue Feb 27 22:47:30 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f3f4e5a6

dev-scheme/guile-git: bump to 0.6.0

Signed-off-by: Maciej Barć <xgqt <AT> gentoo.org>

 dev-scheme/guile-git/Manifest               |  1 +
 dev-scheme/guile-git/guile-git-0.6.0.ebuild | 67 +++++++++++++++++++++++++++++
 2 files changed, 68 insertions(+)

diff --git a/dev-scheme/guile-git/Manifest b/dev-scheme/guile-git/Manifest
index c75f3840803c..24dfb4d5230b 100644
--- a/dev-scheme/guile-git/Manifest
+++ b/dev-scheme/guile-git/Manifest
@@ -1 +1,2 @@
 DIST guile-git-0.5.2.tar.gz 305493 BLAKE2B 03fa85e1943fadc5e7e2da4bed2b6476e5a275856ed087a1730815defc17586f43eb2006bc3970d6f97d42822bcf83ef3d57a74c9a7ddb2fb877f5f0f8237a49 SHA512 4ac55c04c555f1a343f842bbda80d54314697d5bbc28bc3967edfdfacb8afa07c673ef7fd651388a6c55b6977b041174732cde14359a0127f0b931364a7eeda9
+DIST guile-git-v0.6.0.tar.bz2 99833 BLAKE2B 51109cc5f037cffd5e8a6dd1b0ce99631ffb524e209a8b081c33a188ead78d26c76dbb9590e3891c056eb7853da57b7e3f3f08ef3723465bd7ab43671c3d018b SHA512 519b5dafd83b5967403929e347fa2b81fcec97136459722fdc95357cbeba9d519807b8863b17a85fc426e53e8f78f5d3979f96bbb32548bcf598827f3f228219

diff --git a/dev-scheme/guile-git/guile-git-0.6.0.ebuild b/dev-scheme/guile-git/guile-git-0.6.0.ebuild
new file mode 100644
index 000000000000..69f8ffc6fe95
--- /dev/null
+++ b/dev-scheme/guile-git/guile-git-0.6.0.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="Guile bindings of git"
+HOMEPAGE="https://gitlab.com/guile-git/guile-git/"
+
+if [[ "${PV}" == *9999* ]] ; then
+	inherit git-r3
+
+	EGIT_REPO_URI="https://gitlab.com/${PN}/${PN}.git"
+else
+	SRC_URI="https://gitlab.com/${PN}/${PN}/-/archive/v${PV}/${PN}-v${PV}.tar.bz2"
+	S="${WORKDIR}/${PN}-v${PV}"
+
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="LGPL-3+"
+SLOT="0"
+
+# Works without sandbox. But under sandbox sshd claims to break the protocol.
+RESTRICT="test"
+
+# older libgit seems to be incompatible with guile-git bindings
+# https://github.com/trofi/nix-guix-gentoo/issues/7
+RDEPEND="
+	>=dev-libs/libgit2-1:=
+	>=dev-scheme/guile-2.0.11:=
+	dev-scheme/bytestructures
+"
+DEPEND="${RDEPEND}"
+
+# guile generates ELF files without use of C or machine code
+# It's a portage's false positive. bug #677600
+QA_PREBUILT='*[.]go'
+
+src_prepare() {
+	default
+	eautoreconf
+
+	# guile is trying to avoid recompilation by checking if file
+	#     /usr/lib64/guile/2.2/site-ccache/<foo>
+	# is newer than
+	#     <foo>
+	# In case it is instead of using <foo> guile
+	# loads system one (from potentially older version of package).
+	# To work it around we bump last modification timestamp of
+	# '*.scm' files.
+	# http://debbugs.gnu.org/cgi/bugreport.cgi?bug=38112
+	find "${S}" -name "*.scm" -exec touch {} + || die
+}
+
+src_test() {
+	emake check VERBOSE=1
+}
+
+src_install() {
+	default
+
+	# Workaround llvm-strip problem of mangling guile ELF debug
+	# sections: https://bugs.gentoo.org/905898
+	dostrip -x "/usr/$(get_libdir)/guile"
+}