[gentoo-commits] repo/proj/guru:dev commit in: net-im/heisenbridge/

["Anna Vyalkova" <cyber+gentoo@sysrq.in>]

commit:     674e75dae43ac90e2ced10c615b216da404871fc
Author:     Anna (cybertailor) Vyalkova <cyber+gentoo <AT> sysrq <DOT> in>
AuthorDate: Tue Jan 16 11:45:44 2024 +0000
Commit:     Anna Vyalkova <cyber+gentoo <AT> sysrq <DOT> in>
CommitDate: Tue Jan 16 11:45:44 2024 +0000
URL:        https://gitweb.gentoo.org/repo/proj/guru.git/commit/?id=674e75da

net-im/heisenbridge: fix 0.0.0 version

Closes: https://bugs.gentoo.org/922020
Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo <AT> sysrq.in>

 net-im/heisenbridge/heisenbridge-1.14.6-r1.ebuild | 68 +++++++++++++++++++++++
 1 file changed, 68 insertions(+)

diff --git a/net-im/heisenbridge/heisenbridge-1.14.6-r1.ebuild b/net-im/heisenbridge/heisenbridge-1.14.6-r1.ebuild
new file mode 100644
index 0000000000..f1e440b504
--- /dev/null
+++ b/net-im/heisenbridge/heisenbridge-1.14.6-r1.ebuild
@@ -0,0 +1,68 @@
+# Copyright 2022-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit distutils-r1 systemd
+
+DESCRIPTION="A bouncer-style Matrix IRC bridge"
+HOMEPAGE="https://github.com/hifi/heisenbridge/"
+SRC_URI="https://github.com/hifi/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.gh.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	acct-user/heisenbridge
+	<dev-python/aiohttp-4[${PYTHON_USEDEP}]
+	dev-python/async-timeout[${PYTHON_USEDEP}]
+	dev-python/irc[${PYTHON_USEDEP}]
+	dev-python/mautrix[${PYTHON_USEDEP}]
+	dev-python/python-socks[${PYTHON_USEDEP}]
+	dev-python/ruamel-yaml[${PYTHON_USEDEP}]
+"
+
+PATCHES=(
+	"${FILESDIR}/heisenbridge-1.14.1-qanotice.patch"
+)
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+	echo ${PV} > ${PN}/version.txt || die
+}
+
+src_install() {
+	distutils-r1_src_install
+
+	newinitd "${FILESDIR}"/heisenbridge.initd ${PN}
+	newconfd "${FILESDIR}"/heisenbridge.confd ${PN}
+	systemd_dounit "${FILESDIR}"/${PN}.service
+}
+
+pkg_postinst() {
+	[[ -f /var/lib/${PN}/registration.yaml ]] && return 0
+
+	einfo
+	elog "Before you can use ${PN}, you have to configure it correctly."
+	elog "The configuration file is located at /etc/conf.d/${PN}"
+	elog
+	elog "Then, you must generate the registration file using the following command:"
+	elog "* If you are using Synapse:"
+	elog "\t${PN} -c /var/lib/${PN}/registration.yaml --generate https://example.com"
+	elog "* If you are using Dendrite, Conduit or others:"
+	elog "\t${PN} -c /var/lib/${PN}/registration.yaml --generate-compat https://example.com"
+	elog
+	elog "Notice the URL at the end, replace it with your homeserver's URL."
+	elog "Then, you must register the bridge with your homeserver."
+	elog "Refer to your homeserver's documentation for instructions."
+	elog "The registration file is located at /var/lib/${PN}/registration.yaml"
+	elog "Finally, you may start the ${PN} daemon."
+	einfo
+
+}