[gentoo-commits] repo/gentoo:master commit in: www-client/opera-beta/

["Sam James" <sam@gentoo.org>]

commit:     fa623d6c73574c1e05b85984910c574ad1cee943
Author:     Matt Jolly <Matt.Jolly <AT> footclan <DOT> ninja>
AuthorDate: Mon Dec 18 01:56:07 2023 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Mon Dec 18 06:34:14 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=fa623d6c

www-client/opera-beta: remove old

Signed-off-by: Matt Jolly <Matt.Jolly <AT> footclan.ninja>
Closes: https://github.com/gentoo/gentoo/pull/34336
Signed-off-by: Sam James <sam <AT> gentoo.org>

 www-client/opera-beta/Manifest                     |   1 -
 .../opera-beta/opera-beta-105.0.4970.10.ebuild     | 170 ---------------------
 2 files changed, 171 deletions(-)

diff --git a/www-client/opera-beta/Manifest b/www-client/opera-beta/Manifest
index 5be943856f32..0306557a81b2 100644
--- a/www-client/opera-beta/Manifest
+++ b/www-client/opera-beta/Manifest
@@ -1,4 +1,3 @@
-DIST opera-beta_105.0.4970.10_amd64.deb 112026380 BLAKE2B 412dc99ca4230102dcae9c18504ba23cd7e39afe07b1908db9e5a4d258599b18d5f8c4e6e8c376c5edf20d2a830d909461f8f2d35889c0ebcd3d37c89ded78df SHA512 7b1c771523567b14a1511306eec1f6ce3534dfdb16bb7ba37c77b81bcf594bff54e0f81b9cf5d640515de12c190f15b405fe7c6e4b02ec86552062c01daf0ced
 DIST opera-beta_106.0.4998.12_amd64.deb 108017580 BLAKE2B b102c6eb8ea39bbbe5a4bef22f2a7b1257b19c13dd343197e1d482f6c3d0226683fb541f990d9ee16a6265656f8d47c83f6695e1a89396be6c15fc1c7faf66a1 SHA512 9320df034967e86cdcfbed236500d81aa707a604e3c9fbd27c51df0d0ad12ec12e24763bf2b1bcc2e7d0416929c6411aed30977cf264c11443dd4dfc680dfb5d
 DIST opera-beta_106.0.4998.2_amd64.deb 108024200 BLAKE2B 6c7fbadbe2ce01e598487adacc8d4e72ea59228b799178d5e0e7455ae8fc83e6256fccc58fe24fafb85310236d8ee8069df07e36afc0353b5e3f11316efd7165 SHA512 834b9d2c12414d3db000c4ea828cfdcf2a452b52f29d296f3f97dc235609fad13c1053c5ca2b2d108a9dd0e62ff1b5436ca564d3c94ca151392167f884a28a03
 DIST opera-beta_106.0.4998.6_amd64.deb 108017664 BLAKE2B 4b9c00495be70e9589a27fed0445d108c41a84719d863aa32c47cd571c09b33515c3c58e2303cf5df53dc4c923100682700e2ff9643fd585cfcc10f57a0960c5 SHA512 64d748448d710a0fb434ee3c7aefe0183272bbae832cbf3aa0aa2e0d26f124bdad870991ac4174ad14713b90382ababde96bae0f4c0e2e330c28cf11b4e85c1d

