[gentoo-commits] repo/gentoo:master commit in: app-admin/setools/

["Kenton Groombridge" <concord@gentoo.org>]

commit:     cee102b9f47d416612fcf36b5f80d3bb99011b57
Author:     Kenton Groombridge <concord <AT> gentoo <DOT> org>
AuthorDate: Wed Jan 17 00:51:31 2024 +0000
Commit:     Kenton Groombridge <concord <AT> gentoo <DOT> org>
CommitDate: Wed Jan 17 01:28:57 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=cee102b9

app-admin/setools: add 4.4.4

Bug: https://bugs.gentoo.org/922136
Signed-off-by: Kenton Groombridge <concord <AT> gentoo.org>

 app-admin/setools/Manifest             |  1 +
 app-admin/setools/setools-4.4.4.ebuild | 57 ++++++++++++++++++++++++++++++++++
 2 files changed, 58 insertions(+)

diff --git a/app-admin/setools/Manifest b/app-admin/setools/Manifest
index ebb92c6431fe..2e475c76c75d 100644
--- a/app-admin/setools/Manifest
+++ b/app-admin/setools/Manifest
@@ -1 +1,2 @@
 DIST setools-4.4.2.tar.bz2 261962 BLAKE2B 7c8e47d8c15f1eb72d93da5d3ae1a64e857ed0a75e1a47bbad9e4b0d11180581d9e4705ebe942e460acbc4d68261f06f9b03a8c4af1516cc388c201e30dca75e SHA512 4e8cba61ca28459387d862136a2d8ee0914c4bcd254a6d39792cbfcbbf7e58cb82223c05d66c114b08aebbd75c11cef11517c51f674ddb3c1913dc85414546c1
+DIST setools-4.4.4.tar.bz2 262867 BLAKE2B d64605ef050a2d51531e2a180bff086da536aa8d5e5c8cb96a81e137f575d089f9e9ec117cf0de9864f07174d92258b27ebf8fbc462714ef50bbd6d9f80d0a60 SHA512 ef72a7244ba0c724c4aea3afc40d71427e9c0592715f81cccaa8917e96836a88807ea78039c11c261dd3b4d72294accd76ab4bd37447cd500772030245db3c6e

diff --git a/app-admin/setools/setools-4.4.4.ebuild b/app-admin/setools/setools-4.4.4.ebuild
new file mode 100644
index 000000000000..ec3d11050109
--- /dev/null
+++ b/app-admin/setools/setools-4.4.4.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="8"
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit distutils-r1
+
+DESCRIPTION="Policy Analysis Tools for SELinux"
+HOMEPAGE="https://github.com/SELinuxProject/setools/wiki"
+
+if [[ ${PV} == 9999 ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/SELinuxProject/setools.git"
+	S="${WORKDIR}/${P}"
+else
+	SRC_URI="https://github.com/SELinuxProject/setools/releases/download/${PV}/${P}.tar.bz2"
+	KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+	S="${WORKDIR}/${PN}"
+fi
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="0"
+IUSE="test X"
+RESTRICT="!test? ( test )"
+
+RDEPEND="${PYTHON_DEPS}
+	>=dev-python/networkx-2.0[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	>=sys-libs/libsepol-3.2:=
+	>=sys-libs/libselinux-3.2:=
+	X? (
+		dev-python/PyQt5[gui,widgets,${PYTHON_USEDEP}]
+	)"
+DEPEND="${RDEPEND}"
+BDEPEND=">=dev-python/cython-0.27[${PYTHON_USEDEP}]
+	test? (
+		sys-apps/checkpolicy
+	)"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	sed -i "s@^lib_dirs = .*@lib_dirs = ['${ROOT:-/}usr/$(get_libdir)']@" "${S}"/setup.py || \
+		die "failed to set lib_dirs"
+
+	use X || PATCHES+=( "${FILESDIR}"/setools-4.4.2-remove-gui.patch )
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	rm -rf setools || die
+	epytest
+}