[gentoo-commits] repo/gentoo:master commit in: media-gfx/blender/files/, media-gfx/blender/

["Sam James" <sam@gentoo.org>]

commit:     694c68958e60e2e098d63915f8e4dd470bc86905
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Fri Oct 27 02:57:40 2023 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Fri Oct 27 02:57:40 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=694c6895

Revert "media-gfx/blender: add 3.6.5, update 9999"

This reverts commit 824eb57e50e0f5039d42f39e0caa5461d8d73468.

Signed-off-by: Sam James <sam <AT> gentoo.org>

 media-gfx/blender/Manifest                         |   1 -
 media-gfx/blender/blender-3.6.5.ebuild             | 443 ---------------------
 media-gfx/blender/blender-9999.ebuild              |   4 +-
 .../blender/files/blender-4.0.0-ocio-2.3.0.patch   | 110 -----
 4 files changed, 3 insertions(+), 555 deletions(-)

diff --git a/media-gfx/blender/Manifest b/media-gfx/blender/Manifest
index 7c56592c6b76..b3c42c94fb98 100644
--- a/media-gfx/blender/Manifest
+++ b/media-gfx/blender/Manifest
@@ -3,4 +3,3 @@ DIST blender-3.3.8.tar.xz 41915180 BLAKE2B 7fb24afe2151bba53d8c25160bd697145aced
 DIST blender-3.4.1.tar.xz 53666296 BLAKE2B ec5b2771c1b55ecdf3c2c86a413ae5599545800fc072eff45cf212b32c74af60fc3d650ad931fff221c1073adb2b447df3287a965f884a4760a5d972c9877aee SHA512 d6de3ec9cd1a1e4d4e4a838af0cfc113c91c3c1b66703027e0ed61bd818dafc4e4304fd041738ddea32fc76b1ad9b7737cbdcf74d56a0406a87c457375d907ab
 DIST blender-3.5.1.tar.xz 69780800 BLAKE2B 6961280b9d5fb606a35137ce355bf07b4dc16908d5d52cfd3a914907721da16108b8780b1894413a69ab69d455f5d1575697079a24c2bdcecb17174cf7a7c7c7 SHA512 7c9c03de8532884f8ab39fecf1450f8be4bc937a018bd14240ace81a89e422625aba9c4865f6efbb8371f5f01e930932fa5cf03c9d14d44c5312db33e3c56131
 DIST blender-3.6.0.tar.xz 70428872 BLAKE2B a43f2c0a2db6fa624b1bd96264462312d31f2e3983c463da9d17b0c793d0d344dfbbc13acfb8bab53cc37f5b5b3479d60b8046475aa6c977074ef35414640eaf SHA512 5fbb7a48d1f18e5cc6430bdefb4d7d9e8a52d387cf92a319c7fbc8836a3f5a6f90fab13f152be49c3558a8f70ed9f0d1f7aeddb264a938496a2f93254bb569cb
-DIST blender-3.6.5.tar.xz 70447868 BLAKE2B efa366b8aff5c8870c9ed060063eba1115a9ae50b0345c56fbaaab228976afad6f4c6b9c374f22d146fe88db6e0e7aab3d61b1797e71f30f6adfc594599ea2be SHA512 d07e53c708a1e6df18853eb5f0dc032459c74ef43f9559880720170f98ac8729064edb143835f8cec411ab6de42619bed3f0ef1143b288f2a2eb6f05fdfc32ae

