[gentoo-commits] repo/gentoo:master commit in: sys-apps/polychromatic/

["Maciej Barć" <xgqt@gentoo.org>]

commit:     bbd4e8f161ad3b2d832c6c0f0ef0071c227549fa
Author:     Maciej Barć <xgqt <AT> gentoo <DOT> org>
AuthorDate: Mon Nov 20 08:18:05 2023 +0000
Commit:     Maciej Barć <xgqt <AT> gentoo <DOT> org>
CommitDate: Mon Nov 20 19:17:26 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=bbd4e8f1

sys-apps/polychromatic: bump to 0.8.3

Signed-off-by: Maciej Barć <xgqt <AT> gentoo.org>

 sys-apps/polychromatic/Manifest                   |  1 +
 sys-apps/polychromatic/polychromatic-0.8.3.ebuild | 69 +++++++++++++++++++++++
 2 files changed, 70 insertions(+)

diff --git a/sys-apps/polychromatic/Manifest b/sys-apps/polychromatic/Manifest
index f578d5a0802c..e231768e1dc9 100644
--- a/sys-apps/polychromatic/Manifest
+++ b/sys-apps/polychromatic/Manifest
@@ -1,2 +1,3 @@
 DIST polychromatic-0.8.1.tar.gz 1673716 BLAKE2B 9751985ac429d5da19e829f3b17565e1c42b7859df6ce3be031e34148e1c30bcb37bee3103b038e902a818a7ade9e3cc4400570135c34229494666f9a9a6012a SHA512 61add658825f99f729e6921c41aa97b2075e5cbd3dcdabb6602a7eeb6b505a3435d9231ed163490289374bf78737544cda77d45c39f245f20f07886824ea61fa
 DIST polychromatic-0.8.2.tar.gz 1697776 BLAKE2B 209d27258e4e6cedb6d8d0c5e50168ab82854605a90e67cf550e5aaa5a5aec539c84155a0fee44986ae63fba33b8778ad426b0e648ef51e71bb33f42a86909ad SHA512 0965881feb60cdcb2415cf177b951548b6bfefd642fc28305fd37f339e891252bd9a1c9dff296381f53ea221758dbc68ca2968a191d3b7db96c6ee2ec8936c07
+DIST polychromatic-0.8.3.tar.gz 1762021 BLAKE2B eb4925fdd5be892c4f490424f357e8d1a2db79ac4bd9b4ae2a6f05662022837ba624d23c373b073de8045207511c50a6f2c4ba6cc4a6f276c2553edcbae25eaf SHA512 e2b26bfda985a2a80373dfa2c10e85a96724eec16c513e825841b7363b692c3edf51fc7ddc0735e28bb1c5074ebd22e9390606d314df35fc61cb185a0fd0acfc

diff --git a/sys-apps/polychromatic/polychromatic-0.8.3.ebuild b/sys-apps/polychromatic/polychromatic-0.8.3.ebuild
new file mode 100644
index 000000000000..f3045e367458
--- /dev/null
+++ b/sys-apps/polychromatic/polychromatic-0.8.3.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit meson python-single-r1 readme.gentoo-r1 xdg
+
+DESCRIPTION="RGB lighting management software for GNU/Linux powered by OpenRazer"
+HOMEPAGE="https://polychromatic.app/
+	https://github.com/polychromatic/polychromatic/"
+
+if [[ ${PV} == *9999* ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/${PN}/${PN}.git"
+else
+	SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz
+		-> ${P}.tar.gz"
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="GPL-3+"
+SLOT="0"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	>=x11-libs/gtk+-3.20:3[introspection]
+	$(python_gen_cond_dep '
+		dev-python/PyQt5[svg,${PYTHON_USEDEP}]
+		dev-python/PyQtWebEngine[${PYTHON_USEDEP}]
+		dev-python/colorama[${PYTHON_USEDEP}]
+		dev-python/colour[${PYTHON_USEDEP}]
+		dev-python/distro[${PYTHON_USEDEP}]
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/setproctitle[${PYTHON_USEDEP}]
+		sys-apps/openrazer[client,${PYTHON_USEDEP}]
+	')
+"
+BDEPEND="
+	${RDEPEND}
+	dev-util/intltool
+	dev-lang/sassc
+"
+
+DOC_CONTENTS="To automatically start up Polychromatic on session login copy
+/usr/share/polychromatic/polychromatic-autostart.desktop file into Your user's
+~/.config/autostart/ directory."
+
+src_install() {
+	meson_src_install
+	python_optimize
+	readme.gentoo_create_doc
+
+	python_doscript "${S}"/polychromatic-{cli,controller,helper,tray-applet}
+
+	# Do not force polychromatic to autostart on session login.
+	# Move it into /usr/share/polychromatic and treat it as an example file
+	# that could be installed into user's ~/.config/autostart/ directory.
+	mv "${ED}"/etc/xdg/autostart/${PN}-autostart.desktop \
+	   "${ED}"/usr/share/${PN}/${PN}-autostart.desktop || die
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	readme.gentoo_print_elog
+}