public inbox for gentoo-commits@lists.gentoo.org
 help / color / mirror / Atom feed
* [gentoo-commits] repo/proj/guru:dev commit in: app-emulation/looking-glass/
@ 2024-01-08  3:42 Takuya Wakazono
  0 siblings, 0 replies; 3+ messages in thread
From: Takuya Wakazono @ 2024-01-08  3:42 UTC (permalink / raw
  To: gentoo-commits

commit:     38fdbcf7a7b2f9b7f9fda3ee151c56c24b9a99c0
Author:     Takuya Wakazono <pastalian46 <AT> gmail <DOT> com>
AuthorDate: Mon Jan  8 03:41:36 2024 +0000
Commit:     Takuya Wakazono <pastalian46 <AT> gmail <DOT> com>
CommitDate: Mon Jan  8 03:41:36 2024 +0000
URL:        https://gitweb.gentoo.org/repo/proj/guru.git/commit/?id=38fdbcf7

app-emulation/looking-glass: sync live

Signed-off-by: Takuya Wakazono <pastalian46 <AT> gmail.com>

 .../looking-glass/looking-glass-9999.ebuild        | 67 ++++++++++++++--------
 1 file changed, 42 insertions(+), 25 deletions(-)

diff --git a/app-emulation/looking-glass/looking-glass-9999.ebuild b/app-emulation/looking-glass/looking-glass-9999.ebuild
index e7ce49f17f..8e9108ef0e 100644
--- a/app-emulation/looking-glass/looking-glass-9999.ebuild
+++ b/app-emulation/looking-glass/looking-glass-9999.ebuild
@@ -1,20 +1,31 @@
-# Copyright 1999-2023 Gentoo Authors
+# Copyright 1999-2024 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
 
-inherit cmake git-r3 desktop xdg-utils
+inherit cmake desktop xdg
+
+MY_PV="${PV/1_beta/B}"
 
-EGIT_REPO_URI="https://github.com/gnif/LookingGlass.git"
 DESCRIPTION="A low latency KVM FrameRelay implementation for guests with VGA PCI Passthrough"
 HOMEPAGE="https://looking-glass.io https://github.com/gnif/LookingGlass"
 
+if [[ "${PV}" == *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/gnif/LookingGlass.git"
+else
+	SRC_URI="https://looking-glass.io/artifact/${MY_PV}/source -> ${P}.tar.gz"
+	S="${WORKDIR}/${PN}-${MY_PV}"
+	KEYWORDS="~amd64"
+fi
+
 LICENSE="GPL-2"
 SLOT="0"
 IUSE="binutils gnome pipewire pulseaudio wayland X"
-REQUIRED_USE="|| ( binutils gnome pipewire pulseaudio wayland X ) pipewire? ( !pulseaudio ) pulseaudio? ( !pipewire ) "
+REQUIRED_USE="|| ( wayland X )"
 
-RDEPEND="dev-libs/libconfig
+RDEPEND="
+	dev-libs/libconfig
 	dev-libs/nettle
 	media-libs/freetype
 	media-libs/fontconfig
@@ -23,39 +34,44 @@ RDEPEND="dev-libs/libconfig
 	virtual/glu
 	media-libs/libsamplerate
 	binutils? ( sys-devel/binutils )
-	X? ( x11-libs/libX11 x11-libs/libXfixes x11-libs/libXi x11-libs/libXScrnSaver x11-libs/libXpresent )
+	X? (
+		x11-libs/libX11
+		x11-libs/libXfixes
+		x11-libs/libXi
+		x11-libs/libXinerama
+		x11-libs/libXScrnSaver
+		x11-libs/libXpresent
+	)
 	wayland? ( dev-libs/wayland )
 	media-libs/libpulse
 	pipewire? ( media-video/pipewire )
 	gnome? ( gui-libs/libdecor )
 "
 
-DEPEND="${RDEPEND}
+DEPEND="
+	${RDEPEND}
 	app-emulation/spice-protocol
 	wayland? ( dev-libs/wayland-protocols )
 "
-BDEPEND="virtual/pkgconfig"
+BDEPEND="
+	virtual/pkgconfig
+	wayland? ( dev-util/wayland-scanner )
+"
 
 CMAKE_USE_DIR="${S}"/client
 
-src_prepare () {
-	default
-
+src_configure () {
 	# Base on build.rst from the project
 	# doc/build.rst
-	MYCMAKEARGS=(
-		-DENABLE_BACKTRACE=$(usex binutils) \
-		-DENABLE_X11=$(usex X) -DENABLE_WAYLAND=$(usex wayland) \
-		-DENABLE_PIPEWIRE=$(usex pipewire) \
-		-DENABLE_PULSEAUDIO=$(usex pulseaudio) \
+	local mycmakeargs=(
+		-DENABLE_BACKTRACE=$(usex binutils)
+		-DENABLE_X11=$(usex X)
+		-DENABLE_WAYLAND=$(usex wayland)
+		-DENABLE_PIPEWIRE=$(usex pipewire)
+		-DENABLE_PULSEAUDIO=$(usex pulseaudio)
 		-DENABLE_LIBDECOR=$(usex gnome)
 	)
-
-	cmake_src_prepare
-}
-
-src_compile() {
-	cmake_src_compile
+	cmake_src_configure
 }
 
 src_install() {
@@ -74,12 +90,13 @@ src_install() {
 }
 
 pkg_postinst() {
-	xdg_icon_cache_update
+	xdg_pkg_postinst
+
 	if use X && ! use wayland || ! use X && use wayland; then
-		ewarn "The desktop file located located at /usr/share/applications/LookingGlass.desktop"
+		ewarn "The desktop file located at /usr/share/applications/LookingGlass.desktop"
 	fi
 	if use X && use wayland; then
-		ewarn "The desktop files located located at /usr/share/applications/LookingGlass-X.desktop /usr/share/applications/LookingGlass-Wayland.desktop"
+		ewarn "The desktop files located at /usr/share/applications/LookingGlass-X.desktop /usr/share/applications/LookingGlass-Wayland.desktop"
 	fi
 	ewarn "Use the Right Control (Control_R) as the modifier key to control the action in LookingGlass"
 	ewarn "Note: Key was change because my laptop dosent have ScrLk"


^ permalink raw reply related	[flat|nested] 3+ messages in thread
* [gentoo-commits] repo/proj/guru:dev commit in: app-emulation/looking-glass/
@ 2024-01-08  3:42 Takuya Wakazono
  0 siblings, 0 replies; 3+ messages in thread
From: Takuya Wakazono @ 2024-01-08  3:42 UTC (permalink / raw
  To: gentoo-commits

commit:     1b195185cc8d151f877d583e3dc7ff40cadcead9
Author:     Takuya Wakazono <pastalian46 <AT> gmail <DOT> com>
AuthorDate: Mon Jan  8 03:40:35 2024 +0000
Commit:     Takuya Wakazono <pastalian46 <AT> gmail <DOT> com>
CommitDate: Mon Jan  8 03:40:35 2024 +0000
URL:        https://gitweb.gentoo.org/repo/proj/guru.git/commit/?id=1b195185

app-emulation/looking-glass: keyword 1_beta6 for ~amd64

Signed-off-by: Takuya Wakazono <pastalian46 <AT> gmail.com>

 app-emulation/looking-glass/Manifest               |  1 +
 .../looking-glass/looking-glass-1_beta6.ebuild     | 64 ++++++++++++++--------
 2 files changed, 43 insertions(+), 22 deletions(-)

diff --git a/app-emulation/looking-glass/Manifest b/app-emulation/looking-glass/Manifest
new file mode 100644
index 0000000000..bab5816a51
--- /dev/null
+++ b/app-emulation/looking-glass/Manifest
@@ -0,0 +1 @@
+DIST looking-glass-1_beta6.tar.gz 2774858 BLAKE2B 351d7805447552d9945ae9a4e24cb853eda8f5bbff32d882355aa634ad67912881830dd36e5c48b1796b2f26f83f6db061004bfb6af4dfbc7704162190629efe SHA512 558981d6b32098076ef0775a748da349941551352cbef836e37310e43e5cd6072df3dec6fa2418a9abecc7729ef0c1c6869e3168d05a3d76bea46c6eb8c4e82c

diff --git a/app-emulation/looking-glass/looking-glass-1_beta6.ebuild b/app-emulation/looking-glass/looking-glass-1_beta6.ebuild
index 90b1c633e8..8e9108ef0e 100644
--- a/app-emulation/looking-glass/looking-glass-1_beta6.ebuild
+++ b/app-emulation/looking-glass/looking-glass-1_beta6.ebuild
@@ -1,21 +1,31 @@
-# Copyright 1999-2023 Gentoo Authors
+# Copyright 1999-2024 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
 
-inherit cmake git-r3 desktop xdg-utils
+inherit cmake desktop xdg
+
+MY_PV="${PV/1_beta/B}"
 
-EGIT_REPO_URI="https://github.com/gnif/LookingGlass.git"
-EGIT_BRANCH="Release/B6"
 DESCRIPTION="A low latency KVM FrameRelay implementation for guests with VGA PCI Passthrough"
 HOMEPAGE="https://looking-glass.io https://github.com/gnif/LookingGlass"
 
+if [[ "${PV}" == *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/gnif/LookingGlass.git"
+else
+	SRC_URI="https://looking-glass.io/artifact/${MY_PV}/source -> ${P}.tar.gz"
+	S="${WORKDIR}/${PN}-${MY_PV}"
+	KEYWORDS="~amd64"
+fi
+
 LICENSE="GPL-2"
 SLOT="0"
 IUSE="binutils gnome pipewire pulseaudio wayland X"
-REQUIRED_USE="|| ( binutils gnome pipewire pulseaudio wayland X ) pipewire? ( !pulseaudio ) pulseaudio? ( !pipewire ) "
+REQUIRED_USE="|| ( wayland X )"
 
-RDEPEND="dev-libs/libconfig
+RDEPEND="
+	dev-libs/libconfig
 	dev-libs/nettle
 	media-libs/freetype
 	media-libs/fontconfig
@@ -24,35 +34,44 @@ RDEPEND="dev-libs/libconfig
 	virtual/glu
 	media-libs/libsamplerate
 	binutils? ( sys-devel/binutils )
-	X? ( x11-libs/libX11 x11-libs/libXfixes x11-libs/libXi x11-libs/libXScrnSaver x11-libs/libXpresent )
+	X? (
+		x11-libs/libX11
+		x11-libs/libXfixes
+		x11-libs/libXi
+		x11-libs/libXinerama
+		x11-libs/libXScrnSaver
+		x11-libs/libXpresent
+	)
 	wayland? ( dev-libs/wayland )
 	media-libs/libpulse
 	pipewire? ( media-video/pipewire )
 	gnome? ( gui-libs/libdecor )
 "
 
-DEPEND="${RDEPEND}
+DEPEND="
+	${RDEPEND}
 	app-emulation/spice-protocol
 	wayland? ( dev-libs/wayland-protocols )
 "
-BDEPEND="virtual/pkgconfig"
+BDEPEND="
+	virtual/pkgconfig
+	wayland? ( dev-util/wayland-scanner )
+"
 
 CMAKE_USE_DIR="${S}"/client
 
-src_prepare () {
-	default
-
+src_configure () {
 	# Base on build.rst from the project
 	# doc/build.rst
-	MYCMAKEARGS=(
-		-DENABLE_BACKTRACE=$(usex binutils) \
-		-DENABLE_X11=$(usex X) -DENABLE_WAYLAND=$(usex wayland) \
-		-DENABLE_PIPEWIRE=$(usex pipewire) \
-		-DENABLE_PULSEAUDIO=$(usex pulseaudio) \
+	local mycmakeargs=(
+		-DENABLE_BACKTRACE=$(usex binutils)
+		-DENABLE_X11=$(usex X)
+		-DENABLE_WAYLAND=$(usex wayland)
+		-DENABLE_PIPEWIRE=$(usex pipewire)
+		-DENABLE_PULSEAUDIO=$(usex pulseaudio)
 		-DENABLE_LIBDECOR=$(usex gnome)
 	)
-
-	cmake_src_prepare
+	cmake_src_configure
 }
 
 src_install() {
@@ -71,12 +90,13 @@ src_install() {
 }
 
 pkg_postinst() {
-	xdg_icon_cache_update
+	xdg_pkg_postinst
+
 	if use X && ! use wayland || ! use X && use wayland; then
-		ewarn "The desktop file located located at /usr/share/applications/LookingGlass.desktop"
+		ewarn "The desktop file located at /usr/share/applications/LookingGlass.desktop"
 	fi
 	if use X && use wayland; then
-		ewarn "The desktop files located located at /usr/share/applications/LookingGlass-X.desktop /usr/share/applications/LookingGlass-Wayland.desktop"
+		ewarn "The desktop files located at /usr/share/applications/LookingGlass-X.desktop /usr/share/applications/LookingGlass-Wayland.desktop"
 	fi
 	ewarn "Use the Right Control (Control_R) as the modifier key to control the action in LookingGlass"
 	ewarn "Note: Key was change because my laptop dosent have ScrLk"


^ permalink raw reply related	[flat|nested] 3+ messages in thread
* [gentoo-commits] repo/proj/guru:dev commit in: app-emulation/looking-glass/
@ 2025-07-19 13:34 Nikola Brković
  0 siblings, 0 replies; 3+ messages in thread
From: Nikola Brković @ 2025-07-19 13:34 UTC (permalink / raw
  To: gentoo-commits

commit:     325494bf06cb646a538882b968bf3b33496ff971
Author:     Nikola Brković <nikobrk <AT> proton <DOT> me>
AuthorDate: Sat Jul 19 13:25:03 2025 +0000
Commit:     Nikola Brković <nikobrk <AT> proton <DOT> me>
CommitDate: Sat Jul 19 13:25:03 2025 +0000
URL:        https://gitweb.gentoo.org/repo/proj/guru.git/commit/?id=325494bf

app-emulation/looking-glass: add 1_beta7

Signed-off-by: Nikola Brković <nikobrk <AT> proton.me>

 app-emulation/looking-glass/Manifest               |   1 +
 .../looking-glass/looking-glass-1_beta7.ebuild     | 107 +++++++++++++++++++++
 2 files changed, 108 insertions(+)

diff --git a/app-emulation/looking-glass/Manifest b/app-emulation/looking-glass/Manifest
index bab5816a51..f5f8a0df59 100644
--- a/app-emulation/looking-glass/Manifest
+++ b/app-emulation/looking-glass/Manifest
@@ -1 +1,2 @@
 DIST looking-glass-1_beta6.tar.gz 2774858 BLAKE2B 351d7805447552d9945ae9a4e24cb853eda8f5bbff32d882355aa634ad67912881830dd36e5c48b1796b2f26f83f6db061004bfb6af4dfbc7704162190629efe SHA512 558981d6b32098076ef0775a748da349941551352cbef836e37310e43e5cd6072df3dec6fa2418a9abecc7729ef0c1c6869e3168d05a3d76bea46c6eb8c4e82c
+DIST looking-glass-1_beta7.tar.gz 3214844 BLAKE2B dd4b2e7a7d08c78461b176957fb59b7e9c13a57f9c65b33a0d6a197929117e7b6c96f13406defd4d34699c4028a80e293970c5540a5cdaf626137029ba0a4289 SHA512 a3f0193451c64dbd9ead01538fa53cc78b42d318d54b2eef026fb730811e055bb140b67dcd91c1da5ef09ec74fbb141c791b53264a56a943308b81a6e49e1e93

diff --git a/app-emulation/looking-glass/looking-glass-1_beta7.ebuild b/app-emulation/looking-glass/looking-glass-1_beta7.ebuild
new file mode 100644
index 0000000000..8e9108ef0e
--- /dev/null
+++ b/app-emulation/looking-glass/looking-glass-1_beta7.ebuild
@@ -0,0 +1,107 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake desktop xdg
+
+MY_PV="${PV/1_beta/B}"
+
+DESCRIPTION="A low latency KVM FrameRelay implementation for guests with VGA PCI Passthrough"
+HOMEPAGE="https://looking-glass.io https://github.com/gnif/LookingGlass"
+
+if [[ "${PV}" == *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/gnif/LookingGlass.git"
+else
+	SRC_URI="https://looking-glass.io/artifact/${MY_PV}/source -> ${P}.tar.gz"
+	S="${WORKDIR}/${PN}-${MY_PV}"
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="binutils gnome pipewire pulseaudio wayland X"
+REQUIRED_USE="|| ( wayland X )"
+
+RDEPEND="
+	dev-libs/libconfig
+	dev-libs/nettle
+	media-libs/freetype
+	media-libs/fontconfig
+	media-libs/libsdl2
+	media-libs/sdl2-ttf
+	virtual/glu
+	media-libs/libsamplerate
+	binutils? ( sys-devel/binutils )
+	X? (
+		x11-libs/libX11
+		x11-libs/libXfixes
+		x11-libs/libXi
+		x11-libs/libXinerama
+		x11-libs/libXScrnSaver
+		x11-libs/libXpresent
+	)
+	wayland? ( dev-libs/wayland )
+	media-libs/libpulse
+	pipewire? ( media-video/pipewire )
+	gnome? ( gui-libs/libdecor )
+"
+
+DEPEND="
+	${RDEPEND}
+	app-emulation/spice-protocol
+	wayland? ( dev-libs/wayland-protocols )
+"
+BDEPEND="
+	virtual/pkgconfig
+	wayland? ( dev-util/wayland-scanner )
+"
+
+CMAKE_USE_DIR="${S}"/client
+
+src_configure () {
+	# Base on build.rst from the project
+	# doc/build.rst
+	local mycmakeargs=(
+		-DENABLE_BACKTRACE=$(usex binutils)
+		-DENABLE_X11=$(usex X)
+		-DENABLE_WAYLAND=$(usex wayland)
+		-DENABLE_PIPEWIRE=$(usex pipewire)
+		-DENABLE_PULSEAUDIO=$(usex pulseaudio)
+		-DENABLE_LIBDECOR=$(usex gnome)
+	)
+	cmake_src_configure
+}
+
+src_install() {
+	einstalldocs
+	dobin "${BUILD_DIR}/looking-glass-client"
+	newicon -s 128 "${S}/resources/icon-128x128.png" looking-glass-client.png
+
+	if use X && ! use wayland || ! use X && use wayland; then
+		domenu "${FILESDIR}/LookingGlass.desktop"
+	fi
+
+	if use X && use wayland; then
+		domenu "${FILESDIR}/LookingGlass-X.desktop"
+		newmenu "${FILESDIR}/LookingGlass.desktop" LookingGlass-Wayland.desktop
+	fi
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	if use X && ! use wayland || ! use X && use wayland; then
+		ewarn "The desktop file located at /usr/share/applications/LookingGlass.desktop"
+	fi
+	if use X && use wayland; then
+		ewarn "The desktop files located at /usr/share/applications/LookingGlass-X.desktop /usr/share/applications/LookingGlass-Wayland.desktop"
+	fi
+	ewarn "Use the Right Control (Control_R) as the modifier key to control the action in LookingGlass"
+	ewarn "Note: Key was change because my laptop dosent have ScrLk"
+	ewarn "Tip: If you press and hold the modfier key (Control_R) you get all the key shortcuts for all action"
+	ewarn ""
+	ewarn "Note: The modifier key can be change by editing the desktop file"
+	ewarn "More information on this link: https://looking-glass.io/wiki/Client/Keyboard_shortcuts"
+}


^ permalink raw reply related	[flat|nested] 3+ messages in thread
end of thread, other threads:[~2025-07-19 13:34 UTC | newest]

Thread overview: 3+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2024-01-08  3:42 [gentoo-commits] repo/proj/guru:dev commit in: app-emulation/looking-glass/ Takuya Wakazono
  -- strict thread matches above, loose matches on Subject: below --
2025-07-19 13:34 Nikola Brković
2024-01-08  3:42 Takuya Wakazono

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox