[gentoo-commits] repo/gentoo:master commit in: dev-python/cattrs/

["Michał Górny" <mgorny@gentoo.org>]

commit:     cf24fc262d5b9e621022785ee26a9d418ed81086
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sat Nov 18 06:28:12 2023 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sat Nov 18 06:42:34 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=cf24fc26

dev-python/cattrs: Bump to 23.2.1

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/cattrs/Manifest             |  1 +
 dev-python/cattrs/cattrs-23.2.1.ebuild | 67 ++++++++++++++++++++++++++++++++++
 2 files changed, 68 insertions(+)

diff --git a/dev-python/cattrs/Manifest b/dev-python/cattrs/Manifest
index 62c587a736b2..b6f764ced0a8 100644
--- a/dev-python/cattrs/Manifest
+++ b/dev-python/cattrs/Manifest
@@ -1 +1,2 @@
 DIST cattrs-23.1.2.gh.tar.gz 602336 BLAKE2B f39ff3c1525ea14789edd137d82343a9447de0a41f65a71ee85754a15f8fdc929137125043b23c6cd088c8b2d2e9da18577c3b6dbbb6e9a33bdf6789f117bc46 SHA512 d05c8a5d4c5dc0b69ccdf33164d44c35a37a871199a35d1c2c25f9fbd8ee53d48da8e9d9bec49cde2baf901b524d5e8ff1ade175928908ea81f94e8398224488
+DIST cattrs-23.2.1.gh.tar.gz 611553 BLAKE2B f0d1c34838c5b869242411d393f2e395b45a84afb302d2df87ab0a51c537fc0057ee9def2b47313e8134635ffb616045f606070a0260ea4814a2cf227539132d SHA512 2b733dc6123cb26ab6d33b1d445ecbddea98a1a76a02acb15231deee2273933bc726da387419fd6143b44e97729d4fd1746eebadd2309e2440bfc5c153f7079b

diff --git a/dev-python/cattrs/cattrs-23.2.1.ebuild b/dev-python/cattrs/cattrs-23.2.1.ebuild
new file mode 100644
index 000000000000..5fef8728bdc0
--- /dev/null
+++ b/dev-python/cattrs/cattrs-23.2.1.ebuild
@@ -0,0 +1,67 @@
+# Copyright 2022-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit distutils-r1
+
+DESCRIPTION="Composable complex class support for attrs and dataclasses"
+HOMEPAGE="
+	https://pypi.org/project/cattrs/
+	https://github.com/python-attrs/cattrs/
+"
+SRC_URI="
+	https://github.com/python-attrs/cattrs/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="test-rust"
+
+RDEPEND="
+	>=dev-python/attrs-20.1.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		dev-python/exceptiongroup[${PYTHON_USEDEP}]
+		>=dev-python/typing-extensions-4.1.0[${PYTHON_USEDEP}]
+	' 3.10)
+"
+BDEPEND="
+	dev-python/hatch-vcs[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/cbor2-5.4.6[${PYTHON_USEDEP}]
+		>=dev-python/hypothesis-6.54.5[${PYTHON_USEDEP}]
+		>=dev-python/immutables-0.18[${PYTHON_USEDEP}]
+		>=dev-python/msgpack-1.0.2[${PYTHON_USEDEP}]
+		>=dev-python/pymongo-4.2.0[${PYTHON_USEDEP}]
+		>=dev-python/pyyaml-6.0[${PYTHON_USEDEP}]
+		>=dev-python/tomlkit-0.11.4[${PYTHON_USEDEP}]
+		>=dev-python/ujson-5.4.0[${PYTHON_USEDEP}]
+		test-rust? (
+			>=dev-python/orjson-3.5.2[${PYTHON_USEDEP}]
+		)
+	)
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+
+python_test() {
+	local EPYTEST_DESELECT=()
+	if ! has_version "dev-python/orjson[${PYTHON_USEDEP}]"; then
+		EPYTEST_DESELECT+=(
+			tests/test_preconf.py::test_orjson
+			tests/test_preconf.py::test_orjson_converter
+			tests/test_preconf.py::test_orjson_converter_unstruct_collection_overrides
+		)
+	fi
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -o addopts= tests
+}