diff --git a/media-gfx/blender/blender-3.6.5.ebuild b/media-gfx/blender/blender-3.6.5.ebuild
deleted file mode 100644
index 1f87c0fac6ef..000000000000
--- a/media-gfx/blender/blender-3.6.5.ebuild
+++ /dev/null
@@ -1,443 +0,0 @@
-# Copyright 1999-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-PYTHON_COMPAT=( python3_10 python3_11 )
-
-inherit check-reqs cmake flag-o-matic pax-utils python-single-r1 toolchain-funcs xdg-utils
-
-DESCRIPTION="3D Creation/Animation/Publishing System"
-HOMEPAGE="https://www.blender.org"
-
-if [[ ${PV} = *9999* ]] ; then
-	# Subversion is needed for downloading unit test files
-	inherit git-r3 subversion
-	EGIT_REPO_URI="https://projects.blender.org/blender/blender.git"
-	ADDONS_EGIT_REPO_URI="https://projects.blender.org/blender/blender-addons.git"
-else
-	SRC_URI="https://download.blender.org/source/${P}.tar.xz"
-	# Update these between major releases.
-	TEST_TARBALL_VERSION="$(ver_cut 1-2).0"
-	# SRC_URI+=" test? ( https://dev.gentoo.org/~sam/distfiles/${CATEGORY}/${PN}/${PN}-${TEST_TARBALL_VERSION}-tests.tar.xz )"
-	KEYWORDS="~amd64 ~arm ~arm64"
-fi
-
-SLOT="${PV%.*}"
-LICENSE="|| ( GPL-3 BL )"
-IUSE="+bullet +dds +fluid +openexr +tbb
-	alembic collada +color-management cuda +cycles cycles-bin-kernels
-	debug doc +embree +ffmpeg +fftw +gmp jack jemalloc jpeg2k
-	man +nanovdb ndof nls openal +oidn +openmp +openpgl +opensubdiv
-	+openvdb optix osl +pdf +potrace +pugixml pulseaudio sdl
-	+sndfile test +tiff valgrind wayland X"
-RESTRICT="!test? ( test )"
-
-REQUIRED_USE="${PYTHON_REQUIRED_USE}
-	alembic? ( openexr )
-	cuda? ( cycles )
-	cycles? ( openexr tiff )
-	fluid? ( tbb )
-	openvdb? ( tbb )
-	optix? ( cuda )
-	osl? ( cycles )
-	test? ( color-management )"
-
-# Library versions for official builds can be found in the blender source directory in:
-# build_files/build_environment/install_deps.sh
-RDEPEND="${PYTHON_DEPS}
-	dev-libs/boost:=[nls?]
-	dev-libs/lzo:2=
-	$(python_gen_cond_dep '
-		dev-python/cython[${PYTHON_USEDEP}]
-		dev-python/numpy[${PYTHON_USEDEP}]
-		dev-python/zstandard[${PYTHON_USEDEP}]
-		dev-python/requests[${PYTHON_USEDEP}]
-	')
-	media-libs/freetype:=[brotli]
-	media-libs/libepoxy:=
-	media-libs/libjpeg-turbo:=
-	media-libs/libpng:=
-	media-libs/libsamplerate
-	>=media-libs/OpenImageIO-2.4.6.0:=
-	sys-libs/zlib:=
-	virtual/glu
-	virtual/libintl
-	virtual/opengl
-	alembic? ( >=media-gfx/alembic-1.8.3-r2[boost(+),hdf(+)] )
-	collada? ( >=media-libs/opencollada-1.6.68 )
-	color-management? ( media-libs/OpenColorIO:= )
-	cuda? ( dev-util/nvidia-cuda-toolkit:= )
-	embree? ( >=media-libs/embree-3.10.0[raymask] )
-	ffmpeg? ( media-video/ffmpeg:=[x264,mp3,encode,theora,jpeg2k?,vpx,vorbis,opus,xvid] )
-	fftw? ( sci-libs/fftw:3.0= )
-	gmp? ( dev-libs/gmp )
-	jack? ( virtual/jack )
-	jemalloc? ( dev-libs/jemalloc:= )
-	jpeg2k? ( media-libs/openjpeg:2= )
-	ndof? (
-		app-misc/spacenavd
-		dev-libs/libspnav
-	)
-	nls? ( virtual/libiconv )
-	openal? ( media-libs/openal )
-	oidn? ( >=media-libs/oidn-1.4.1 )
-	openexr? (
-		>=dev-libs/Imath-3.1.4-r2:=
-		>=media-libs/openexr-3:0=
-	)
-	openpgl? ( media-libs/openpgl )
-	opensubdiv? ( >=media-libs/opensubdiv-3.4.0 )
-	openvdb? (
-		>=media-gfx/openvdb-9.0.0:=[nanovdb?]
-		dev-libs/c-blosc:=
-	)
-	optix? ( <dev-libs/optix-7.5.0 )
-	osl? ( >=media-libs/OpenShadingLanguage-1.11.16.0-r3:= )
-	pdf? ( media-libs/libharu )
-	potrace? ( media-gfx/potrace )
-	pugixml? ( dev-libs/pugixml )
-	pulseaudio? ( media-libs/libpulse )
-	sdl? ( media-libs/libsdl2[sound,joystick] )
-	sndfile? ( media-libs/libsndfile )
-	tbb? ( dev-cpp/tbb:= )
-	tiff? ( media-libs/tiff:= )
-	valgrind? ( dev-util/valgrind )
-	wayland? (
-		>=dev-libs/wayland-1.12
-		>=dev-libs/wayland-protocols-1.15
-		>=x11-libs/libxkbcommon-0.2.0
-		media-libs/mesa[wayland]
-		sys-apps/dbus
-	)
-	X? (
-		x11-libs/libX11
-		x11-libs/libXi
-		x11-libs/libXxf86vm
-	)
-"
-
-DEPEND="${RDEPEND}
-	dev-cpp/eigen:=
-"
-
-BDEPEND="
-	virtual/pkgconfig
-	doc? (
-		app-doc/doxygen[dot]
-		dev-python/sphinx[latex]
-		dev-texlive/texlive-bibtexextra
-		dev-texlive/texlive-fontsextra
-		dev-texlive/texlive-fontutils
-		dev-texlive/texlive-latex
-		dev-texlive/texlive-latexextra
-	)
-	nls? ( sys-devel/gettext )
-	wayland? (
-		dev-util/wayland-scanner
-	)
-"
-
-PATCHES=(
-	"${FILESDIR}/${PN}-4.0.0-ocio-2.3.0.patch"
-)
-
-blender_check_requirements() {
-	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
-
-	if use doc; then
-		CHECKREQS_DISK_BUILD="4G" check-reqs_pkg_pretend
-	fi
-}
-
-blender_get_version() {
-	# Get blender version from blender itself.
-	BV=$(grep "BLENDER_VERSION " source/blender/blenkernel/BKE_blender_version.h | cut -d " " -f 3; assert)
-	if ((${BV:0:1} < 3)) ; then
-		# Add period (290 -> 2.90).
-		BV=${BV:0:1}.${BV:1}
-	else
-		# Add period and skip the middle number (301 -> 3.1)
-		BV=${BV:0:1}.${BV:2}
-	fi
-}
-
-pkg_pretend() {
-	blender_check_requirements
-}
-
-pkg_setup() {
-	blender_check_requirements
-	python-single-r1_pkg_setup
-}
-
-src_unpack() {
-	if [[ ${PV} = *9999* ]] ; then
-		git-r3_src_unpack
-
-		git-r3_fetch "${ADDONS_EGIT_REPO_URI}"
-		git-r3_checkout "${ADDONS_EGIT_REPO_URI}" "${S}/scripts/addons"
-
-		if use test; then
-			TESTS_SVN_URL=https://svn.blender.org/svnroot/bf-blender/trunk/lib/tests
-			subversion_fetch ${TESTS_SVN_URL} ../lib/tests
-		fi
-		ASSETS_SVN_URL=https://svn.blender.org/svnroot/bf-blender/trunk/lib/assets
-		subversion_fetch ${ASSETS_SVN_URL} ../lib/assets
-	else
-		default
-		if use test; then
-			#The tests are downloaded from: https://svn.blender.org/svnroot/bf-blender/tags/blender-${SLOT}-release/lib/tests
-			mkdir -p lib || die
-			mv "${WORKDIR}/blender-${TEST_TARBALL_VERSION}-tests/tests" lib || die
-		fi
-	fi
-
-}
-
-src_prepare() {
-	cmake_src_prepare
-
-	blender_get_version
-
-	# Disable MS Windows help generation. The variable doesn't do what it
-	# it sounds like.
-	sed -e "s|GENERATE_HTMLHELP      = YES|GENERATE_HTMLHELP      = NO|" \
-		-i doc/doxygen/Doxyfile || die
-
-	# Prepare icons and .desktop files for slotting.
-	sed -e "s|blender.svg|blender-${BV}.svg|" -i source/creator/CMakeLists.txt || die
-	sed -e "s|blender-symbolic.svg|blender-${BV}-symbolic.svg|" -i source/creator/CMakeLists.txt || die
-	sed -e "s|blender.desktop|blender-${BV}.desktop|" -i source/creator/CMakeLists.txt || die
-
-	sed -e "s|Name=Blender|Name=Blender ${PV}|" -i release/freedesktop/blender.desktop || die
-	sed -e "s|Exec=blender|Exec=blender-${BV}|" -i release/freedesktop/blender.desktop || die
-	sed -e "s|Icon=blender|Icon=blender-${BV}|" -i release/freedesktop/blender.desktop || die
-
-	mv release/freedesktop/icons/scalable/apps/blender.svg "release/freedesktop/icons/scalable/apps/blender-${BV}.svg" || die
-	mv release/freedesktop/icons/symbolic/apps/blender-symbolic.svg "release/freedesktop/icons/symbolic/apps/blender-${BV}-symbolic.svg" || die
-	mv release/freedesktop/blender.desktop "release/freedesktop/blender-${BV}.desktop" || die
-
-	if use test; then
-		# Without this the tests will try to use /usr/bin/blender and /usr/share/blender/ to run the tests.
-		sed -e "s|set(TEST_INSTALL_DIR.*|set(TEST_INSTALL_DIR ${ED}/usr/)|g" -i tests/CMakeLists.txt || die
-		sed -e "s|string(REPLACE.*|set(TEST_INSTALL_DIR ${ED}/usr/)|g" -i build_files/cmake/Modules/GTestTesting.cmake || die
-	fi
-}
-
-src_configure() {
-	append-lfs-flags
-	blender_get_version
-
-	local mycmakeargs=(
-		-DBUILD_SHARED_LIBS=OFF
-		-DPYTHON_INCLUDE_DIR="$(python_get_includedir)"
-		-DPYTHON_LIBRARY="$(python_get_library_path)"
-		-DPYTHON_VERSION="${EPYTHON/python/}"
-		-DWITH_ALEMBIC=$(usex alembic)
-		-DWITH_ASSERT_ABORT=$(usex debug)
-		-DWITH_BOOST=ON
-		-DWITH_BULLET=$(usex bullet)
-		-DWITH_CODEC_FFMPEG=$(usex ffmpeg)
-		-DWITH_CODEC_SNDFILE=$(usex sndfile)
-		-DWITH_CXX_GUARDEDALLOC=$(usex debug)
-		-DWITH_CYCLES=$(usex cycles)
-		-DWITH_CYCLES_CUDA_BINARIES=$(usex cycles-bin-kernels)
-		-DWITH_CYCLES_DEVICE_CUDA=$(usex cuda TRUE FALSE)
-		-DWITH_CYCLES_DEVICE_OPTIX=$(usex optix)
-		-DWITH_CYCLES_EMBREE=$(usex embree)
-		-DWITH_CYCLES_OSL=$(usex osl)
-		-DWITH_CYCLES_PATH_GUIDING=$(usex openpgl)
-		-DWITH_CYCLES_STANDALONE=OFF
-		-DWITH_CYCLES_STANDALONE_GUI=OFF
-		-DWITH_DOC_MANPAGE=$(usex man)
-		-DWITH_FFTW3=$(usex fftw)
-		-DWITH_GHOST_WAYLAND=$(usex wayland)
-		-DWITH_GHOST_WAYLAND_APP_ID="blender-${BV}"
-		-DWITH_GHOST_WAYLAND_DBUS=$(usex wayland)
-		-DWITH_GHOST_WAYLAND_DYNLOAD=OFF
-		-DWITH_GHOST_WAYLAND_LIBDECOR=OFF
-		-DWITH_GHOST_X11=$(usex X)
-		-DWITH_GMP=$(usex gmp)
-		-DWITH_GTESTS=$(usex test)
-		-DWITH_HARU=$(usex pdf)
-		-DWITH_HEADLESS=$($(use X || use wayland) && echo OFF || echo ON)
-		-DWITH_INSTALL_PORTABLE=OFF
-		-DWITH_IMAGE_DDS=$(usex dds)
-		-DWITH_IMAGE_OPENEXR=$(usex openexr)
-		-DWITH_IMAGE_OPENJPEG=$(usex jpeg2k)
-		-DWITH_IMAGE_TIFF=$(usex tiff)
-		-DWITH_INPUT_NDOF=$(usex ndof)
-		-DWITH_INTERNATIONAL=$(usex nls)
-		-DWITH_JACK=$(usex jack)
-		-DWITH_MEM_JEMALLOC=$(usex jemalloc)
-		-DWITH_MEM_VALGRIND=$(usex valgrind)
-		-DWITH_MOD_FLUID=$(usex fluid)
-		-DWITH_MOD_OCEANSIM=$(usex fftw)
-		-DWITH_NANOVDB=$(usex nanovdb)
-		-DWITH_OPENAL=$(usex openal)
-		-DWITH_OPENCOLLADA=$(usex collada)
-		-DWITH_OPENCOLORIO=$(usex color-management)
-		-DWITH_OPENIMAGEDENOISE=$(usex oidn)
-		-DWITH_OPENMP=$(usex openmp)
-		-DWITH_OPENSUBDIV=$(usex opensubdiv)
-		-DWITH_OPENVDB=$(usex openvdb)
-		-DWITH_OPENVDB_BLOSC=$(usex openvdb)
-		-DWITH_POTRACE=$(usex potrace)
-		-DWITH_PUGIXML=$(usex pugixml)
-		-DWITH_PULSEAUDIO=$(usex pulseaudio)
-		-DWITH_PYTHON_INSTALL=OFF
-		-DWITH_SDL=$(usex sdl)
-		-DWITH_STATIC_LIBS=OFF
-		-DWITH_SYSTEM_EIGEN3=ON
-		-DWITH_SYSTEM_FREETYPE=ON
-		-DWITH_SYSTEM_LZO=ON
-		-DWITH_TBB=$(usex tbb)
-		-DWITH_USD=OFF
-		-DWITH_XR_OPENXR=OFF
-	)
-
-	if use optix; then
-		mycmakeargs+=(
-			-DCYCLES_RUNTIME_OPTIX_ROOT_DIR="${EPREFIX}"/opt/optix
-			-DOPTIX_ROOT_DIR="${EPREFIX}"/opt/optix
-		)
-	fi
-
-	# This is currently needed on arm64 to get the NEON SIMD wrapper to compile the code successfully
-	use arm64 && append-flags -flax-vector-conversions
-
-	append-flags $(usex debug '-DDEBUG' '-DNDEBUG')
-
-	if tc-is-gcc ; then
-		# These options only exist when GCC is detected.
-		# We disable these to respect the user's choice of linker.
-		mycmakeargs+=(
-			-DWITH_LINKER_GOLD=OFF
-			-DWITH_LINKER_LLD=OFF
-		)
-	fi
-
-	cmake_src_configure
-}
-
-src_test() {
-	# A lot of tests needs to have access to the installed data files.
-	# So install them into the image directory now.
-	cmake_src_install
-
-	blender_get_version
-	# Define custom blender data/script file paths not be able to find them otherwise during testing.
-	# (Because the data is in the image directory and it will default to look in /usr/share)
-	export BLENDER_SYSTEM_SCRIPTS="${ED}"/usr/share/blender/${BV}/scripts
-	export BLENDER_SYSTEM_DATAFILES="${ED}"/usr/share/blender/${BV}/datafiles
-
-	# Sanity check that the script and datafile path is valid.
-	# If they are not vaild, blender will fallback to the default path which is not what we want.
-	[ -d "$BLENDER_SYSTEM_SCRIPTS" ] || die "The custom script path is invalid, fix the ebuild!"
-	[ -d "$BLENDER_SYSTEM_DATAFILES" ] || die "The custom datafiles path is invalid, fix the ebuild!"
-
-	cmake_src_test
-
-	# Clean up the image directory for src_install
-	rm -fr "${ED}"/* || die
-}
-
-src_install() {
-	blender_get_version
-
-	# Pax mark blender for hardened support.
-	pax-mark m "${BUILD_DIR}"/bin/blender
-
-	cmake_src_install
-
-	if use man; then
-		# Slot the man page
-		mv "${ED}/usr/share/man/man1/blender.1" "${ED}/usr/share/man/man1/blender-${BV}.1" || die
-	fi
-
-	if use doc; then
-		# Define custom blender data/script file paths. Otherwise Blender will not be able to find them during doc building.
-		# (Because the data is in the image directory and it will default to look in /usr/share)
-		export BLENDER_SYSTEM_SCRIPTS=${ED}/usr/share/blender/${BV}/scripts
-		export BLENDER_SYSTEM_DATAFILES=${ED}/usr/share/blender/${BV}/datafiles
-
-		# Workaround for binary drivers.
-		addpredict /dev/ati
-		addpredict /dev/dri
-		addpredict /dev/nvidiactl
-
-		einfo "Generating Blender C/C++ API docs ..."
-		cd "${CMAKE_USE_DIR}"/doc/doxygen || die
-		doxygen -u Doxyfile || die
-		doxygen || die "doxygen failed to build API docs."
-
-		cd "${CMAKE_USE_DIR}" || die
-		einfo "Generating (BPY) Blender Python API docs ..."
-		"${BUILD_DIR}"/bin/blender --background --python doc/python_api/sphinx_doc_gen.py -noaudio || die "sphinx failed."
-
-		cd "${CMAKE_USE_DIR}"/doc/python_api || die
-		sphinx-build sphinx-in BPY_API || die "sphinx failed."
-
-		docinto "html/API/python"
-		dodoc -r "${CMAKE_USE_DIR}"/doc/python_api/BPY_API/.
-
-		docinto "html/API/blender"
-		dodoc -r "${CMAKE_USE_DIR}"/doc/doxygen/html/.
-	fi
-
-	# Fix doc installdir
-	docinto html
-	dodoc "${CMAKE_USE_DIR}"/release/text/readme.html
-	rm -r "${ED}"/usr/share/doc/blender || die
-
-	python_optimize "${ED}/usr/share/blender/${BV}/scripts"
-
-	mv "${ED}/usr/bin/blender-thumbnailer" "${ED}/usr/bin/blender-${BV}-thumbnailer" || die
-	mv "${ED}/usr/bin/blender" "${ED}/usr/bin/blender-${BV}" || die
-}
-
-pkg_postinst() {
-	elog
-	elog "Blender uses python integration. As such, may have some"
-	elog "inherent risks with running unknown python scripts."
-	elog
-	elog "It is recommended to change your blender temp directory"
-	elog "from /tmp to /home/user/tmp or another tmp file under your"
-	elog "home directory. This can be done by starting blender, then"
-	elog "changing the 'Temporary Files' directory in Blender preferences."
-	elog
-
-	if use osl; then
-		ewarn ""
-		ewarn "OSL is know to cause runtime segfaults if Mesa has been linked to"
-		ewarn "an other LLVM version than what OSL is linked to."
-		ewarn "See https://bugs.gentoo.org/880671 for more details"
-		ewarn ""
-	fi
-
-	if ! use python_single_target_python3_10; then
-		elog "You are building Blender with a newer python version than"
-		elog "supported by this version upstream."
-		elog "If you experience breakages with e.g. plugins, please switch to"
-		elog "python_single_target_python3_10 instead."
-		elog "Bug: https://bugs.gentoo.org/737388"
-		elog
-	fi
-
-	xdg_icon_cache_update
-	xdg_mimeinfo_database_update
-	xdg_desktop_database_update
-}
-
-pkg_postrm() {
-	xdg_icon_cache_update
-	xdg_mimeinfo_database_update
-	xdg_desktop_database_update
-
-	ewarn ""
-	ewarn "You may want to remove the following directory."
-	ewarn "~/.config/${PN}/${SLOT}/cache/"
-	ewarn "It may contain extra render kernels not tracked by portage"
-	ewarn ""
-}

diff --git a/media-gfx/blender/blender-9999.ebuild b/media-gfx/blender/blender-9999.ebuild
index d32731e15fef..a637534483c4 100644
--- a/media-gfx/blender/blender-9999.ebuild
+++ b/media-gfx/blender/blender-9999.ebuild
@@ -45,6 +45,8 @@ REQUIRED_USE="${PYTHON_REQUIRED_USE}
 
 # Library versions for official builds can be found in the blender source directory in:
 # build_files/build_environment/install_deps.sh
+#
+# <OpenColorIO-2.3.0 for https://projects.blender.org/blender/blender/issues/112917.
 RDEPEND="${PYTHON_DEPS}
 	dev-libs/boost:=[nls?]
 	dev-libs/lzo:2=
@@ -66,7 +68,7 @@ RDEPEND="${PYTHON_DEPS}
 	virtual/opengl
 	alembic? ( >=media-gfx/alembic-1.8.3-r2[boost(+),hdf(+)] )
 	collada? ( >=media-libs/opencollada-1.6.68 )
-	color-management? ( media-libs/OpenColorIO:= )
+	color-management? ( <media-libs/OpenColorIO-2.3.0:= )
 	cuda? ( dev-util/nvidia-cuda-toolkit:= )
 	embree? ( >=media-libs/embree-3.10.0[raymask] )
 	ffmpeg? ( media-video/ffmpeg:=[x264,mp3,encode,theora,jpeg2k?,vpx,vorbis,opus,xvid] )

diff --git a/media-gfx/blender/files/blender-4.0.0-ocio-2.3.0.patch b/media-gfx/blender/files/blender-4.0.0-ocio-2.3.0.patch
deleted file mode 100644
index e6cc4a6fa026..000000000000
--- a/media-gfx/blender/files/blender-4.0.0-ocio-2.3.0.patch
+++ /dev/null
@@ -1,110 +0,0 @@
-From 458917773afb4cdf8e1189c0bf5aff7feda6a664 Mon Sep 17 00:00:00 2001
-From: Brecht Van Lommel <brecht@blender.org>
-Date: Mon, 2 Oct 2023 17:31:08 +0200
-Subject: [PATCH] Build: changes to build with OpenColorIO 2.3
-
-Ref #113157
----
- intern/opencolorio/ocio_impl_glsl.cc          | 12 +++++++++-
- .../ocio_color_space_conversion_shader.cc     | 24 +++++++++++++++++++
- 2 files changed, 35 insertions(+), 1 deletion(-)
-
-diff --git a/intern/opencolorio/ocio_impl_glsl.cc b/intern/opencolorio/ocio_impl_glsl.cc
-index 8d46a2f0773..35e4d0b7a90 100644
---- a/intern/opencolorio/ocio_impl_glsl.cc
-+++ b/intern/opencolorio/ocio_impl_glsl.cc
-@@ -343,8 +343,15 @@ static bool addGPULut1D2D(OCIO_GPUTextures &textures,
-   unsigned int height = 0;
-   GpuShaderCreator::TextureType channel = GpuShaderCreator::TEXTURE_RGB_CHANNEL;
-   Interpolation interpolation = INTERP_LINEAR;
-+#if OCIO_VERSION_HEX >= 0x02030000
-+  /* Always use 2D textures in OpenColorIO 2.3, simpler and same performance. */
-+  GpuShaderDesc::TextureDimensions dimensions = GpuShaderDesc::TEXTURE_2D;
-+  shader_desc->getTexture(
-+      index, texture_name, sampler_name, width, height, channel, dimensions, interpolation);
-+#else
-   shader_desc->getTexture(
-       index, texture_name, sampler_name, width, height, channel, interpolation);
-+#endif
- 
-   const float *values;
-   shader_desc->getTextureValues(index, values);
-@@ -358,6 +365,7 @@ static bool addGPULut1D2D(OCIO_GPUTextures &textures,
-                                                                                   GPU_R16F;
- 
-   OCIO_GPULutTexture lut;
-+#if OCIO_VERSION_HEX < 0x02030000
-   /* There does not appear to be an explicit way to check if a texture is 1D or 2D.
-    * It depends on more than height. So check instead by looking at the source. */
-   std::string sampler1D_name = std::string("sampler1D ") + sampler_name;
-@@ -365,7 +373,9 @@ static bool addGPULut1D2D(OCIO_GPUTextures &textures,
-     lut.texture = GPU_texture_create_1d(
-         texture_name, width, 1, format, GPU_TEXTURE_USAGE_SHADER_READ, values);
-   }
--  else {
-+  else
-+#endif
-+  {
-     lut.texture = GPU_texture_create_2d(
-         texture_name, width, height, 1, format, GPU_TEXTURE_USAGE_SHADER_READ, values);
-   }
-diff --git a/source/blender/compositor/realtime_compositor/cached_resources/intern/ocio_color_space_conversion_shader.cc b/source/blender/compositor/realtime_compositor/cached_resources/intern/ocio_color_space_conversion_shader.cc
-index 4cdbb52a6ba..52492754c0f 100644
---- a/source/blender/compositor/realtime_compositor/cached_resources/intern/ocio_color_space_conversion_shader.cc
-+++ b/source/blender/compositor/realtime_compositor/cached_resources/intern/ocio_color_space_conversion_shader.cc
-@@ -95,6 +95,18 @@ class GPUShaderCreator : public OCIO::GpuShaderCreator {
-     return GPU_max_texture_size();
-   }
- 
-+#  if OCIO_VERSION_HEX >= 0x02030000
-+  void setAllowTexture1D(bool allowed) override
-+  {
-+    allow_texture_1D_ = allowed;
-+  }
-+
-+  bool getAllowTexture1D() const override
-+  {
-+    return allow_texture_1D_;
-+  }
-+#  endif
-+
-   bool addUniform(const char *name, const DoubleGetter &get_double) override
-   {
-     /* Check if a resource exists with the same name and assert if it is the case, returning false
-@@ -201,6 +213,9 @@ class GPUShaderCreator : public OCIO::GpuShaderCreator {
-                   uint width,
-                   uint height,
-                   TextureType channel,
-+#  if OCIO_VERSION_HEX >= 0x02030000
-+                  OCIO::GpuShaderDesc::TextureDimensions dimensions,
-+#  endif
-                   OCIO::Interpolation interpolation,
-                   const float *values) override
-   {
-@@ -216,7 +231,11 @@ class GPUShaderCreator : public OCIO::GpuShaderCreator {
-     GPUTexture *texture;
-     eGPUTextureFormat texture_format = (channel == TEXTURE_RGB_CHANNEL) ? GPU_RGB16F : GPU_R16F;
-     /* A height of 1 indicates a 1D texture according to the OCIO API. */
-+#  if OCIO_VERSION_HEX >= 0x02030000
-+    if (dimensions == OCIO::GpuShaderDesc::TEXTURE_1D) {
-+#  else
-     if (height == 1) {
-+#  endif
-       texture = GPU_texture_create_1d(
-           texture_name, width, 1, texture_format, GPU_TEXTURE_USAGE_SHADER_READ, values);
-       shader_create_info_.sampler(textures_.size() + 1, ImageType::FLOAT_1D, resource_name);
-@@ -398,6 +417,11 @@ class GPUShaderCreator : public OCIO::GpuShaderCreator {
-   /* A vectors that stores the created uniform buffers when bind_shader_and_resources() is called,
-    * so that they can be properly unbound and freed in the unbind_shader_and_resources() method. */
-   Vector<GPUUniformBuf *> uniform_buffers_;
-+
-+#  if OCIO_VERSION_HEX >= 0x02030000
-+  /* Allow creating 1D textures, or only use 2D textures. */
-+  bool allow_texture_1D_ = true;
-+#  endif
- };
- 
- #else
--- 
-2.30.2
-