[gentoo-commits] repo/proj/guru:dev commit in: x11-wm/phoc/

["Anna Vyalkova" <cyber+gentoo@sysrq.in>]

commit:     b7c7436cc88a782948bf6ad96b506aaff3c2c462
Author:     Anna (cybertailor) Vyalkova <cyber+gentoo <AT> sysrq <DOT> in>
AuthorDate: Sun Jan  7 20:18:33 2024 +0000
Commit:     Anna Vyalkova <cyber+gentoo <AT> sysrq <DOT> in>
CommitDate: Sun Jan  7 20:18:33 2024 +0000
URL:        https://gitweb.gentoo.org/repo/proj/guru.git/commit/?id=b7c7436c

x11-wm/phoc: add 0.35.0

Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo <AT> sysrq.in>

 x11-wm/phoc/Manifest           |  1 +
 x11-wm/phoc/phoc-0.35.0.ebuild | 76 ++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 77 insertions(+)

diff --git a/x11-wm/phoc/Manifest b/x11-wm/phoc/Manifest
index 06e04b7557..fd75171bab 100644
--- a/x11-wm/phoc/Manifest
+++ b/x11-wm/phoc/Manifest
@@ -1 +1,2 @@
 DIST phoc-0.33.0.tar.xz 646148 BLAKE2B 74e6ac8eec5a37a9dd255d48b1bca65f992399eeb9dc19b22bb84e746f7cae95306c0a487aae828d939be2a0736408476aba6b947c1f44d825340bfcb1873d49 SHA512 7907c116b426383843b6782bafe5f416e7cb8b4039c9ee81ace35476df3b4d0ef92a968f57edef91094cd28387ceff03f1cdd802de65e0e9e3840eab03a78ac9
+DIST phoc-0.35.0.tar.xz 677432 BLAKE2B 722a3669b1d76015612b5f4020d0e21c47faa8f6fb19887b2b79d4f6b79e30f45e0332ae2e2771fb9169214002508bdcff61ee0e7f874930e03a7cf952c44e7c SHA512 ec4b382ef11b257afe3b13ebf1e588353c785279afde4b1a8ee80790cb6a299fd94098a5170b30a2114061d86bdf388bb1c99f8ce1bd5173deb886d11015681e

diff --git a/x11-wm/phoc/phoc-0.35.0.ebuild b/x11-wm/phoc/phoc-0.35.0.ebuild
new file mode 100644
index 0000000000..ff9004696c
--- /dev/null
+++ b/x11-wm/phoc/phoc-0.35.0.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome2-utils meson virtualx xdg
+
+DESCRIPTION="Wayland compositor for mobile phones"
+HOMEPAGE="https://gitlab.gnome.org/World/Phosh/phoc"
+SRC_URI="https://sources.phosh.mobi/releases/${PN}/${P}.tar.xz"
+
+LICENSE="|| ( GPL-3+ MIT ) GPL-3+ LGPL-2.1+ MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+IUSE="+X gtk-doc man test"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	>=dev-libs/glib-2.74:2
+	dev-libs/json-glib
+	dev-libs/libinput:=
+	dev-libs/wayland
+	>=gnome-base/gnome-desktop-3.26:3
+	gnome-base/gsettings-desktop-schemas
+	>=gui-libs/wlroots-0.17.1:=[X?]
+	<gui-libs/wlroots-0.18.0
+	media-libs/libglvnd
+	x11-libs/libdrm
+	x11-libs/pixman
+	x11-libs/libxkbcommon[X?,wayland]
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	dev-libs/glib:2
+	dev-libs/wayland-protocols
+	dev-util/wayland-scanner
+	sys-devel/gettext
+	gtk-doc? ( dev-util/gi-docgen )
+	man? ( dev-python/docutils )
+	test? ( x11-wm/mutter )
+"
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature X xwayland)
+		$(meson_use gtk-doc gtk_doc)
+		$(meson_use man)
+		$(meson_use test tests)
+		-Dembed-wlroots=disabled
+	)
+	meson_src_configure
+}
+
+src_test() {
+	local -x LC_ALL="C.UTF-8"
+	local -x WLR_RENDERER="pixman"
+
+	virtx meson_src_test
+}
+
+src_install() {
+	meson_src_install
+
+	newbin helpers/auto-maximize phoc-auto-maximize
+	newbin helpers/scale-to-fit phoc-scale-to-fit
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}