[gentoo-commits] repo/gentoo:master commit in: dev-python/qtawesome/

["Michał Górny" <mgorny@gentoo.org>]

commit:     54f5918b672173972a1fb049fc46c25efe2a74bd
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Tue Dec 12 06:23:18 2023 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Tue Dec 12 06:32:20 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=54f5918b

dev-python/qtawesome: Bump to 1.3.0

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/qtawesome/Manifest               |  1 +
 dev-python/qtawesome/qtawesome-1.3.0.ebuild | 49 +++++++++++++++++++++++++++++
 2 files changed, 50 insertions(+)

diff --git a/dev-python/qtawesome/Manifest b/dev-python/qtawesome/Manifest
index 25346ce48f10..c29face938cc 100644
--- a/dev-python/qtawesome/Manifest
+++ b/dev-python/qtawesome/Manifest
@@ -1 +1,2 @@
 DIST QtAwesome-1.2.3.tar.gz 2281470 BLAKE2B 3aa015708b6cc26b01fdb17cd1a283ce6aaf05eb8e6e6c316f02a6475738565fb350d64d298c7c2983604f61f40c3b51f3b5e2c134ecae6142519fa78593daf9 SHA512 8c265511922016e6e304443d5771ce19abae62afc8a7115452bde83ca033cb63da2fbe3a91073ff0394ded9a5959a965a0e2a17cae9ed8be0e7c93309a952337
+DIST QtAwesome-1.3.0.tar.gz 2375398 BLAKE2B ed4f33b7f1fe7c54b4794247032a65638f4b1527ac460274486c673d767332c5aab64bc27924738914147e674e17c23e0e23e728fa32af8925fce7f58b417d17 SHA512 536918a63a22555b52abd66302f020f91df8ee75e8e806b258780944e143275245a73a4f215e2626eaf1d844552426fc1b45eff4e5de05a268b8b9179492cd7e

diff --git a/dev-python/qtawesome/qtawesome-1.3.0.ebuild b/dev-python/qtawesome/qtawesome-1.3.0.ebuild
new file mode 100644
index 000000000000..fef57c0b82ba
--- /dev/null
+++ b/dev-python/qtawesome/qtawesome-1.3.0.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+DISTUTILS_USE_PEP517=setuptools
+
+inherit distutils-r1 pypi virtualx
+
+DESCRIPTION="Enables iconic fonts such as Font Awesome in PyQt"
+HOMEPAGE="
+	https://github.com/spyder-ide/qtawesome/
+	https://pypi.org/project/QtAwesome/
+"
+SRC_URI="$(pypi_sdist_url --no-normalize QtAwesome)"
+S="${WORKDIR}/QtAwesome-${PV}"
+
+LICENSE="MIT"
+# bundled fonts
+# -------------
+# Font Awesome, Elusive Icons: OFL-1.1
+# Phosphor: MIT
+# Material Design Icons, Remix Icon: Apache-2.0
+# Codicons: CC-BY-4.0
+LICENSE+=" Apache-2.0 CC-BY-4.0 MIT OFL-1.1"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	media-fonts/fontawesome
+	dev-python/QtPy[gui,${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/pytest-qt[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs/source
+
+src_test() {
+	virtx distutils-r1_src_test
+}
+
+python_test() {
+	nonfatal epytest || die -n "Tests failed with ${EPYTHON}"
+}