diff --git a/www-client/opera-beta/opera-beta-105.0.4970.10.ebuild b/www-client/opera-beta/opera-beta-105.0.4970.10.ebuild
deleted file mode 100644
index fa627a202454..000000000000
--- a/www-client/opera-beta/opera-beta-105.0.4970.10.ebuild
+++ /dev/null
@@ -1,170 +0,0 @@
-# Copyright 1999-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-CHROMIUM_LANGS="
-	bg bn ca cs da de el en-GB en-US es-419 es fil fi fr hi hr hu id
-	it ja ko lt lv ms nb nl pl pt-BR pt-PT ro ru sk sr sv sw ta te th tr uk vi
-	zh-CN zh-TW
-"
-
-# These are intended for ebuild maintainer use to force RPM if DEB is not available.
-: ${OPERA_FORCE_RPM=no}
-
-inherit chromium-2 pax-utils xdg
-
-if [[ ${OPERA_FORCE_RPM} == yes ]]; then
-	inherit rpm
-	OPERA_ARCHIVE_EXT="rpm"
-else
-	inherit unpacker
-	OPERA_ARCHIVE_EXT="deb"
-fi
-
-DESCRIPTION="A fast and secure web browser"
-HOMEPAGE="https://www.opera.com/"
-LICENSE="OPERA-2018"
-SLOT="0"
-
-SRC_URI_BASE=(
-	"https://download1.operacdn.com/pub/${PN}"
-	"https://download2.operacdn.com/pub/${PN}"
-	"https://download3.operacdn.com/pub/${PN}"
-	"https://download4.operacdn.com/pub/${PN}"
-)
-
-if [[ ${PN} == opera ]]; then
-	MY_PN=${PN}-stable
-	SRC_URI_BASE=( "${SRC_URI_BASE[@]/%//desktop}" )
-else
-	MY_PN=${PN}
-fi
-
-KEYWORDS="-* ~amd64"
-
-FFMPEG_VERSION="114.0.5735.9"
-
-SRC_URI="${SRC_URI_BASE[@]/%//${PV}/linux/${MY_PN}_${PV}_amd64.${OPERA_ARCHIVE_EXT}}
-	proprietary-codecs? (
-		mirror+https://dev.gentoo.org/~sultan/distfiles/www-client/opera/opera-ffmpeg-codecs-${FFMPEG_VERSION}.tar.xz
-	)"
-
-IUSE="+proprietary-codecs +suid qt5 qt6"
-RESTRICT="bindist mirror strip"
-
-RDEPEND="
-	>=app-accessibility/at-spi2-core-2.46.0:2
-	dev-libs/expat
-	dev-libs/glib:2
-	dev-libs/nspr
-	dev-libs/nss
-	gnome-base/gsettings-desktop-schemas
-	media-libs/alsa-lib
-	media-libs/mesa[gbm(+)]
-	net-misc/curl
-	net-print/cups
-	sys-apps/dbus
-	sys-libs/glibc
-	x11-libs/cairo
-	x11-libs/gdk-pixbuf
-	x11-libs/gtk+:3
-	x11-libs/libdrm
-	x11-libs/libxcb
-	x11-libs/libxkbcommon
-	x11-libs/libxshmfence
-	x11-libs/libX11
-	x11-libs/libXcomposite
-	x11-libs/libXdamage
-	x11-libs/libXext
-	x11-libs/libXfixes
-	x11-libs/libXrandr
-	x11-libs/pango
-	qt5? (
-		dev-qt/qtcore:5
-		dev-qt/qtgui:5[X]
-		dev-qt/qtwidgets:5
-	)
-	qt6? ( dev-qt/qtbase:6[gui,widgets] )
-"
-
-QA_PREBUILT="*"
-S=${WORKDIR}
-OPERA_HOME="opt/opera${PN#opera}"
-
-pkg_pretend() {
-	# Protect against people using autounmask overzealously
-	use amd64 || die "opera only works on amd64"
-}
-
-pkg_setup() {
-	chromium_suid_sandbox_check_kernel_config
-}
-
-src_unpack() {
-	:
-}
-
-src_install() {
-	dodir /
-	cd "${ED}" || die
-	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
-		rpm_src_unpack "${A[0]}"
-	else
-		unpacker
-	fi
-
-	# move to /opt, bug #573052
-	mkdir -p "${OPERA_HOME%${PN}}"
-	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
-		mv "usr/lib64/${PN}" "${OPERA_HOME%${PN}}" || die
-	else
-		mv "usr/lib/x86_64-linux-gnu/${PN}" "${OPERA_HOME%${PN}}" || die
-	fi
-	rm -r "usr/lib" || die
-
-	# disable auto update
-	rm "${OPERA_HOME}/${PN%-*}_autoupdate"{,.licenses,.version} || die
-
-	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
-		rm "${OPERA_HOME}/setup_repo.sh" || die
-	else
-		rm -r "usr/share/lintian" || die
-
-		# fix docs
-		mv usr/share/doc/${MY_PN} usr/share/doc/${PF} || die
-		gzip -d usr/share/doc/${PF}/changelog.gz || die
-	fi
-
-	# fix desktop file
-	sed -i \
-		-e 's|^TargetEnvironment|X-&|g' \
-		usr/share/applications/${PN}.desktop || die
-
-	# remove unused language packs
-	pushd "${OPERA_HOME}/localization" > /dev/null || die
-	chromium_remove_language_paks
-	popd > /dev/null || die
-
-	# setup opera symlink
-	rm "usr/bin/${PN}" || die
-	dosym "../../${OPERA_HOME}/${PN}" "/usr/bin/${PN}"
-
-	# install proprietary codecs
-	rm "${OPERA_HOME}/resources/ffmpeg_preload_config.json" || die
-	if use proprietary-codecs; then
-		mv lib_extra "${OPERA_HOME}"
-	fi
-
-	if ! use qt5; then
-		rm "${OPERA_HOME}/libqt5_shim.so" || die
-	fi
-	if ! use qt6; then
-		rm "${OPERA_HOME}/libqt6_shim.so" || die
-	fi
-
-	# pax mark opera, bug #562038
-	pax-mark m "${OPERA_HOME}/opera"
-	# enable suid sandbox if requested
-	use suid && fperms 4711 "/${OPERA_HOME}/opera_sandbox"
-}